732535_zh-CN

liliconcom

如何在 JMP JSL 中将 :column_name 替换为变量？

@jthi你能帮我修复下面的代码错误吗？如何使用变量以正确的方式替换：列名？非常感谢你的帮助。

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

自动化和脚本编写视窗回复：如何在 JMP JSL 中将 :column_name 替换为变量？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

有时您需要使用“作为列”。有时只是“列”。

回复：如何在 JMP JSL 中用变量替换 :column_name？

如何替换它取决于用例，在您的情况下，按照@pmroz建议使用 AsColumn 是最简单的选择。

链接很少

• Column() vs As Column() vs datable:column vs dt:As name("column")
• 在 JSL 中引用列
• JSL 语法参考 - 作为列
• JSL 语法参考 - Column()

下面是一些其他选项，但它们确实需要更多脚本，这在这种情况下通常是不必要的

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

hvar = "height";
gvar = "sex";

// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));

// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);

// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
	Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
	Expr(groupcol), Name Expr(AsColumn(gvar)),
	Expr(numcol), Name Expr(AsColumn(hvar))
));

// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));

show(std, std2, std3, std4);

回复：如何在 JMP JSL 中用变量替换 :column_name？

太感谢了。这非常有效。