737626_it-IT

liliconcom

Come creare una tabella dati di 3 colonne per riga da una stringa numerica

Sono nuovo in JSL. Ho una stringa di testo che contiene valori separati da un "#". I numeri devono essere raggruppati in 3 colonne

So che posso scrivere un codice per inserire i valori in colonne separate da "#", ma come faccio a creare una tabella di 3 valori in ciascuna riga, fino al completamento della tabella. So che probabilmente dovrò rimuovere anche il primo "#" per evitare problemi poiché i primi 3 numeri sarebbero dalla seconda alla quarta colonna.

Per esempio:

#1#0.93#0.99#2#1.92#1.99#3#2.9#2.99#4#3.86#3.98#5#4.85#4.98

puoi andare a questo:

1

0,93

0,99

2

1.92

1,99

3

2.9

2,99

4

3.86

3,98

5

4.85

4.98

Ma come scrivo il codice JSL per arrivare a questo:

Valore1	Valore2	Valore3
1	0,93	0,99
2	1.92	1,99
3	2.9	2,99
4	3.86	3,98
5	4.85	4.98

In questo esempio ci sono 5 righe nella tabella ma il numero di righe potrebbe variare.

Combinazione e pulizia dei datiRi: Come creare una tabella dati di 3 colonne per riga da una stringa numerica

Usa Testo in colonne per ottenere questo

Quindi impila i tuoi dati con più serie di stack

e infine rimuovere le colonne aggiuntive, rinominare le intestazioni delle colonne e correggere i dati/tipi di modellazione delle colonne

Lo script creato da JMP è un buon punto di partenza per il JSL finale

// Text to columns
Data Table("Untitled 6") << Text to Columns(columns(:Column 1), Delimiters("#"));


// Stack data table
// → Data Table("Untitled 11")
Data Table("Untitled 6") << Stack(
	columns(
		:Column 1 1, :Column 1 2, :Column 1 3, :Column 1 4, :Column 1 5, :Column 1 6,
		:Column 1 7, :Column 1 8, :Column 1 9, :Column 1 10, :Column 1 11,
		:Column 1 12, :Column 1 13, :Column 1 14, :Column 1 15
	),
	Source Label Column("Label"),
	Stacked Data Column("Data"),
	Drop All Other Columns(1),
	Number of Series(3),
	Output Table("Untitled 11.jmp")
);


// Delete columns
Data Table("Untitled 11") << Delete Columns(:Label, :Label 2, :Label 3);


// Recode column names
Local({dt = Data Table("Untitled 11"), names},
	names = Recode(
		dt << Get Column Names(String),
		{Map Value(
			_rcOrig,
			{"Data", "Value1", "Data 2", "Value2", "Data 3", "Value3"},
			Unmatched(_rcNow)
		)}
	);
	For Each({name, i}, names, Column(dt, i) << Set Name(name));
);


// Standardize column attributes
Local({old dt = Current Data Table()},
	Current Data Table(Data Table("Untitled 11"));
	For Each({col, index}, {:Value1, :Value2, :Value3},
		col << Data Type(Numeric, Format("Best", 12)) <<
		Set Modeling Type("Continuous")
	);
	Current Data Table(old dt);
);

Ri: Come creare una tabella dati di 3 colonne per riga da una stringa numerica

Ecco un approccio

Names Default To Here( 1 );
theString = "#1#0.93#0.99#2#1.92#1.99#3#2.9#2.99#4#3.86#3.98#5#4.85#4.98";

dt = New Table( "Start",
	add rows( 1 ),
	New Column( "string", character, set each value( theString ) )
);
dt << Text To Columns( delimiter( "#" ), columns( :string ) );
dt << delete columns( :string );
colNames = dt << get column names( string );
For Each( {col}, colNames,
	Column( dt, col ) << Data Type( Numeric, Format( "Best", 12 ) ) <<
	Set Modeling Type( "Continuous" )
);

dt << Stack(
	columns( colNames ),
	Source Label Column( "Label" ),
	Stacked Data Column( "Value" ),
	Number of Series( 3 ),
	Output Table( "Final" )
);

dtFinal = Current Data Table();
dtFinal << delete columns( {:Label, :Label2, :Label3} );
dtFinal:value << set name( "Value 1" );

close( dt, nosave);