737626_es-ES

liliconcom

Cómo crear una tabla de datos de 3 columnas por fila a partir de una cadena numérica

Soy nuevo en JSL. Tengo una cadena de texto que contiene valores separados por "#". Los números deben agruparse en 3 columnas.

Sé que puedo escribir un código para poner los valores en columnas separadas por "#", pero ¿cómo puedo crear una tabla de 3 valores en cada fila, hasta que la tabla esté completa? Sé que probablemente también tendré que eliminar el primer "#" para evitar problemas, ya que los primeros 3 números estarían en la segunda a la cuarta columna.

Por ejemplo:

#1#0,93#0,99#2#1,92#1,99#3#2,9#2,99#4#3,86#3,98#5#4,85#4,98

puede ir a esto:

1

0,93

0,99

2

1,92

1,99

3

2.9

2,99

4

3.86

3,98

5

4.85

4,98

Pero, ¿cómo escribo el código JSL para llegar a esto?

Valor1	Valor2	Valor3
1	0,93	0,99
2	1,92	1,99
3	2.9	2,99
4	3.86	3,98
5	4.85	4,98

En este ejemplo hay 5 filas en la tabla pero el número de filas puede variar.

Combinación y limpieza de datosRe: Cómo crear una tabla de datos de 3 columnas por fila a partir de una cadena numérica

Utilice Texto a columnas para obtener esto

Luego apile sus datos con una pila de series múltiples

y finalmente eliminar columnas adicionales, cambiar el nombre de los encabezados de las columnas y corregir los tipos de modelado/datos de las columnas

El script creado por JMP es un buen punto de partida para el JSL final

// Text to columns
Data Table("Untitled 6") << Text to Columns(columns(:Column 1), Delimiters("#"));


// Stack data table
// → Data Table("Untitled 11")
Data Table("Untitled 6") << Stack(
	columns(
		:Column 1 1, :Column 1 2, :Column 1 3, :Column 1 4, :Column 1 5, :Column 1 6,
		:Column 1 7, :Column 1 8, :Column 1 9, :Column 1 10, :Column 1 11,
		:Column 1 12, :Column 1 13, :Column 1 14, :Column 1 15
	),
	Source Label Column("Label"),
	Stacked Data Column("Data"),
	Drop All Other Columns(1),
	Number of Series(3),
	Output Table("Untitled 11.jmp")
);


// Delete columns
Data Table("Untitled 11") << Delete Columns(:Label, :Label 2, :Label 3);


// Recode column names
Local({dt = Data Table("Untitled 11"), names},
	names = Recode(
		dt << Get Column Names(String),
		{Map Value(
			_rcOrig,
			{"Data", "Value1", "Data 2", "Value2", "Data 3", "Value3"},
			Unmatched(_rcNow)
		)}
	);
	For Each({name, i}, names, Column(dt, i) << Set Name(name));
);


// Standardize column attributes
Local({old dt = Current Data Table()},
	Current Data Table(Data Table("Untitled 11"));
	For Each({col, index}, {:Value1, :Value2, :Value3},
		col << Data Type(Numeric, Format("Best", 12)) <<
		Set Modeling Type("Continuous")
	);
	Current Data Table(old dt);
);

Re: Cómo crear una tabla de datos de 3 columnas por fila a partir de una cadena numérica

Aquí hay un enfoque

Names Default To Here( 1 );
theString = "#1#0.93#0.99#2#1.92#1.99#3#2.9#2.99#4#3.86#3.98#5#4.85#4.98";

dt = New Table( "Start",
	add rows( 1 ),
	New Column( "string", character, set each value( theString ) )
);
dt << Text To Columns( delimiter( "#" ), columns( :string ) );
dt << delete columns( :string );
colNames = dt << get column names( string );
For Each( {col}, colNames,
	Column( dt, col ) << Data Type( Numeric, Format( "Best", 12 ) ) <<
	Set Modeling Type( "Continuous" )
);

dt << Stack(
	columns( colNames ),
	Source Label Column( "Label" ),
	Stacked Data Column( "Value" ),
	Number of Series( 3 ),
	Output Table( "Final" )
);

dtFinal = Current Data Table();
dtFinal << delete columns( {:Label, :Label2, :Label3} );
dtFinal:value << set name( "Value 1" );

close( dt, nosave);