730241_es-ES

liliconcom

¿Cómo procedo después de seleccionar algo de un cuadro combinado?

 //fruit is a row in my table
 nw = New window ("Select fruit",
 cb = combo box ("apple", "Mango", "Banana")
 cb << Set Selected,
 << Set Width (20),
 //Here I select apple
 Button Box ("OK",
 	table1 << SelectWhere(:fruit!=apple) << Delete Rows;
 ) )

¿Cómo procedo con los análisis seleccionando únicamente los datos correspondientes a 'manzana'?

Esto es lo que quiero de este código:

1, primero hago un cuadro combinado

2. Seleccione manzana en el cuadro combinado.

3. Una vez que hago clic en "Aceptar", debería eliminar las otras filas y dejar solo las filas con la manzana.

Análisis y modelado de datos básicosventanasRe: ¿Cómo procedo después de seleccionar algo de un cuadro combinado?

Podrías hacer algo como esto.

table1 = New Table( "Kind of Fruity",
	Add Rows( 6 ),
	New Column( "fruit", Character, "Nominal", Set Values( {"Apple", "Banana", "Mango", "Apple", "Apple", "Banana"} ) ),
	New Column( "Condiment",
		Character,
		"Nominal",
		Set Values( {"Peanut Butter", "Ketchup", "Cayenne Pepper", "Chocolate Fudge", "Caramel", "Salt"} )
	)
);
nw = New Window( "Select fruit",
	cb = Combo Box( {"Apple", "Mango", "Banana"} ),
	Button Box( "OK",
		table1 << Delete Rows( table1 << Get Rows Where( :fruit != (cb << Get Selected) ) );
		nw << Close Window;
	)
);

Re: ¿Cómo procedo después de seleccionar algo de un cuadro combinado?

Necesita ligeras modificaciones en su script:

• Necesita usar la lista para ingresar valores en el cuadro combinado
• Debería obtener el valor seleccionado por el usuario (normalmente dentro del botón Aceptar) usando << ser seleccionado
• Debe realizar la verificación dinámicamente según la selección del usuario en su declaración Seleccionar Dónde

La respuesta de @mmarchandTSI ya tiene una respuesta para estos problemas, por lo que proporciono una solución un poco diferente en la que obtienes los valores según la columna de frutas en el cuadro combinado, demuestras cómo configurar frutas específicas y usas << obtener filas donde en lugar de seleccionar dónde

Names Default To Here(1);

dt = New Table("Untitled",
	Add Rows(5),
	Compress File When Saved(1),
	New Column("fruit",
		Character,
		"Nominal",
		Set Values({"apple", "Mango", "Banana", "apple", "Banana", "Kiwi"})
	)
);
Summarize(dt, fruits = By(:fruit));

nw = New Window("Select fruit",
	cb_fruits = Combo Box(fruits),
	Button Box("OK",
		sel_fruit = cb_fruits << get selected;
		nok_fruit_rows = dt << Get Rows Where(:fruit != sel_fruit);
		dt << Delete Rows(nok_fruit_rows); // note that fruits variable isn't updated
		nw << Close Window; 
	),
	cb_fruits << Set(Contains(fruits, "Kiwi"));
);