730823_zh-TW

liliconcom

即使為空，如何強制熱圖顯示所有行/列？

即使資料過濾器消除了其中一些行，是否有技巧可以使熱圖顯示所有行？

考慮針對「Big Class.jmp」所建立的這個圖：

Graph Builder(
	Size( 673, 714 ),
	Variables( X( :sex ), Y( :age ) ),
	Elements( Heatmap( X, Y, Legend( 2 ) ) ),
	Local Data Filter(
		Add Filter( columns( :height ), Where( :height >= 65.137 & :height <= 70 ) )
	)
)

如果您查看此圖，您會發現 13 歲這一行完全缺失。我意識到本地資料過濾器刪除了 13 歲的所有條目，但是有沒有一個好方法可以使 13 歲的行仍然顯示，即作為全白行。

數據探索和視覺化回覆：即使為空，如何強制熱圖顯示所有行/列？

將 Age 列從 Ordinal 變更為 Continuous，您將獲得所需的完整 Y 軸

回覆：即使為空，如何強制熱圖顯示所有行/列？

遺憾的是，在我們的例子中，該變數確實是名義上的，因此這不適用於我們的特定問題。

回覆：即使為空，如何強制熱圖顯示所有行/列？

您可以建立一個包含所有類別的簡單形狀地圖，然後將計數列拖曳到地圖上，它將顯示一個分區統計圖，即熱圖。您必須建立一個新列，它是當前 X 和 Y 變數的組合，它將指向地圖中的特定元素，但它將執行您想要的操作。

回覆：即使為空，如何強制熱圖顯示所有行/列？

這聽起來好像可行。我閱讀了有關形狀圖的文檔，但我不確定我是否理解它們。我如何製作你所描述的地圖？我該如何加載它？

回覆：即使為空，如何強制熱圖顯示所有行/列？

地圖可以儲存到

C:\Users\\AppData\Roaming\SAS\JMP\Maps

或者，可以將它們儲存到 $TEMP 中，然後透過將位置傳遞給圖形產生器來引用。我花時間將您的範例擴展為創建形狀圖檔案的腳本，並將它們保存到 $TEMP，最後繪製資料圖

Names Default To Here( 1 );

dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );


// Create the Shape Map tables
dtXY = New Table( "Class-XY",
	New Column( "Shape", modeling type( Ordinal ) ),
	New Column( "Part", Modeling type( Ordinal ) ),
	New Column( "X" ),
	New Column( "Y" )
);

dtName = New Table( "Class-Name",
	New Column( "Shape", Modeling type( Ordinal ) ),
	New Column( "Cell", character )
);
dtName:Cell << set property( "Map Role", Map Role( Shape Name Definition ) );

// Populate the tables
ages = Associative Array( dt:Age << get values ) << get keys;
sexes = Associative Array( dt:Sex << get values ) << get keys;
ID = 0;
For Each( {sex, xi}, sexes,
	For Each( {age, yi}, ages,
		theName = Char( sex ) || Char( age );show(thename);
		ID++;
		dtName << add rows( 1 );
		dtName:Shape[N Rows( dtName )] = ID;
		dtName:Cell[N Rows( dtName )] = theName;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi;
		dtXY:Y[N Rows( dtXY )] = yi;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi;
		dtXY:Y[N Rows( dtXY )] = yi + 1;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi + 1;
		dtXY:Y[N Rows( dtXY )] = yi + 1;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi + 1;
		dtXY:Y[N Rows( dtXY )] = yi;
	)
);

// Save the Map tables to the Temp Directory
close( dtXY, Save( "$temp\mycell-XY.jmp" ));
close( dtName, Save( "$temp\mycell-Name.jmp") );

// Add the concatenated Sex/Age column to the data table
dt << New Column( "Cell", character, set each value( :Sex || Char(:Age)));

// Create the Heat map using the Shape Map
gb = Graph Builder(
	Size( 522, 456 ),
	Show Control Panel( 0 ),
	Variables(
		Color( :height ),
		Shape(
			:Cell,
			Set Shape File( "$TEMP/mycell-Name.jmp" )
		)
	),
	Elements(
		Map Shapes(
			Legend( 3 ),
			Summary Statistic( "N" ),
			Show Missing Shapes( 1 )
		)
	),
	Local Data Filter(
		Add Filter( columns( :height ), Where( :height >= 65.137 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"",
			ScaleBox,
			{Format( "Fixed Dec", 12, 0 ), Min( -2.44489795918367 ),
			Max( 6.44489795918367 ), Inc( 1 ), Minor Ticks( 0 ),
			Label Row(
				{Automatic Font Size( 0 ), Automatic Tick Marks( 0 ),
				Show Major Labels( 0 ), Show Major Ticks( 0 ), Show Minor Ticks( 0 )
				}
			)}
		),
		Dispatch(
			{},
			"",
			ScaleBox( 2 ),
			{Min( -0.0843053453846471 ), Max( 7.18430534538465 ), Inc( 1 ),
			Minor Ticks( 0 ), Label Row(
				{Automatic Font Size( 0 ), Automatic Tick Marks( 0 ),
				Show Major Labels( 0 ), Show Major Ticks( 0 ), Show Minor Ticks( 0 )
				}
			)}
		),
		Dispatch( {}, "400", LegendBox, {Set Title( "Count" )} )
	)
);

// Add the cell labelling to the graph

Report( gb )[FrameBox( 1 )] << Add Graphics script(
	For Each( {sex, xi}, sexes,
		Eval( Eval Expr( Text( Center Justified, {Expr( xi + .5 ), .5}, Expr( sex ) ) ) )
	);
	For Each( {age, yi}, ages,
		Eval( Eval Expr( Text( Center Justified, {.5,Expr( yi + .5 ) }, Expr( char(age) ) ) ) )
	);
);

回覆：即使為空，如何強制熱圖顯示所有行/列？

有時啟用“顯示排除的行”也可能有效。若要啟用“顯示排除的行”，請在按一下紅色三角形時按住 Shift 鍵

但這最終可能會顯示一些您可能不希望看到的行（例如，您可以從資料表中排除行）。

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(626, 662),
	Show Control Panel(0),
	Ignore Platform Preferences(1),
	Show Excluded Rows(1),
	Variables(X(:sex), Y(:age)),
	Elements(Heatmap(X, Y, Legend(2))),
	Local Data Filter(Add Filter(columns(:height), Where(:height >= 65.137)))
);

根據您的數據，形狀檔案可能是一個好主意，就像吉姆已經建議的那樣。

回覆：即使為空，如何強制熱圖顯示所有行/列？

雅爾莫,

您的回答顯然是更好的選擇，但是，互動式選擇

顯示排除的行

沒有作為選項出現在我的選擇清單中

該選項確實出現在我的偏好設定中。你知道問題是什麼嗎？

回覆：即使為空，如何強制熱圖顯示所有行/列？

單擊紅色小三角選單時，必須按住 SHIFT 鍵（JMP 在紅色小三角選單中幾乎沒有這些「隱藏」功能）。我在 Julian 的一些帖子中了解到了這一點，例如https://community.jmp.com/t5/Discussions/Exclude-and-Show-Data-in-Fit-Y-by-X-and-Graph-Builder /mp/50457/highlight/true#M28685

在圖形產生器中繪製排除和未隱藏的資料點