722385_ja-JP

liliconcom

[JSL] グラフビルダーに数式を使用して参照線を追加します

こんにちは、

私は JMP を初めて使用するので、グラフ ビルダーの式に基づいて変数参照行を追加できるようにしたいと考えています。

Y を複数の X (グループ) でプロットするとき、グラフ ビルダーで各 X に対して生成したいと思います。

- 数式を含む 2 行 (Mean-4*Std ; Mean+4*Std)

- 範囲を色で塗りつぶします

- 各行に値を含むラベル

これらの行を JSL に追加しようとしましたが、成功しませんでした。

次のコードは、定数 (200) と単純な変数 (列平均 (Y)) に対して機能しますが、複雑さを加えることに失敗します (各 X グループの正しい値を計算し、2 行間の空白を埋め、ラベルを追加します)。この線）

JMP データ サンプルを使用して、目標の簡単な例を以下に示しました (.PNG が添付されています)。

ご協力ありがとうございました

Open( "$SAMPLE_DATA/Cholesterol Stacked.jmp" );
temp = Graph Builder(
	Size( 715, 637 ),
	Variables( Y( :Y ), Group X( :Treatment ) ),
	Elements( Points( Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Y",
			ScaleBox,
			{Min( -123.790318945935 ), Max( 574.600650636745 ), Inc( 100 ),
			Minor Ticks( 1 )}
		)
	)
);


DataMean = 100;   /* that code works with a constant*/
DataMean2 = Col Mean( :Y ); /* that code works with a simple variable */ 
report(temp)[axisbox(2)] << Add Ref Line( DataMean, "solid", red, "label1", 1 );
report(temp)[axisbox(2)] << Add Ref Line( DataMean2, "solid", red, "label2", 1 );

基本的なデータ分析とモデリングデータの探索と視覚化品質およびプロセスエンジニアリングRe: [JSL] 数式を使用してグラフビルダーに基準線を追加する

こんにちは、ジャーモさん

うまくいきました、ご協力ありがとうございました！

ジュリアン

Re: [JSL] 数式を使用してグラフビルダーに基準線を追加する

各グループの平均を計算するには、ByVar を使用して Col Mean を使用してテーブルに新しい列を作成できます。他のオプションは Summarize 関数を使用する (または集計テーブルを作成する) ことです。

通常、私はまず新しい列を作成し、複数のプロット タイプをオーバーレイして使用して、このようなものを構築しようとします。折れ線の新しい列と折れ線グラフの追加。この点に到達するのは簡単です

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Cholesterol Stacked.jmp");

dt << New Column("NegLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) - 4 * Col Std Dev(:Y, :Treatment)
));

dt << New Column("PosLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) + 4 * Col Std Dev(:Y, :Treatment)
));


gb = dt << Graph Builder(
	Size(673, 592),
	Show Control Panel(0),
	Variables(
		Y(:Y),
		Y(:NegLimit, Position(1)),
		Y(:PosLimit, Position(1)),
		Group X(:Treatment)
	),
	Elements(
		Points(Y(1), Legend(5)),
		Line(Y(2), Y(3), Legend(7), Fill("Fill Between"))
	),
	SendToReport(
		Dispatch(
			{},
			"Y",
			ScaleBox,
			{Min(-123.790318945935), Max(574.600650636745), Inc(100), Minor Ticks(1)
			}
		)
	)
);

その後、ラベルの作業を開始すると、すぐに非常に面倒になる可能性があります (ラベル付けはグラフ ビルダーの強力な部分ではありません)。

もちろん、これらはグラフィック スクリプトを使用して構築することもできますが、それをどのようにスクリプト化するかは、データとビジュアライゼーションに 100% 依存します (通常、考慮すべき点は非常に多くあります)。

編集：

新しい列、新しい行、グラフ ビルダーを使用してどこまで到達できるかについての 1 つのオプション

もっと見る...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Cholesterol Stacked.jmp");

dt << New Column("NegLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) - 4 * Col Std Dev(:Y, :Treatment)
));

dt << New Column("PosLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) + 4 * Col Std Dev(:Y, :Treatment)
));

dt << New Column("MarkerVal", Numeric, Continuous, Formula(
	If(!IsMissing(Days),
		.
	, Row() == Col Min(Row(), :Treatment, :Days),
		:NegLimit - 10
	,
		:PosLimit + 10
		
	)
));

dt << New Column("MarkerLabel", Character, Continuous, Label(1), Formula(
	If(!IsMissing(Days),
		.
	, Row() == Col Min(Row(), :Treatment, :Days),
		"-4Sigma " || Char(Round(:NegLimit, 2))
	,
		"+4Sigma " || Char(Round(:PosLimit, 2))
	)
));

Summarize(dt, uniq_treatments = by(:Treatment));
rows_added = 0;
For Each({cur_treatment}, uniq_treatments,
	dt << Add Rows({Treatment = cur_treatment});
	dt << Add Rows({Treatment = cur_treatment});
	rows_added = rows_added + 2;
);
dt << Select Rows((N Rows(dt) - rows_added + 1)::N Rows(dt)) << Label(1) << Clear Select;

gb = dt << Graph Builder(
	Size(1126, 772),
	Show Control Panel(0),
	Variables(
		Y(:Y, Combine("Merged")),
		Y(:NegLimit, Position(1), Combine("Merged")),
		Y(:PosLimit, Position(1), Combine("Merged")),
		Y(:MarkerVal, Position(1), Combine("Merged")),
		Group X(:Treatment)
	),
	Elements(
		Line(
			Y(2),
			Y(3),
			Legend(7),
			Fill("Fill Between"),
			Missing Factors("Treat as Missing"),
			Missing Values("Connect Faded")
		),
		Points(Y(1), Legend(5)),
		Points(Y(4), Legend(11))
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				7,
				Properties(0, {Line Color(16)}, Item ID("Mean(NegLimit)", 1)),
				Properties(1, {Line Color(16)}, Item ID("Mean(PosLimit)", 1)),
				Properties(
					2,
					{Fill Color(37)},
					Item ID("Mean(NegLimit)..Mean(PosLimit)", 1)
				)
			), Legend Model(
				11,
				Properties(
					0,
					{Line Color(0), Marker(" "), Marker Size(0)},
					Item ID("MarkerVal", 1)
				)
			)}
		),
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position({7, [1, 2, 3], 5, [0], 11, [4]})}
		)
	)
);