730471_de-DE

liliconcom

Wie verwende ich die Tabellierungsfunktion mit Rohdaten anstelle von zusammenfassenden Statistiken?

Liebe Community,

Wie kann ich die Tabellierungsfunktion mit den tatsächlichen Daten einer kontinuierlichen Variablen und nicht mit einer zusammenfassenden Statistik verwenden?

Oder mit anderen Worten: Gibt es eine Möglichkeit, eine Tabelle mit Spalten- und Zeilenüberschriften auf mehreren Ebenen zu erstellen, aber die Rohdaten zu verwenden?

Danke,

T

Grundlegende Datenanalyse und ModellierungWindowsBetreff: Wie verwende ich die Tabellierungsfunktion mit Rohdaten anstelle von zusammenfassenden Statistiken?

Mir ist nicht klar, was Sie tun möchten. Aber es hört sich so an, als ob Sie die Anforderung vermeiden möchten, dass die Tabellenzeilen- und -spaltenüberschriften nominal sein müssen (wenn Sie an einer Stelle eine kontinuierliche Variable einfügen, wird JMP sie einordnen, um sie zu einer nominalen Variablen zu machen). Wenn das Ihr Problem ist, dann denke ich, dass Sie Spalten entweder stapeln oder teilen möchten, um eine neue Datentabelle zu erstellen, anstatt die Tabulatorplattform zu verwenden. Es hört sich so an, als ob Sie alle Rohdaten behalten möchten, was bedeutet, dass Sie den Datensatz umstrukturieren, ohne ihn zusammenzufassen. Ich glaube nicht, dass Tabellieren der richtige Weg ist.

Betreff: Wie verwende ich die Tabellierungsfunktion mit Rohdaten anstelle von zusammenfassenden Statistiken?

Die Daten in jeder Zelle können Rohwerte sein, wenn sich herausstellt, dass nur eine Zeile aus der Datentabelle die Zelle füllt. Hier ist ein Beispiel:

Names Default To Here( 1 );

dt = New Table( "School Report",
	New Column( "Name", character ),
	New Column( "Class", character ),
	New Column( "Semester", character ),
	New Column( "Test", modeling type( ordinal ) ),
	New Column( "Score" )
);

nameList={"Jim","Nancy","Edward"};
classList={"Math","Science","Civics","History","Phys Ed"};
semesterList={"Fall","Spring","Summer"};
testList={1,2,3,4,5};

For Each( {Name}, nameList,
	For Each( {Class}, classList,
		For Each( {Semester}, semesterList,
			For Each( {Test}, testList,
				dt << add rows(1);
				dt:Name[nrows(dt)] = Name;
				dt:Class[nrows(dt)] = Class;
				dt:Semester[nrows(dt)] = Semester;
				dt:Test[nrows(dt)] = Test;
				dt:Score[nrows(dt)] = Random Integer( 70,100);
			)
		)
	)
);

dt << Tabulate(
	Change Item Label( Statistics( Sum, "Score" ) ),
	Remove Column Label( Analysis Columns( Score ) ),
	Add Table(
		Column Table(
			Grouping Columns( :Semester, :Test ),
			Analysis Columns( :Score )
		),
		Row Table( Grouping Columns( :Name, :Class ) )
	)
);