739343_it-IT

liliconcom

Come aggiungere testo in tabulare.

Sto cercando di inserire il contenitore degli errori, che è alfabetico nella tabella. C'è qualche soluzione per raggiungere questo obiettivo?

Analisi e modellazione dei dati di baseRe: Come aggiungere testo in Tabulate.

Non sono sicuro se è possibile ottenere quel tipo di risultato utilizzando Tabulate ( utilizzare la piattaforma Tabulate per costruire in modo interattivo tabelle di riepilogo, o tabelle pivot, di statistiche descrittive ), ma è possibile creare una tabella simile utilizzando Split o Transpose

e poi rinominarli 1 2 3 in Esegui1, Esegui2, Esegui3.

Con tabulate otterrai qualcosa del tipo

Re: Come aggiungere testo in Tabulate.

Ecco il mio modo alternativo di affrontare questa richiesta, utilizzando un po' di JSL per creare una Table Box

Names Default To Here( 1 );
dt = New Table( "JMP Help",
	Add Rows( 9 ),
	New Column( "Run",
		Numeric,
		"Ordinal",
		Format( "Best", 12 ),
		Formula( Col Cumulative Sum( 1, :Serial Number ) ),
		Set Display Width( 38 )
	),
	New Column( "Serial Number",
		Character( 4 ),
		Set Values(
			{"1001", "1001", "1001", "1002", "1002", "1002", "1003", "1003", "1003"}
		),
		Set Display Width( 81 )
	),
	New Column( "Failure Bin",
		Character( 1 ),
		Set Values( {"A", "A", "B", "A", "B", "B", "C", "C", "A"} ),
		Set Display Width( 59 )
	)
);

dtSplit = dt << Split(
	Split By( :Run ),
	Split( :Failure Bin ),
	Group( :Serial Number ),
	Output Table( "Split" ),
	Sort by Column Property
);

nw = New Window( "Tabulate",
	tb = Table Box(
		Col Span Box(
			"",
			sn = String Col Box( "Serial Number",
				dtSplit:Serial Number << get values
			)
		),
		Col Span Box(
			"Run",
			scb1 = String Col Box( "1", dtSplit:"1"n << get values ),
			scb2 = String Col Box( "2", dtSplit:"2"n << get values ),
			scb3 = String Col Box( "3", dtSplit:"3"n << get values )
		)
	)
);
sn << set width( 100 );
scb1 << set width( 30 ) << set justify( "center" );
scb2 << set width( 30 ) << set justify( "center" );
scb3 << set width( 30 ) << set justify( "center" );
tb << Set Row Borders( 1 );
tb << Set Column Borders( 1 );