Bonjour,
Je voudrais créer des graphiques ternaires montrant la variance de prédiction relative des DOE à mélange à 3 composants.
Pour ce faire, je devrais extraire un nombre élevé de valeurs (disons 20 000) du graphique du profil de variance de prédiction et créer un tableau de données avec ces valeurs. Cette table de données aurait 20 000 lignes et 4 colonnes : X1, X2, X3 et la variance de prédiction relative.
Peut-être qu'une autre façon de procéder serait d'utiliser l'éditeur de formule de colonne et d'implémenter la formule de variance de prédiction relative, mais je ne suis pas familier avec les fonctions matricielles de l'éditeur de formule.
Merci beaucoup.
D'ailleurs, ce serait une fonctionnalité intéressante pour les prochaines mises à jour de JMP 
Merveilleux! Merci beaucoup Marc
Ce script illustre une approche pour trois composants, X1, X2, X3 et le modèle quadratique de Scheffe.
Names Default to Here( 1 );
// make design
doe = DOE(
Custom Design,
{Add Response( Maximize, "Y", ., ., . ), Add Factor( Mixture, 0, 1, "X1", 0 ),
Add Factor( Mixture, 0, 1, "X2", 0 ), Add Factor( Mixture, 0, 1, "X3", 0 ),
Set Random Seed( 27513 ), Number of Starts( 10000 ), Add Term( {1, 1} ),
Add Term( {2, 1} ), Add Term( {3, 1} ), Add Term( {1, 1}, {2, 1} ),
Add Term( {1, 1}, {3, 1} ), Add Term( {2, 1}, {3, 1} ), Set Sample Size( 12 ),
Simulate Responses( 0 ), Save X Matrix( 1 ), Make Design,
Set Run Order( Randomize )}
);
// make design data table
doe dt = doe << Make Table;
doe << Close Window;
// get model matrix, X
model matrix expr = doe dt << Get Script( "Model Matrix" );
X = Arg( Arg( model matrix expr, 1 ), 2 );
inv x prime x = Inverse( X` * X );
// make expression for prediction variance
pv expr = Substitute(
Expr(
xi = Matrix( List( :X1, :X2, :X3, :X1*:X2, :X1*:X3, :X2*:X3 ) );
xi` * iii * xi;
),
Expr( iii ), inv x prime x
);
// add data column with prediction variance formula
Eval(
Substitute(
Expr(
doe dt << New Column( "Prediction Variance", Numeric, Continuous,
Formula( fff )
);
),
Expr( fff ), Name Expr( pv expr )
)
);
// plot prediction variance
mp = doe dt << Mixture Profiler(
Y( :Prediction Variance ),
Mixture Profiler(
1,
Term Value(
X1( 0.333333333333335, Lock( 0 ), Show( 1 ) ),
X2( 0.333333333333336, Lock( 0 ), Show( 1 ) ),
X3( 0.333333333333335, Lock( 0 ), Show( 1 ) )
),
Contour Value(
Prediction Variance(
0.5,
Min( 0 ),
Max( 1 )
)
),
Top Factor( X1 ),
Left Factor( X2 ),
Right Factor( X3 )
)
);
mp << Contour Grid( 0, 1, 0.1, :Prediction Variance );Oui, tu as raison Mark, merci. En effet, mon idée initiale était d'utiliser l'éditeur de formule pour calculer le
expression.
Mais comme je l'ai dit, je ne connais pas les fonctions Matrix de l'éditeur de formule et je n'ai pas réussi à le faire...
Je connais le profil de variance de prédiction et le tracé FDS, malheureusement ces deux plates-formes ne peuvent pas afficher les valeurs de variance de prédiction dans un tracé ternaire (c'est-à-dire un triangle avec X1, X2, X3 comme variables et la variance de prédiction comme réponse).
Vous pouvez utiliser la formule standard de régression linéaire si vous souhaitez créer votre propre visualisation. La formule est fournie dans le guide Aide > Livres > Conception d'expériences. Voir le chapitre sur les détails statistiques. Voici les informations pertinentes :
Le résultat en bas à droite est la variance relative de la prédiction, qui est la quantité tracée dans le Prediction Variance Profiler et le FDS Plot. Multipliez ce résultat par la variance de réponse réelle pour obtenir le résultat absolu si vous le souhaitez.
JMP fournit un profileur et un tracé de fraction du plan pour la variance de prédiction attendue avec n'importe quel plan, y compris une expérience de mélange. Ces deux visualisations de la variance de prédiction sont disponibles dans le plan d'évaluation de la conception. Ils sont automatiquement produits après avoir cliqué sur Make Design.
Si vous disposez déjà d'une conception, vous pouvez également sélectionner DOE > Diagnostics de conception > Évaluer la conception avec une table de données ouverte et ajouter des colonnes de données au rôle de facteur. Les deux mêmes visualisations sont disponibles.
Je suis un peu confus quant à ce que vous cherchez à faire.
Puisque vous disposez de données DOE et que vous consultez un profileur, vous disposez d'un modèle. Avez-vous examiné le profileur de mélange fourni dans le cadre de l'ajustement d'un modèle de mélange ? Vous pouvez ajouter une grille de contour au profileur de mélange qui donnera un tracé ternaire basé sur votre modèle.
Si vous souhaitez toujours utiliser les tracés de contour de Graphique > Tracé ternaire, enregistrez votre formule de prédiction à partir de l'ajustement du modèle. Spécifiez la formule de prédiction dans le champ de contour de la boîte de dialogue Tracé ternaire. Cela vous donnera des contours lisses. Il n'est pas nécessaire de créer une table de données avec des milliers de lignes, sauf si quelque chose me manque.
