729557_zh-CN

liliconcom

获取所有列名称并使用管理规格限制

你好 ，

我正在使用管理规格限制将规格限制添加到我的原始数据中。

我获取了原始数据的所有列名称，并希望将其列出在“管理规格限制”窗口中。但它失败了。

请帮忙提供一些想法。

谢谢。

dt_raw = Open( raw_file );
raw_item = dt_raw << Get Column Names();
	
dt_spec = Open( spec_file );
	
obj = dt_raw << Manage Spec Limits(
	Y( raw_item ),
	Load from Limits Table( dt_spec ),
	Show Limits All(0),
	Save to Column Properties( 1 )
);

基础数据分析和建模质量和工艺工程回复：获取所有列名称并使用管理规格限制

以下是向列表添加 Eval() 函数以使其正常工作的示例

Names Default To Here( 1 );
dt_raw = Open( "$SAMPLE_DATA/Cities.jmp" );
colNames = dt_raw << Get Column Names( string, continuous );
dt_spec = New Table( "Cities Limits",
	Add Rows( 4 ),
	New Column( "Process", Character, Set Values( {"OZONE", "CO", "SO2", "NO"} ) ),
	New Column( "LSL", Numeric, Set Values( [0, 0, 0, 0] ) ),
	New Column( "Target", Numeric, Set Values( [0.2, 15, 0.05, 0.035] ) ),
	New Column( "USL", Numeric, Set Values( [0.4, 30, 0.1, 0.07] ) ),
	Set Label Columns( :Process )
);

raw_item ={};
for each row(
	If(contains(colNames,:Process), insert into(raw_item,:Process)
));

obj = dt_raw << Manage Limits(
	Process Variables( eval(raw_item) ),
	Load From Limits Table( dt_spec )
);
obj << Save to Column Properties;
obj << close window;

我还更改了“保存到列属性”的调用结构。我的方法似乎效果更好。但这可能只是假设的行为。