730386_ja-JP

liliconcom

jslを使用してグラフビルダーにX変数を追加するにはどうすればよいですか

親愛なるみんな：

平行グラフを作成したい
X 軸はテーブルの列の一部です
jslを使った作成方法

また、変数（）を追加しようとしましたが、機能しません

ありがとう

自動化とスクリプト作成Re: jsl を使用して X 変数をグラフビルダーに追加するにはどうすればよいですか

<< 変数の追加は機能するはずですが、場合によってはより複雑になる可能性があります

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 448),
	Show Control Panel(0),
	Variables(X(:weight), X(:height, Position(1))),
	Elements(Parallel(X(1), X(2), Legend(9)))
);

wait(1); // for demo purposes

gb << Add Variable({:age, Role("X"), Position(1)});

Re: jsl を使用してグラフビルダーに X 変数を追加するにはどうすればいいですか?

ありがとう、

他に質問がある場合は、

これで、変数の追加を使用してグラフビルダーにX変数を追加できるようになりました。

しかし、要素の追加を使用してX変数（自動）を追加するための平行グラフに変更することはできません。

添付ファイルを参照してください

ありがとう

Names Default To Here(1);

dt=Current Data Table();

colnames=dt<< get column names( "character" );
remove from(colnames,nitems(colnames));
remove from(colnames,1);

variables_expr = Expr(Variables(X(:X__1)));

gb = dt << Graph Builder(
Size( 1854, 917 ),
 Show control Panel(0),
 Variables(X(:X__1)),
 Color( :color ),				
		Size( :Amt )
);

gb << inval;

For Each({x_col, idx}, colnames,
 Eval(EvalExpr(
  gb << Add Variable({Expr(Name Expr(As Column(dt, x_col))), Role("X"),position(1)})
 ));


);

<FONT color="#0000FF">// question</FONT>
<FONT color="#0000FF">gb << Add Element( 1, 1, {Type( "Parallel" ),Legend( 4 ),Combine Sets( 1 )} );</FONT>


gb << Update window;

Re: jsl を使用してグラフビルダーに X 変数を追加するにはどうすればいいですか?

パラレルプロットを手動で構築し、スクリプトをチェックすると

Graph Builder(
	Size(490, 448),
	Show Control Panel(0),
	Variables(
		X(:X__1),
		X(:X__2, Position(1)),
		X(:X__3, Position(1)),
		X(:X__4, Position(1)),
		X(:X__5, Position(1))
	),
	Elements(Parallel(X(1), X(2), X(3), X(4), X(5), Legend(18)))
)

そしてそれを自分のスクリプトと比較します（ビルドしてから赤い三角のメニューからスクリプトを取得します）

Graph Builder(
	Size(1854, 917),
	Show Control Panel(0),
	Variables(
		X(:X__1),
		X(:X__2, Position(1)),
		X(:X__3, Position(1)),
		X(:X__4, Position(1)),
		X(:X__5, Position(1))
	),
	Elements(
		Points(X(1), X(2), X(3), X(4), X(5), Legend(5)),
		Parallel(Legend(4), Combine Sets(1))
	)
)

大きな違いはほとんどありません。ポイントはまだ残っており、スクリプトで X() を定義していないだけです。

もしこれをやりたいのであれば、グラフビルダー式を作成し、<<変数の追加と<<要素の追加を使用せずに、より簡単に作成することをお勧めします。

Names Default To Here(1);

dt = Current Data Table();

colnames = dt << get column names("character");
Remove From(colnames, N Items(colnames));
Remove From(colnames, 1);

variables_expr = Expr(Variables(X(:X__1)));
parallel_expr = Expr(Parallel(X(1)));

For Each({colname, idx}, colnames,
	xpart = EvalExpr(X(Expr(NameExpr(AsColumn(dt, colname))), Position(1)));
	Insert Into(variables_expr, Name Expr(xpart));
	
	Eval(EvalExpr(
		Insert Into(parallel_expr, Name Expr(X(Expr(idx + 1))));
	));
);

Insert Into(parallel_expr, Name Expr(Legend(18)));
elements_expr = Expr(Elements());
InsertInto(elements_expr, NameExpr(parallel_expr));


gb = Eval(Substitute(
		Expr(dt << Graph Builder(
			Size(1854, 917),
			Show control Panel(0),
			_variables_,
			_elements_,
			Color(:color),
			Size(:Amt)
	)),
	Expr(_variables_), Name Expr(variables_expr),
	Expr(_elements_), Name Expr(elements_expr)
));