730471_zh-TW

liliconcom

如何使用製表函數處理原始資料而不是匯總統計？

親愛的社區，

如何使用製表函數處理連續變數的實際資料而不是匯總統計量？

或者換句話說：有沒有辦法建立一個具有多個層級的列標題和行標題但使用原始資料的表格？

謝謝，

T

基礎資料分析與建模視窗回覆：如何使用原始資料的製表函數而不是匯總統計？

我不清楚你想做什麼。但聽起來您想要避免的是表格行和列標題必須是名義變數的要求（如果您將連續變數放入任一位置，JMP 會將其分箱以使其成為名義變數）。如果這是您的問題，那麼我認為您想要堆疊或分割列來建立新的資料表，而不是使用製表平台。聽起來您想保留所有原始數據，這意味著重組資料集而不對其進行匯總。我不認為製表是做到這一點的方法。

回覆：如何使用原始資料製表函數而不是匯總統計？

如果計算出資料表中只有一行填入儲存​​格，則每個儲存格中的資料可以是原始值。這是一個例子：

Names Default To Here( 1 );

dt = New Table( "School Report",
	New Column( "Name", character ),
	New Column( "Class", character ),
	New Column( "Semester", character ),
	New Column( "Test", modeling type( ordinal ) ),
	New Column( "Score" )
);

nameList={"Jim","Nancy","Edward"};
classList={"Math","Science","Civics","History","Phys Ed"};
semesterList={"Fall","Spring","Summer"};
testList={1,2,3,4,5};

For Each( {Name}, nameList,
	For Each( {Class}, classList,
		For Each( {Semester}, semesterList,
			For Each( {Test}, testList,
				dt << add rows(1);
				dt:Name[nrows(dt)] = Name;
				dt:Class[nrows(dt)] = Class;
				dt:Semester[nrows(dt)] = Semester;
				dt:Test[nrows(dt)] = Test;
				dt:Score[nrows(dt)] = Random Integer( 70,100);
			)
		)
	)
);

dt << Tabulate(
	Change Item Label( Statistics( Sum, "Score" ) ),
	Remove Column Label( Analysis Columns( Score ) ),
	Add Table(
		Column Table(
			Grouping Columns( :Semester, :Test ),
			Analysis Columns( :Score )
		),
		Row Table( Grouping Columns( :Name, :Class ) )
	)
);