732535_ja-JP

liliconcom

JMP JSL で :column_name を変数に置き換える方法は?

@jthi以下のコードエラーを修正するのを手伝ってもらえますか？変数を使用して :column 名を正しい方法で置き換えるにはどうすればよいですか?手伝ってくれてどうもありがとう。

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(Excluded( Row State() ) == 0 & column(gvar) =="M", column(hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

自動化とスクリプト作成ウィンドウズRe: JMP JSL で :column_name を変数に置き換える方法は?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
hvar = "height";
gvar = "sex";

std = Col Std Dev( if(!Excluded( Row State() ) & as column(dt, gvar) == "M", as column(dt, hvar) ));

//std = Col Std Dev( if(Excluded( Row State() ) == 0 & :sex =="M", column(hvar) ));
show(std);

場合によっては、「列として」を使用する必要があります。単に「コラム」の場合もあります。

Re: JMP JSL で :column_name を変数に置き換える方法は?

それを置き換える方法はユースケースによって異なります。あなたの場合、 @pmrozが提案したようにAsColumnを使用するのが最も簡単なオプションです。

リンクが少ない

• Column() vs As Column() vs dataable:column vs dt:As name("column")
• JSL での列の参照
• JSL 構文リファレンス - 列として
• JSL 構文リファレンス - Column()

以下にその他のオプションをいくつか示しますが、さらに多くのスクリプトが必要になりますが、この種のケースでは通常は不要です。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

hvar = "height";
gvar = "sex";

// As Column
std = Col Std Dev(If(!Excluded(Row State()) & As Column(dt, gvar) == "M", As Column(dt, hvar)));

// Data table subscripting
// https://community.jmp.com/t5/Uncharted/Data-table-subscripting/ba-p/21013
rows_of_interest = dt << Get Rows Where(Excluded(Row State()) == 0 & Column(gvar)[] == "M");
std2 = Std Dev(dt[rows_of_interest, hvar]);

// Build and evaluate expression
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
std3 = Eval(Substitute(
	Expr(Col Std Dev(If(!Excluded(Row State()) & groupcol == "M", numcol))),
	Expr(groupcol), Name Expr(AsColumn(gvar)),
	Expr(numcol), Name Expr(AsColumn(hvar))
));

// Check
std4 = Col Std Dev(If(Excluded(Row State()) == 0 & :sex == "M", :height));

show(std, std2, std3, std4);

Re: JMP JSL で :column_name を変数に置き換える方法は?

どうもありがとう。これは非常にうまく機能します。