nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

How to minimize a floating global filter window

shampton82

Hey everyone,

I am having an issue trying to find a way to minimize a floating global data filter window. I have tried <<show window(0) and <<minimize window(1) and neither seem to work.

Any ideas on what syntax to use?

Thanks for any input!

Steve

Accepted answers

mmarchandTSI

You can do it this way.

Current Data Table() << Data Filter(
	Location( {780, 189} ),
	Conditional,
	Add Filter(
		columns( :Date Time Quarter, :Date Time Period, :Date Time ),
		Display( :Date Time Quarter, N Items( 5 ) ),
		Display( :Date Time Period, N Items( 5 ) )
	),
	Show Window( 0 )
)

All comments

jthi

Show Window(0) works for me

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
dt << Data Filter();

wait(1);

windows = Get Window List() << get window title;
For Each({window}, windows,
	If(Starts With(window, "Data Filter for"),
		Window(window) << Show Window(0);
		break();
	);
);

shampton82

@jthi So weird! I'm using this script in a work flow:

Current Data Table() << Data Filter(
	Location( {780, 189} ),
	Conditional,
	Add Filter(
		columns( :Date Time Quarter, :Date Time Period, :Date Time ),
		Display( :Date Time Quarter, N Items( 5 ) ),
		Display( :Date Time Period, N Items( 5 ) )
	)
)<<show window(0);

This creates the filter but won't hide it.

jthi

Maybe you just need extra pair of brackets

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
(dt << Data Filter()) << Show Window(0);

or if you want to get a reference something like this

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
Local({filter_ref},
	filter_ref = dt << Data Filter();
	filter_ref << Show Window(0);
);

mmarchandTSI

You can do it this way.

Current Data Table() << Data Filter(
	Location( {780, 189} ),
	Conditional,
	Add Filter(
		columns( :Date Time Quarter, :Date Time Period, :Date Time ),
		Display( :Date Time Quarter, N Items( 5 ) ),
		Display( :Date Time Period, N Items( 5 ) )
	),
	Show Window( 0 )
)

shampton82

Hey @jthi , I don't know why but the top method did not work when I tired it in my script but it works just fine when I run the provide script on its own. I haven't had a chance to try out the second method in my script but I'll give an update when I can. For some reason the proposed solution by @mmarchandTSI worked......