730386_fr-FR

liliconcom

Comment utiliser JSL pour ajouter une variable X à graphbuilder

Chers tous:

Je veux créer un graphique parallèle
L'axe X fait partie de la colonne du tableau
Comment créer en utilisant jsl

J'essaie aussi d'ajouter une variable() mais je ne peux pas fonctionner

merci

Automatisation et scriptsRe : Comment utiliser JSL pour ajouter une variable X à graphbuilder

<< Ajouter une variable devrait fonctionner mais certains cas peuvent être plus compliqués

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 448),
	Show Control Panel(0),
	Variables(X(:weight), X(:height, Position(1))),
	Elements(Parallel(X(1), X(2), Legend(9)))
);

wait(1); // for demo purposes

gb << Add Variable({:age, Role("X"), Position(1)});

Re : Comment utiliser JSL pour ajouter une variable X à GraphBuilder

Merci,

Vous avez d'autres questions,

Je peux maintenant utiliser Ajouter une variable pour ajouter des variables X au générateur de graphiques,

mais ne peut pas passer au graphique parallèle pour ajouter une variable X (auto) en utilisant Ajouter un élément

Veuillez vous référer à la pièce jointe

merci

Names Default To Here(1);

dt=Current Data Table();

colnames=dt<< get column names( "character" );
remove from(colnames,nitems(colnames));
remove from(colnames,1);

variables_expr = Expr(Variables(X(:X__1)));

gb = dt << Graph Builder(
Size( 1854, 917 ),
 Show control Panel(0),
 Variables(X(:X__1)),
 Color( :color ),				
		Size( :Amt )
);

gb << inval;

For Each({x_col, idx}, colnames,
 Eval(EvalExpr(
  gb << Add Variable({Expr(Name Expr(As Column(dt, x_col))), Role("X"),position(1)})
 ));


);

<FONT color="#0000FF">// question</FONT>
<FONT color="#0000FF">gb << Add Element( 1, 1, {Type( "Parallel" ),Legend( 4 ),Combine Sets( 1 )} );</FONT>


gb << Update window;

Re : Comment utiliser JSL pour ajouter une variable X à GraphBuilder

Si vous construisez l'intrigue parallèle à la main et vérifiez le script

Graph Builder(
	Size(490, 448),
	Show Control Panel(0),
	Variables(
		X(:X__1),
		X(:X__2, Position(1)),
		X(:X__3, Position(1)),
		X(:X__4, Position(1)),
		X(:X__5, Position(1))
	),
	Elements(Parallel(X(1), X(2), X(3), X(4), X(5), Legend(18)))
)

et comparez-le ensuite à votre script (construisez-le puis récupérez le script à partir du menu triangle rouge)

Graph Builder(
	Size(1854, 917),
	Show Control Panel(0),
	Variables(
		X(:X__1),
		X(:X__2, Position(1)),
		X(:X__3, Position(1)),
		X(:X__4, Position(1)),
		X(:X__5, Position(1))
	),
	Elements(
		Points(X(1), X(2), X(3), X(4), X(5), Legend(5)),
		Parallel(Legend(4), Combine Sets(1))
	)
)

Il y a quelques grandes différences : il vous reste encore des points et vous n'avez tout simplement pas défini X() dans votre script.

Si c'est ce que vous souhaitez faire, je vous suggère de créer l'expression du générateur de graphiques et de ne pas utiliser << Ajouter une variable et << Ajouter un élément, car cela peut être plus simple.

Names Default To Here(1);

dt = Current Data Table();

colnames = dt << get column names("character");
Remove From(colnames, N Items(colnames));
Remove From(colnames, 1);

variables_expr = Expr(Variables(X(:X__1)));
parallel_expr = Expr(Parallel(X(1)));

For Each({colname, idx}, colnames,
	xpart = EvalExpr(X(Expr(NameExpr(AsColumn(dt, colname))), Position(1)));
	Insert Into(variables_expr, Name Expr(xpart));
	
	Eval(EvalExpr(
		Insert Into(parallel_expr, Name Expr(X(Expr(idx + 1))));
	));
);

Insert Into(parallel_expr, Name Expr(Legend(18)));
elements_expr = Expr(Elements());
InsertInto(elements_expr, NameExpr(parallel_expr));


gb = Eval(Substitute(
		Expr(dt << Graph Builder(
			Size(1854, 917),
			Show control Panel(0),
			_variables_,
			_elements_,
			Color(:color),
			Size(:Amt)
	)),
	Expr(_variables_), Name Expr(variables_expr),
	Expr(_elements_), Name Expr(elements_expr)
));