739361_fr-FR

liliconcom

HTML interactif JMP17 fonctionnant avec Enregistrer sous mais ne pouvant pas être recréé uniquement dans le code

Bonjour,

J'ai réussi à créer un rapport HTML interactif lors de l'exécution de la méthode Fichier -> Enregistrer sous. Cependant, j'ai des problèmes pour que le HTML interactif affiche les filtres de données lors de l'enregistrement dans le code JSL. Quelqu'un peut-il jeter un œil et voir si je manque quelque chose d'évident ici ?

Voici le code que j'utilise :

JMP17

v2 = dtconcat << Graph Builder(
	Size(951, 734),
	Show Control Panel(0),
	Variables(X(:TIME), Y(:Something), Overlay(:label)),
	Elements(Points(X, Y, Legend(11)), Smoother(X, Y, Legend(12))),
	Local Data Filter(
		Show Modes(1),
		Count Excluded Rows(0),
		Mode(Include(0)),
		Add Filter(
			columns(:label, :"otherlabel"n),
			Display(:label, N Items(15), Find(Set Text(""))),
			Display(:"otherlabel"n, N Items(5))
		)
	)
);
 
v2 << save interactive html("path\path1\path2\test.html");

Automatisation et scriptsles fenêtresRe : JMP17 HTML interactif fonctionne avec « Enregistrer sous », mais impossible de le reproduire uniquement par le code.

Merci Jarmo ! J'ai aussi trouvé ce message précédent qui reprend ton idée. Ça marche maintenant !

Résolu : Filtre de données locales manquant dans le script « Enregistrer HTML interactif() » - Communauté d’utilisateurs JMP

Re : HTML interactif JMP17 fonctionnant avec Enregistrer sous mais ne pouvant pas être recréé uniquement dans le code

Vous devrez peut-être d'abord l'envelopper dans une nouvelle fenêtre ou prendre une référence de niveau supérieur pour capturer également le filtre.

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("Graph Builder",
	gb = dt << Graph Builder(
		Size(525, 454),
		Show Control Panel(0),
		Variables(X(:weight), Y(:height), Overlay(:sex)),
		Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
		Local Data Filter(
			Show Modes(1),
			Mode(Include(0)),
			Add Filter(columns(:age), Display(:age, N Items(6)))
		)
	)
);


nw << Save Interactive HTML("$TEMP/test.html");
nw << Close Window;

Web("$TEMP/test.html");

Avec une référence de niveau plus élevée (ou plutôt la plus élevée dans ce cas)

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(525, 454),
	Show Control Panel(0),
	Variables(X(:weight), Y(:height), Overlay(:sex)),
	Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
	Local Data Filter(
		Show Modes(1),
		Mode(Include(0)),
		Add Filter(columns(:age), Display(:age, N Items(6)))
	)
);

topref = (gb << top parent);
topref << Save Interactive HTML("$TEMP/test.html");

Web("$TEMP/test.html");