732535_es-ES

liliconcom

¿Cómo reemplazar: nombre_columna con variable en JMP JSL?

@jthi ¿Puedes ayudarme a corregir el siguiente error de código? ¿Cómo utilizar la variable para reemplazar: nombre de columna de la forma correcta? Muchas gracias por tu ayuda.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

Automatización y secuencias de comandosventanasRe: ¿Cómo reemplazar :column_name con variable en JMP JSL?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

A veces es necesario utilizar "como columna". A veces simplemente "columna".

Re: ¿Cómo reemplazar :column_name con variable en JMP JSL?

La forma de reemplazarlo depende del caso de uso; en su caso, usar AsColumn como sugirió @pmroz es la opción más sencilla.

Pocos enlaces

• Columna() vs As Columna() vs datable:columna vs dt:Como nombre("columna")
• Hacer referencia a una columna en JSL
• Referencia de sintaxis JSL: como columna
• Referencia de sintaxis JSL: columna()

A continuación se muestran algunas otras opciones, pero requieren más secuencias de comandos, lo que suele ser innecesario en este tipo de casos.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

hvar = "height";
gvar = "sex";

// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));

// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);

// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
	Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
	Expr(groupcol), Name Expr(AsColumn(gvar)),
	Expr(numcol), Name Expr(AsColumn(hvar))
));

// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));

show(std, std2, std3, std4);

Re: ¿Cómo reemplazar :column_name con variable en JMP JSL?

Muchas gracias. Esto funciona muy bien.