723216_zh-TW

liliconcom

如何動態更新進程篩選或其他物件。

JMP 社區，您好！

非常感謝您抽出寶貴時間回答我之前的問題。我在下面運行的程式碼（JMP pro 17.2）似乎沒有按預期工作。我的目標是按下重做按鈕後，工藝篩選從按“lot_id”分組更改為按“晶圓”分組。

我想一旦我聲明了 PS 變量，它就會保留所有初始設置，並且不可能動態更新它，因為我找不到任何可以更新分組變量的“<<”命令。對於這個例子有一個簡單的解決方案嗎：

Cols = {"NPN1", "PNP1", "PNP2", "NPN2"};
GR = "lot_id";
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

PLAT = Platform(
	dt,
	PS = Process Screening(
		Y( Eval( Cols ) ),
		Grouping( Eval( GR ) ),
		Control Chart Type( "Indiv and MR" ),
		Minimum Process Length( 1 ),
		Use Medians instead of Means( 1 ),
		Show tests( 0 ),
		Test 1( 0 ),
		Cp( 1 ),
		Spec Limits( 1 ), 
	), 
);

Redo= Expr(
			GR = "wafer";
			
			NW << Close Window;
			PS << Redo Analysis;
			Make_Win();
);

Make_Win = Expr(
	NW = New Window( "ProcessScreening",
		Vlist_box = V List Box( 
		PLAT, 
		BB = Button Box( "Redo", Redo ),
		),
	),
);

Make_Win();

此致，

紐澤西州.

自動化和腳本編寫蘋果系統回覆：如何動態更新進程篩選或其他物件。

這可能會給你一些你可以做什麼的想法

Names Default To Here(1);

Cols = {"NPN1", "PNP1", "PNP2", "NPN2"};
GR = "lot_id";

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

ps = Expr(dt << Process Screening(
	Y(Eval(Cols)),
	Grouping(Eval(GR)),
	Control Chart Type("Indiv and MR"),
	Minimum Process Length(1),
	Use Medians instead of Means(1),
	Show tests(0),
	Test 1(0),
	Cp(1),
	Spec Limits(1)
));


redo_ps = Expr(
	If(GR == "lot_id",
		GR = "wafer";
	,
		GR = "lot_id";
	);
	
	ps_collector << Delete Box();
	vlb << Append(ps_collector = V List Box(ps));
);

nw = New Window("ProcessScreening", 
	V List Box(
		vlb = V List Box(
			ps_collector = V List Box(ps)
		),
		BB = Button Box("Redo", redo_ps);
	)
);