739343_en-US

liliconcom

How to Add text in Tabulate.

I am trying to put failure bin, which is alphabetic in the tabulate. Is there any work around to achieve this?

 

 

Basic Data Analysis and ModelingRe: How to Add text in Tabulate.

I'm not sure if you can get that type of result using Tabulate (use the Tabulate platform to interactively construct summary tables, or pivot tables, of descriptive statistics), but you can create similar table using Split or Transpose

and then rename those 1 2 3 to Run1, Run2, Run3.

 

With tabulate you will end up with something like

 

 

Re: How to Add text in Tabulate.

Here is my alternative way of approaching this request, by using some JSL to create a Table Box

Names Default To Here( 1 );
dt = New Table( "JMP Help",
	Add Rows( 9 ),
	New Column( "Run",
		Numeric,
		"Ordinal",
		Format( "Best", 12 ),
		Formula( Col Cumulative Sum( 1, :Serial Number ) ),
		Set Display Width( 38 )
	),
	New Column( "Serial Number",
		Character( 4 ),
		Set Values(
			{"1001", "1001", "1001", "1002", "1002", "1002", "1003", "1003", "1003"}
		),
		Set Display Width( 81 )
	),
	New Column( "Failure Bin",
		Character( 1 ),
		Set Values( {"A", "A", "B", "A", "B", "B", "C", "C", "A"} ),
		Set Display Width( 59 )
	)
);

dtSplit = dt << Split(
	Split By( :Run ),
	Split( :Failure Bin ),
	Group( :Serial Number ),
	Output Table( "Split" ),
	Sort by Column Property
);

nw = New Window( "Tabulate",
	tb = Table Box(
		Col Span Box(
			"",
			sn = String Col Box( "Serial Number",
				dtSplit:Serial Number << get values
			)
		),
		Col Span Box(
			"Run",
			scb1 = String Col Box( "1", dtSplit:"1"n << get values ),
			scb2 = String Col Box( "2", dtSplit:"2"n << get values ),
			scb3 = String Col Box( "3", dtSplit:"3"n << get values )
		)
	)
);
sn << set width( 100 );
scb1 << set width( 30 ) << set justify( "center" );
scb2 << set width( 30 ) << set justify( "center" );
scb3 << set width( 30 ) << set justify( "center" );
tb << Set Row Borders( 1 );
tb << Set Column Borders( 1 );