722385_es-ES

liliconcom

[JSL] agregue líneas de referencia en el generador de gráficos con fórmula

Hola,

Soy bastante nuevo en JMP y me gustaría poder agregar líneas de referencias variables basadas en fórmulas en el generador de gráficos.

Cuando trazo la Y con varias X (grupos), me gustaría generar para cada X en el generador de gráficos:

- 2 líneas con la fórmula (Media-4*Std; Media+4*Std)

- Rellena la gama con un color.

- Etiqueta con el valor en cada línea.

Intenté agregar estas líneas en JSL pero sin éxito.

El siguiente código funciona para una constante (200) y una variable simple (Columna Media (Y)), pero no logro agregar más complejidad (calcular el valor correcto para cada grupo X, llenar el espacio en blanco entre las 2 líneas, agregar una etiqueta para la línea)

Tomé una muestra de datos de JMP para mostrar un ejemplo rápido de mi objetivo a continuación (.PNG adjunto).

Muchas gracias por tu ayuda

Open( "$SAMPLE_DATA/Cholesterol Stacked.jmp" );
temp = Graph Builder(
	Size( 715, 637 ),
	Variables( Y( :Y ), Group X( :Treatment ) ),
	Elements( Points( Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Y",
			ScaleBox,
			{Min( -123.790318945935 ), Max( 574.600650636745 ), Inc( 100 ),
			Minor Ticks( 1 )}
		)
	)
);


DataMean = 100;   /* that code works with a constant*/
DataMean2 = Col Mean( :Y ); /* that code works with a simple variable */ 
report(temp)[axisbox(2)] << Add Ref Line( DataMean, "solid", red, "label1", 1 );
report(temp)[axisbox(2)] << Add Ref Line( DataMean2, "solid", red, "label2", 1 );

Análisis y modelado de datos básicosExploración y visualización de datosIngeniería de Calidad y ProcesosRe: [JSL] agregar líneas de referencia en el generador de gráficos con fórmula

Hola Jarmo,

¡¡¡Funciona muy bien, muchas gracias por tu ayuda!!!

julián

Re: [JSL] agregar líneas de referencia en el generador de gráficos con fórmula

Para calcular la media de cada uno de los grupos, puede crear una nueva columna en su tabla usando Col Mean con ByVar; otra opción es usar la función Resumir (o crear una tabla de resumen).

Generalmente, primero intentaría construir algo como esto creando nuevas columnas y usando múltiples tipos de gráficos superpuestos. Nuevas columnas para líneas y agregar gráfico de líneas. Llegar a este punto es fácil

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Cholesterol Stacked.jmp");

dt << New Column("NegLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) - 4 * Col Std Dev(:Y, :Treatment)
));

dt << New Column("PosLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) + 4 * Col Std Dev(:Y, :Treatment)
));


gb = dt << Graph Builder(
	Size(673, 592),
	Show Control Panel(0),
	Variables(
		Y(:Y),
		Y(:NegLimit, Position(1)),
		Y(:PosLimit, Position(1)),
		Group X(:Treatment)
	),
	Elements(
		Points(Y(1), Legend(5)),
		Line(Y(2), Y(3), Legend(7), Fill("Fill Between"))
	),
	SendToReport(
		Dispatch(
			{},
			"Y",
			ScaleBox,
			{Min(-123.790318945935), Max(574.600650636745), Inc(100), Minor Ticks(1)
			}
		)
	)
);

Luego comienzas a trabajar en etiquetas y rápidamente puede volverse muy complicado (el etiquetado definitivamente no es una parte importante del generador de gráficos).

Por supuesto, estos podrían crearse utilizando secuencias de comandos gráficas, pero la forma en que se deben programar depende 100% de sus datos y su visualización (generalmente hay mucho que tener en cuenta).

Editar:

Una opción sobre hasta dónde puede llegar con nuevas columnas, nuevas filas y generador de gráficos

Ver más...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Cholesterol Stacked.jmp");

dt << New Column("NegLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) - 4 * Col Std Dev(:Y, :Treatment)
));

dt << New Column("PosLimit", Numeric, Continuous, Formula(
	Col Mean(:Y, :Treatment) + 4 * Col Std Dev(:Y, :Treatment)
));

dt << New Column("MarkerVal", Numeric, Continuous, Formula(
	If(!IsMissing(Days),
		.
	, Row() == Col Min(Row(), :Treatment, :Days),
		:NegLimit - 10
	,
		:PosLimit + 10
		
	)
));

dt << New Column("MarkerLabel", Character, Continuous, Label(1), Formula(
	If(!IsMissing(Days),
		.
	, Row() == Col Min(Row(), :Treatment, :Days),
		"-4Sigma " || Char(Round(:NegLimit, 2))
	,
		"+4Sigma " || Char(Round(:PosLimit, 2))
	)
));

Summarize(dt, uniq_treatments = by(:Treatment));
rows_added = 0;
For Each({cur_treatment}, uniq_treatments,
	dt << Add Rows({Treatment = cur_treatment});
	dt << Add Rows({Treatment = cur_treatment});
	rows_added = rows_added + 2;
);
dt << Select Rows((N Rows(dt) - rows_added + 1)::N Rows(dt)) << Label(1) << Clear Select;

gb = dt << Graph Builder(
	Size(1126, 772),
	Show Control Panel(0),
	Variables(
		Y(:Y, Combine("Merged")),
		Y(:NegLimit, Position(1), Combine("Merged")),
		Y(:PosLimit, Position(1), Combine("Merged")),
		Y(:MarkerVal, Position(1), Combine("Merged")),
		Group X(:Treatment)
	),
	Elements(
		Line(
			Y(2),
			Y(3),
			Legend(7),
			Fill("Fill Between"),
			Missing Factors("Treat as Missing"),
			Missing Values("Connect Faded")
		),
		Points(Y(1), Legend(5)),
		Points(Y(4), Legend(11))
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				7,
				Properties(0, {Line Color(16)}, Item ID("Mean(NegLimit)", 1)),
				Properties(1, {Line Color(16)}, Item ID("Mean(PosLimit)", 1)),
				Properties(
					2,
					{Fill Color(37)},
					Item ID("Mean(NegLimit)..Mean(PosLimit)", 1)
				)
			), Legend Model(
				11,
				Properties(
					0,
					{Line Color(0), Marker(" "), Marker Size(0)},
					Item ID("MarkerVal", 1)
				)
			)}
		),
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position({7, [1, 2, 3], 5, [0], 11, [4]})}
		)
	)
);