722822_ja-JP

liliconcom

jmp スクリプトのオブジェクト参照

JMP コミュニティの皆さん、こんにちは。

jmp スクリプトのオブジェクト参照について質問があります。以下のコードは実行されます (JMP pro 17.2) が、プロセスのスクリーニングは、ボタンも配置されている Make_Win 関数ではなく、別のウィンドウに表示されます。コピペすればわかるのですが、

PS = dt << プロセススクリーニング(...); V リスト ボックス内の一部を削除すると、動作は期待どおりになりますが、コードは読みにくくなり、さらに乱雑になります。

PS を別の場所で定義し、(以下の例に示すように) 関数内にその参照のみを含める方法はありますか、または以下のコードを意図したとおりに動作させる方法はありますか。

Cols = {"NPN1", "PNP1", "PNP2", "NPN2", "PNP3", "IVP1", "PNP4", "NPN3", "IVP2", "NPN4", "SIT1", "INM1", "INM2",
"VPM1", "VPM2"};
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

	PS = dt << Process Screening(
		Y( Eval(Cols)),
		Control Chart Type( "Indiv and MR" ),
		Minimum Process Length( 1 ),
		Use Medians instead of Means( 1 ),
		Show tests( 0 ),
		Test 1( 0 ),
		Cp( 1 ),
		Spec Limits( 1 ), 
	);
	
	Make_Win = Expr( 
		New Window( "ProcessScreening", 
			Vlist_box = V List Box(
				PS,
				MyButton = Button Box( "SelectedRows", SendRows ),
			),
		),
	);

	SendRows = Expr(
		print_cols = Report( PS )[Table Box( 1 )][String Col Box( 1 )] << getselectedrows();
		Print( Report( PS )[Table Box( 1 )][String Col Box( 1 )][print_cols] );
	);

	Make_Win();

ありがとう、

JNS

自動化とスクリプト作成Re: jmp スクリプトのオブジェクト参照

これを行うにはさまざまなオプションがありますが、ここではその 1 つを紹介します

Names Default To Here(1);

Cols = {"NPN1", "PNP1", "PNP2", "NPN2", "PNP3", "IVP1", "PNP4", "NPN3", "IVP2", "NPN4", "SIT1", "INM1", "INM2",
"VPM1", "VPM2"};

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

ps_collector = V List Box(
	PS = dt << Process Screening(
		Y(Eval(Cols)),
		Control Chart Type("Indiv and MR"),
		Minimum Process Length(1),
		Use Medians instead of Means(1),
		Show tests(0),
		Test 1(0),
		Cp(1),
		Spec Limits(1),

	)
);
	
SendRows = Expr(
	print_cols = Report(PS)[Table Box(1)][String Col Box(1)] << getselectedrows();
	Print(Report(PS)[Table Box(1)][String Col Box(1)][print_cols]);
);
	
nw = New Window("ProcessScreening", Vlist_box = V List Box(ps_collector),
	Button Box("OK", sendrows);
);

Re: jmp スクリプトのオブジェクト参照

platform(...) 関数を使用したいと考えています。

Scripting Index is in the Help menuScripting Index は [ヘルプ] メニューにあります

プラットフォームが起動すると、プラットフォームは、新しいウィンドウ構造内で作成されている場合は新しいウィンドウに接続され、ディスプレイボックス構造内に作成されている場合はディスプレイボックスに接続されます。それ以外の場合は、新しいウィンドウが作成されます。 platform() 関数は、ルート ディスプレイボックスを何もアタッチせずに返します。以前、私は dt< の周囲にボーダーボックス ラッパーを使用することも推奨しました。

スクリプティング インデックスの例は次のようになります。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
p=Platform(
			dt,
			Bubble Plot(
				X( :weight ),
				Y( :age ),
				Sizes( :height ),
				Title Position( 0, 0 )
			)
		);
New Window( "Platform example",
	H List Box(
		Platform(
			dt,
			Bubble Plot(
				X( :weight ),
				Y( :height ),
				Sizes( :age ),
				Title Position( 0, 0 )
			)
		),
		p
	)
);