739343_ko-KR

liliconcom

Tabulate에 텍스트를 추가하는 방법.

표에 알파벳순으로 표시되는 실패함을 넣으려고 합니다. 이를 달성하기 위한 해결 방법이 있습니까?

기본 데이터 분석 및 모델링Re: Tabulate에 텍스트를 추가하는 방법.

Tabulate를 사용하여 해당 유형의 결과를 얻을 수 있는지 확실하지 않습니다( Tabulate 플랫폼을 사용하여 설명 통계의 요약 표 또는 피벗 테이블을 대화형으로 구성 ). 그러나 Split 또는 Transpose를 사용하여 유사한 표를 만들 수 있습니다.

그리고 1 2 3의 이름을 Run1, Run2, Run3으로 바꾸세요.

tabulate를 사용하면 다음과 같은 결과가 나옵니다.

Re: Tabulate에 텍스트를 추가하는 방법.

다음은 JSL을 사용하여 테이블 상자를 만드는 방식으로 이 요청에 접근하는 대체 방법입니다.

Names Default To Here( 1 );
dt = New Table( "JMP Help",
	Add Rows( 9 ),
	New Column( "Run",
		Numeric,
		"Ordinal",
		Format( "Best", 12 ),
		Formula( Col Cumulative Sum( 1, :Serial Number ) ),
		Set Display Width( 38 )
	),
	New Column( "Serial Number",
		Character( 4 ),
		Set Values(
			{"1001", "1001", "1001", "1002", "1002", "1002", "1003", "1003", "1003"}
		),
		Set Display Width( 81 )
	),
	New Column( "Failure Bin",
		Character( 1 ),
		Set Values( {"A", "A", "B", "A", "B", "B", "C", "C", "A"} ),
		Set Display Width( 59 )
	)
);

dtSplit = dt << Split(
	Split By( :Run ),
	Split( :Failure Bin ),
	Group( :Serial Number ),
	Output Table( "Split" ),
	Sort by Column Property
);

nw = New Window( "Tabulate",
	tb = Table Box(
		Col Span Box(
			"",
			sn = String Col Box( "Serial Number",
				dtSplit:Serial Number << get values
			)
		),
		Col Span Box(
			"Run",
			scb1 = String Col Box( "1", dtSplit:"1"n << get values ),
			scb2 = String Col Box( "2", dtSplit:"2"n << get values ),
			scb3 = String Col Box( "3", dtSplit:"3"n << get values )
		)
	)
);
sn << set width( 100 );
scb1 << set width( 30 ) << set justify( "center" );
scb2 << set width( 30 ) << set justify( "center" );
scb3 << set width( 30 ) << set justify( "center" );
tb << Set Row Borders( 1 );
tb << Set Column Borders( 1 );