738244_ja-JP

liliconcom

リストを含む式列を指定されたリストと比較して、目的の値に置き換えます

こんにちは、

以下の問題の列に新しい数式を追加する方法はありますか?

リスト値の列があり、指定されたリストと比較したいのですが、列のリストの要素が指定されたリストと一致する場合、その単一の要素を「1」に置き換えます。以下に例を示します。指定されたリストは {"aa", "app", "b", "pp", "zzzz"} です。

自動化とスクリプト作成Re: リストを含む式列を指定されたリストと比較して、目的の値に置き換えます

以下はあなたが使用できるアイデアの 1 つです

Names Default To Here(1);

dt = New Table("Untitled",
	Add Rows(1),
	Compress File When Saved(1),
	New Column("Column 1", Expression, "None", Set Values({{"aa", "bb", "dd"}, {"bb", "2", "cc"}}))
);

mylist = {"aa", "bb", "cc"};

dt << New Column("res", Expression, "None");

For Each Row(dt,
	rowresult = Transform Each({myitem, idx}, mylist,
		If(:Column 1[Row()][idx] == myitem,
			"1"
		,
			myitem
		)
	);
	:res = rowresult;
);

Re: リストを含む式列を指定されたリストと比較して、目的の値に置き換えます

まだ問題があります。この提案では、mylist の最初の要素と :Column 1 の最初の要素のみが一致します。次に、2 番目と 2 番目、3 番目と 3 番目の要素が一致します。また、:column 1 に 3 つ以上の要素がある場合、残りは削除されます。以下は提案の結果です

以下を有効にする方法。

Re: リストを含む式列を指定されたリストと比較し、目的の値に置き換えます

私の例には間違いが 1 つあり、あなたが探しているものを誤って理解しました。これはおそらくあなたが探しているものに近いでしょう。

Names Default To Here(1);

dt = New Table("Untitled",
	Add Rows(1),
	Compress File When Saved(1),
	New Column("Column 1",
		Expression,
		"None",
		Set Values({{"aa", "bb", "dd"}, {"bb", "2", "cc"}})
	)
);

mylist = {"aa", "bb", "cc"};

dt << New Column("res", Expression, "None");

For Each Row(
	dt,
	rowresult = Transform Each({item}, :Column 1[Row()],
		If(Contains(mylist, item),
			"1"
		,
			item
		)
	);
	:res = rowresult;
);