730823_zh-CN

liliconcom

即使为空，如何强制热图显示所有行/列？

即使数据过滤器消除了其中一些行，是否有技巧可以使热图显示所有行？

考虑针对“Big Class.jmp”创建的这个图：

Graph Builder(
	Size( 673, 714 ),
	Variables( X( :sex ), Y( :age ) ),
	Elements( Heatmap( X, Y, Legend( 2 ) ) ),
	Local Data Filter(
		Add Filter( columns( :height ), Where( :height >= 65.137 & :height <= 70 ) )
	)
)

如果您查看此图，您会发现 13 岁这一行完全缺失。我意识到本地数据过滤器删除了 13 岁的所有条目，但是有没有一个好方法可以使 13 岁的行仍然显示，即作为全白行。

数据探索和可视化回复：即使为空，如何强制热图显示所有行/列？

将 Age 列从 Ordinal 更改为 Continuous，您将获得所需的完整 Y 轴

回复：即使为空，如何强制热图显示所有行/列？

遗憾的是，在我们的例子中，该变量确实是名义上的，因此这不适用于我们的特定问题。

回复：即使为空，如何强制热图显示所有行/列？

您可以创建一个包含所有类别的简单形状地图，然后将计数列拖到地图上，它将显示一个分区统计图，即热图。您必须创建一个新列，它是当前 X 和 Y 变量的组合，它将指向地图中的特定元素，但它将执行您想要的操作。

回复：即使为空，如何强制热图显示所有行/列？

这听起来好像可行。我阅读了有关形状图的文档，但我不确定我是否理解它们。我如何制作你所描述的地图？我该如何加载它？

回复：即使为空，如何强制热图显示所有行/列？

地图可以保存到

C:\Users\\AppData\Roaming\SAS\JMP\Maps

或者，可以将它们保存到 $TEMP 中，然后通过将位置传递给图形生成器来引用。我花时间将您的示例扩展为创建形状图文件的脚本，并将它们保存到 $TEMP，最后绘制数据图

Names Default To Here( 1 );

dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );


// Create the Shape Map tables
dtXY = New Table( "Class-XY",
	New Column( "Shape", modeling type( Ordinal ) ),
	New Column( "Part", Modeling type( Ordinal ) ),
	New Column( "X" ),
	New Column( "Y" )
);

dtName = New Table( "Class-Name",
	New Column( "Shape", Modeling type( Ordinal ) ),
	New Column( "Cell", character )
);
dtName:Cell << set property( "Map Role", Map Role( Shape Name Definition ) );

// Populate the tables
ages = Associative Array( dt:Age << get values ) << get keys;
sexes = Associative Array( dt:Sex << get values ) << get keys;
ID = 0;
For Each( {sex, xi}, sexes,
	For Each( {age, yi}, ages,
		theName = Char( sex ) || Char( age );show(thename);
		ID++;
		dtName << add rows( 1 );
		dtName:Shape[N Rows( dtName )] = ID;
		dtName:Cell[N Rows( dtName )] = theName;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi;
		dtXY:Y[N Rows( dtXY )] = yi;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi;
		dtXY:Y[N Rows( dtXY )] = yi + 1;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi + 1;
		dtXY:Y[N Rows( dtXY )] = yi + 1;
		dtXY << add rows( 1 );
		dtXY:Shape[N Rows( dtXY )] = ID;
		dtXY:Part[N Rows( dtXY )] = ID;
		dtXY:X[N Rows( dtXY )] = xi + 1;
		dtXY:Y[N Rows( dtXY )] = yi;
	)
);

// Save the Map tables to the Temp Directory
close( dtXY, Save( "$temp\mycell-XY.jmp" ));
close( dtName, Save( "$temp\mycell-Name.jmp") );

// Add the concatenated Sex/Age column to the data table
dt << New Column( "Cell", character, set each value( :Sex || Char(:Age)));

// Create the Heat map using the Shape Map
gb = Graph Builder(
	Size( 522, 456 ),
	Show Control Panel( 0 ),
	Variables(
		Color( :height ),
		Shape(
			:Cell,
			Set Shape File( "$TEMP/mycell-Name.jmp" )
		)
	),
	Elements(
		Map Shapes(
			Legend( 3 ),
			Summary Statistic( "N" ),
			Show Missing Shapes( 1 )
		)
	),
	Local Data Filter(
		Add Filter( columns( :height ), Where( :height >= 65.137 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"",
			ScaleBox,
			{Format( "Fixed Dec", 12, 0 ), Min( -2.44489795918367 ),
			Max( 6.44489795918367 ), Inc( 1 ), Minor Ticks( 0 ),
			Label Row(
				{Automatic Font Size( 0 ), Automatic Tick Marks( 0 ),
				Show Major Labels( 0 ), Show Major Ticks( 0 ), Show Minor Ticks( 0 )
				}
			)}
		),
		Dispatch(
			{},
			"",
			ScaleBox( 2 ),
			{Min( -0.0843053453846471 ), Max( 7.18430534538465 ), Inc( 1 ),
			Minor Ticks( 0 ), Label Row(
				{Automatic Font Size( 0 ), Automatic Tick Marks( 0 ),
				Show Major Labels( 0 ), Show Major Ticks( 0 ), Show Minor Ticks( 0 )
				}
			)}
		),
		Dispatch( {}, "400", LegendBox, {Set Title( "Count" )} )
	)
);

// Add the cell labelling to the graph

Report( gb )[FrameBox( 1 )] << Add Graphics script(
	For Each( {sex, xi}, sexes,
		Eval( Eval Expr( Text( Center Justified, {Expr( xi + .5 ), .5}, Expr( sex ) ) ) )
	);
	For Each( {age, yi}, ages,
		Eval( Eval Expr( Text( Center Justified, {.5,Expr( yi + .5 ) }, Expr( char(age) ) ) ) )
	);
);

回复：即使为空，如何强制热图显示所有行/列？

有时启用“显示排除的行”也可能有效。要启用“显示排除的行”，请在单击红色三角形时按住 Shift 键

但这最终可能会显示一些您可能不希望看到的行（例如，您可以从数据表中排除行）。

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(626, 662),
	Show Control Panel(0),
	Ignore Platform Preferences(1),
	Show Excluded Rows(1),
	Variables(X(:sex), Y(:age)),
	Elements(Heatmap(X, Y, Legend(2))),
	Local Data Filter(Add Filter(columns(:height), Where(:height >= 65.137)))
);

根据您的数据，形状文件可能是一个好主意，就像吉姆已经建议的那样。

回复：即使为空，如何强制热图显示所有行/列？

雅尔莫,

您的回答显然是更好的选择，但是，交互式选择

显示排除的行

没有作为选项出现在我的选择列表中

该选项确实出现在我的偏好设置中。你知道问题是什么吗？

回复：即使为空，如何强制热图显示所有行/列？

单击红色小三角菜单时，必须按住 SHIFT 键（JMP 在红色小三角菜单中几乎没有这些“隐藏”功能）。我在 Julian 的一些帖子中了解到了这一点，例如https://community.jmp.com/t5/Discussions/Exclude-and-Show-Data-in-Fit-Y-by-X-and-Graph-Builder /mp/50457/highlight/true#M28685

在图形生成器中绘制排除和未隐藏的数据点