734298_es-ES

liliconcom

Conmutador de columnas aplicado a todos los informes abiertos

Hola chicos,

Estoy intentando escribir un script para aplicar el conmutador de columnas a todos los informes abiertos. Por favor guíame

dt = Current data Table();
//Get all Open reports
wList = Get Window List( Type( "Reports" ) );

//Get Column to replace and column to replace with
win = New Window( "Set a Value",
	<Por favor guíe cómo realizar esta acción. gracias de antemanoAutomatización y secuencias de comandos

Re: Cambiador de columnas aplicado a todos los informes abiertos

¿Cómo desea utilizar Col List Box? El conmutador de columnas requiere que tenga una sola columna que luego se cambia a otra columna (según la lista de columnas en el conmutador de columnas) y esta columna debe ser la misma en todos los informes al principio.

Re: Cambiador de columnas aplicado a todos los informes abiertos

@jthi , Lo siento, lo siento. Supongo que en lugar de un conmutador de columnas es más fácil tener 2 cuadros de lista de colillas donde el usuario selecciona la columna para reemplazar en la primera y la columna para reemplazar en la segunda. ¿Es este enfoque más adecuado?

Re: Cambiador de columnas aplicado a todos los informes abiertos

Creo que podría ser un poco más fácil. No tengo tiempo para escribir una solución adecuada, pero a continuación hay una idea de cómo abordaría esto (use el conmutador de columnas para cambiar las columnas que crea en la llamada a la función + "Pedir perdón, no permiso"). Todavía tiene cosas codificadas, pero volveré a él más tarde hoy o mañana y lo haré más sólido ya que este es un problema interesante.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Probe.jmp");
dt << Clear Row States;

New Window("",
	Lineup box(N Col(2),
		dist = dt << Distribution(Continuous Distribution(Column(:DELL_RPNBR))),
		dist2 = dt << Distribution(Continuous Distribution(Column(:DELW_M1))),
		gb1 = dt << Graph Builder(
			Size(528, 448),
			Show Control Panel(0),
			Variables(X(:Site), Y(:Lot ID)),
			Elements(Points(X, Y, Legend(3)))
		),	
		gb2 = dt << Graph Builder(
			Size(523, 454),
			Show Control Panel(0),
			Variables(X(:DELW_M1), Y(:DELL_RPNBR)),
			Elements(Points(X, Y, Legend(3)))
		)
	)
);

nw = New Window("",
	H List Box(
		Lineup Box(N Col(2),
			Panel Box("Select Column to Change",
				fcs1 = Filter Col Selector(dt, << Set Max Selected(1))
			),
			Panel Box("Select New Column",
				fcs2 = Filter Col Selector(dt, << Set Max Selected(1))
			)
		),
		Panel Box("Action",
			Button Box("Change Columns"),
			Button Box("Cancel"),
		)
	)
);

update_reports = function({dt, report_list, old_col, new_col}, {Default Local},
	nw_switcher = New Window("", << Window View("Invisible"),
		ref_colswitcher = dt << Column Switcher(:DELL_RPNBR, {:DELW_SICR, :DELL_RPNBR});
	);
	wait(0);

	For Each({report}, report_list,
		Try(ref_colswitcher << Link Platform(report));
	);
	wait(0);
	
	nw_switcher[ListBoxBox(1)] << Set Selected(1);
	nw_switcher << Close Window;
	
);

reports = Eval List({dist, dist2, gb1, gb2});

update_reports(dt, reports, "a", "b");

Re: Cambiador de columnas aplicado a todos los informes abiertos

Parece haber algunos errores diferentes/interacciones extrañas que hacen que esto sea más difícil de lo que pensaba y por eso el código es muy confuso, pero parece funcionar en algún nivel.

Names Default To Here(1);

get_reports_for_datatable = function({dt}, {Default Local},
	valid_reports = {};
	
	// This might need improvements
	report_windows = Get Window List(Type("Reports"));
	
	For Each({report_window}, report_windows,
		Try(
			cur_analytic_layer = report_window[OutlineBox(1)] << Get Scriptable Object;
			cur_dt = cur_analytic_layer << Get Data Table;
			If(cur_dt == dt,
				Insert Into(valid_reports, cur_analytic_layer);
			);
		,
			show(exception_msg);
		);
	);
	return(valid_reports);
);

// I would use function, but there seem to be some bugs 
swap_report_columns = Expr(

	Eval(EvalExpr(
		nw_switcher = New Window("Switcher", << Window View("Invisible"),
			vlb2 = V List Box(
				ref_colswitcher2 = dt << Column Switcher(Expr(NameExpr(AsColumn(dt, old_col))),
					{Expr(NameExpr(AsColumn(dt, old_col))), Expr(NameExpr(AsColumn(dt, new_col)))}
				)
			)
		);
	));
	
	Batch Interactive(1);
	For Each({report, idx}, report_list,
		//report = report_list[2]
		
		nw1 = New Window("", << Window View("Invisible"),
			ref_colswitcher1 = dt << Column Switcher(Expr(NameExpr(AsColumn(dt, old_col))),
				{Expr(NameExpr(AsColumn(dt, old_col))), Expr(NameExpr(AsColumn(dt, new_col)))}
			)
		);
		
		lc = Log Capture(ref_colswitcher1 << Link Platform(report));
		ref_colswitcher1 << Remove Column Switcher;
		nw1 << Close Window;
		
		If(Is Missing(lc),
			Log Capture(
				Try(ref_colswitcher2 << Link Platform(report));
			);
		);
		
		wait(0);
	);
	Batch Interactive(0);
	Try(vlb2[ListBoxBox(1)] << Set Selected(2));
	
	wait(0);
	ref_colswitcher2 << Remove Column Switcher;
	
	Caption(remove);

	nw_switcher << Close Window;	
);

swap_columns = Expr(
	nw = New Window("Swap report columns", << Type("Launcher"),
		window:dt = Current Data Table(),
		H List Box(
			Lineup Box(N Col(2),
				Panel Box("Select Column to Change",
					fcs1 = Filter Col Selector(dt, << Set Max Selected(1))
				),
				Panel Box("Select New Column",
					fcs2 = Filter Col Selector(dt, << Set Max Selected(1))
				)
			),
			Panel Box("Action",
				Button Box("Change Columns",
					report_list = get_reports_for_datatable(dt);
					old_col = (fcs1 << get selected)[1];
					new_col = (fcs2 << get selected)[1];
					Try(swap_report_columns);
				),
				Button Box("Cancel",
					fcs1 << close window;
				),
			)
		)
	);
);

dt = Open("$SAMPLE_DATA/Probe.jmp");
dt << Clear Row States;

dist = dt << Distribution(Continuous Distribution(Column(:DELL_RPNBR)));
dist2 = dt << Distribution(Continuous Distribution(Column(:DELW_M1)));

gb1 = dt << Graph Builder(
	Size(528, 448),
	Show Control Panel(0),
	Variables(X(:Site), Y(:Lot ID)),
	Elements(Points(X, Y, Legend(3)))
);
gb2 = dt << Graph Builder(
	Size(523, 454),
	Show Control Panel(0),
	Variables(X(:DELW_M1), Y(:DELL_RPNBR)),
	Elements(Points(X, Y, Legend(3)))
);

swap_columns;

Write();