734298_de-DE

liliconcom

Spaltenumschalter auf alle geöffneten Berichte angewendet

Hallo Leute,

Ich versuche, ein Skript zu schreiben, um den Spaltenumschalter auf alle geöffneten Berichte anzuwenden. Bitte führen Sie mich

dt = Current data Table();
//Get all Open reports
wList = Get Window List( Type( "Reports" ) );

//Get Column to replace and column to replace with
win = New Window( "Set a Value",
	<Bitte geben Sie eine Anleitung zur Durchführung dieser Aktion an. Dank im VorausAutomatisierung und Skripterstellung

Betreff: Spaltenumschalter auf alle geöffneten Berichte angewendet

Wie möchten Sie Col List Box verwenden? Column Switcher erfordert, dass Sie über eine einzelne Spalte verfügen, die dann in eine andere Spalte geändert wird (basierend auf der Spaltenliste im Column Switcher), und diese Spalte sollte zu Beginn in allen Berichten gleich sein.

Betreff: Spaltenumschalter auf alle geöffneten Berichte angewendet

@jthi , mein Fehler, es tut mir leid. Ich denke, anstelle eines Spaltenumschalters ist es einfacher, zwei colList-Felder zu haben, in denen der Benutzer die zu ersetzende Spalte im ersten und die zu ersetzende Spalte im zweiten auswählt. Ist dieser Ansatz besser geeignet?

Betreff: Spaltenumschalter auf alle geöffneten Berichte angewendet

Ich denke, das könnte etwas einfacher sein. Ich habe keine Zeit, die richtige Lösung zu schreiben, aber unten finden Sie eine Idee, wie ich das angehen würde (verwenden Sie den Spaltenumschalter, um Spalten zu ändern, die Sie beim Funktionsaufruf erstellen + „Bitten Sie um Verzeihung, nicht um Erlaubnis“). Es enthält immer noch hartcodierte Dinge, aber ich werde später heute oder morgen darauf zurückkommen und es robuster machen, da es sich um ein interessantes Problem handelt.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Probe.jmp");
dt << Clear Row States;

New Window("",
	Lineup box(N Col(2),
		dist = dt << Distribution(Continuous Distribution(Column(:DELL_RPNBR))),
		dist2 = dt << Distribution(Continuous Distribution(Column(:DELW_M1))),
		gb1 = dt << Graph Builder(
			Size(528, 448),
			Show Control Panel(0),
			Variables(X(:Site), Y(:Lot ID)),
			Elements(Points(X, Y, Legend(3)))
		),	
		gb2 = dt << Graph Builder(
			Size(523, 454),
			Show Control Panel(0),
			Variables(X(:DELW_M1), Y(:DELL_RPNBR)),
			Elements(Points(X, Y, Legend(3)))
		)
	)
);

nw = New Window("",
	H List Box(
		Lineup Box(N Col(2),
			Panel Box("Select Column to Change",
				fcs1 = Filter Col Selector(dt, << Set Max Selected(1))
			),
			Panel Box("Select New Column",
				fcs2 = Filter Col Selector(dt, << Set Max Selected(1))
			)
		),
		Panel Box("Action",
			Button Box("Change Columns"),
			Button Box("Cancel"),
		)
	)
);

update_reports = function({dt, report_list, old_col, new_col}, {Default Local},
	nw_switcher = New Window("", << Window View("Invisible"),
		ref_colswitcher = dt << Column Switcher(:DELL_RPNBR, {:DELW_SICR, :DELL_RPNBR});
	);
	wait(0);

	For Each({report}, report_list,
		Try(ref_colswitcher << Link Platform(report));
	);
	wait(0);
	
	nw_switcher[ListBoxBox(1)] << Set Selected(1);
	nw_switcher << Close Window;
	
);

reports = Eval List({dist, dist2, gb1, gb2});

update_reports(dt, reports, "a", "b");

Betreff: Spaltenumschalter auf alle geöffneten Berichte angewendet

Es scheint ein paar verschiedene Fehler/seltsame Interaktionen zu geben, die das Ganze schwieriger machen, als ich dachte, und deshalb ist der Code sehr chaotisch, aber er scheint auf einer bestimmten Ebene zu funktionieren

Names Default To Here(1);

get_reports_for_datatable = function({dt}, {Default Local},
	valid_reports = {};
	
	// This might need improvements
	report_windows = Get Window List(Type("Reports"));
	
	For Each({report_window}, report_windows,
		Try(
			cur_analytic_layer = report_window[OutlineBox(1)] << Get Scriptable Object;
			cur_dt = cur_analytic_layer << Get Data Table;
			If(cur_dt == dt,
				Insert Into(valid_reports, cur_analytic_layer);
			);
		,
			show(exception_msg);
		);
	);
	return(valid_reports);
);

// I would use function, but there seem to be some bugs 
swap_report_columns = Expr(

	Eval(EvalExpr(
		nw_switcher = New Window("Switcher", << Window View("Invisible"),
			vlb2 = V List Box(
				ref_colswitcher2 = dt << Column Switcher(Expr(NameExpr(AsColumn(dt, old_col))),
					{Expr(NameExpr(AsColumn(dt, old_col))), Expr(NameExpr(AsColumn(dt, new_col)))}
				)
			)
		);
	));
	
	Batch Interactive(1);
	For Each({report, idx}, report_list,
		//report = report_list[2]
		
		nw1 = New Window("", << Window View("Invisible"),
			ref_colswitcher1 = dt << Column Switcher(Expr(NameExpr(AsColumn(dt, old_col))),
				{Expr(NameExpr(AsColumn(dt, old_col))), Expr(NameExpr(AsColumn(dt, new_col)))}
			)
		);
		
		lc = Log Capture(ref_colswitcher1 << Link Platform(report));
		ref_colswitcher1 << Remove Column Switcher;
		nw1 << Close Window;
		
		If(Is Missing(lc),
			Log Capture(
				Try(ref_colswitcher2 << Link Platform(report));
			);
		);
		
		wait(0);
	);
	Batch Interactive(0);
	Try(vlb2[ListBoxBox(1)] << Set Selected(2));
	
	wait(0);
	ref_colswitcher2 << Remove Column Switcher;
	
	Caption(remove);

	nw_switcher << Close Window;	
);

swap_columns = Expr(
	nw = New Window("Swap report columns", << Type("Launcher"),
		window:dt = Current Data Table(),
		H List Box(
			Lineup Box(N Col(2),
				Panel Box("Select Column to Change",
					fcs1 = Filter Col Selector(dt, << Set Max Selected(1))
				),
				Panel Box("Select New Column",
					fcs2 = Filter Col Selector(dt, << Set Max Selected(1))
				)
			),
			Panel Box("Action",
				Button Box("Change Columns",
					report_list = get_reports_for_datatable(dt);
					old_col = (fcs1 << get selected)[1];
					new_col = (fcs2 << get selected)[1];
					Try(swap_report_columns);
				),
				Button Box("Cancel",
					fcs1 << close window;
				),
			)
		)
	);
);

dt = Open("$SAMPLE_DATA/Probe.jmp");
dt << Clear Row States;

dist = dt << Distribution(Continuous Distribution(Column(:DELL_RPNBR)));
dist2 = dt << Distribution(Continuous Distribution(Column(:DELW_M1)));

gb1 = dt << Graph Builder(
	Size(528, 448),
	Show Control Panel(0),
	Variables(X(:Site), Y(:Lot ID)),
	Elements(Points(X, Y, Legend(3)))
);
gb2 = dt << Graph Builder(
	Size(523, 454),
	Show Control Panel(0),
	Variables(X(:DELW_M1), Y(:DELL_RPNBR)),
	Elements(Points(X, Y, Legend(3)))
);

swap_columns;

Write();