721481_fr-FR

liliconcom

Créer un nombre différent de zones de texte en fonction de la variable

Cher JMPer,

J'essaye de créer plusieurs zones de texte dans une nouvelle fenêtre, le nombre de zones de texte est une variable

Ensuite, j'ai une zone de curseur et je dois définir le texte des zones de texte que je viens de créer lorsque je déplace la barre.

Je suppose qu'une boucle for devrait être la solution, mais je n'arrive tout simplement pas à le faire

colname = {"Name", "Height", "Weight"}; //it's a list of column names from previous code, number of items is not fixed
min = 0;
max = 10;
Value = 0;

eval(evalexpr(
	nw = New Window( "parameter setting",
		 Panel Box( "parameter setting",
			tb1 = text box(char(colname[1]) || ": " || char(:expr(nameexpr(ascolumn(colname[1])))[1])),
			tb2 = text box(char(colname[2]) || ": " || char(:expr(nameexpr(ascolumn(colname[2])))[1])),
			tb3 = text box(char(colname[3]) || ": " || char(:expr(nameexpr(ascolumn(colname[3])))[1])),
			//.
			//.
			//.
			//.
			//.
			//.etc
			//lines for tb should determined by N itmes(colname)
			Valuetb = Text Box( "Value: " || Char( Value )),
			sb = Slider Box( 
				min, max, Value, 
				Valuetb << set text( "Value: " || Char( Value ));
				:Parameter A << set each value(Value);
				tb1 << set text(char(colname[1]) || ": " || char(:expr(nameexpr(ascolumn(colname[1])))[1]));
				tb2 << set text(char(colname[2]) || ": " || char(:expr(nameexpr(ascolumn(colname[2])))[1]));
				tb3 << set text(char(colname[3]) || ": " || char(:expr(nameexpr(ascolumn(colname[3])))[1]))			
			) // when I move the slider box, values of all columns in colname will be changed, so I do set text for all columns in colname 
		)	
	)		
))

Automatisation et scriptsRe : Créer un nombre différent de zones de texte en fonction d'une variable

Je ne suis pas sûr que ce soit ce que vous voulez. Mes modifications apportées à votre script modifient les valeurs des zones de texte dans la fenêtre d'affichage, à mesure que vous déplacez le curseur

names default to here(1);
dt = open("$SAMPLE_DATA/big class.jmp");
colname = {"Name", "Height", "Weight"}; //it's a list of column names from previous code, number of items is not fixed
min = 1;
max = 10;
Value = 1;

Eval(
	Eval Expr(
		nw = New Window( "parameter setting",
			Panel Box( "parameter setting",
				tb1 = Text Box(
					Char( colname[1] ) || ": " || Char( :expr( Name Expr( As Column( colname[1] ) ) )[1] )
				),
				tb2 = Text Box(
					Char( colname[2] ) || ": " || Char( :expr( Name Expr( As Column( colname[2] ) ) )[1] )
				),
				tb3 = Text Box(
					Char( colname[3] ) || ": " || Char( :expr( Name Expr( As Column( colname[3] ) ) )[1] )
				), 
			//.
				//.
				//.
				//.
				//.
				//.etc
				//lines for tb should determined by N itmes(colname)
				Valuetb = Text Box( "Value: " || Char( Value ) ),
				sb = Slider Box(
					min,
					max,
					Value,
					Valuetb << set text( "Value: " || Char( Value ) );
					//:Parameter A << set each value( Value );
					tb1 << set text(
						Char( colname[1] ) || ": " ||char(column( colname[1] )[value] ));
					tb2 << set text(
						Char( colname[2] ) || ": " ||char(column( colname[2] )[value] ));
					tb3 << set text(
						Char( colname[3] ) || ": " ||char(column( colname[3] )[value] ));
				) // when I move the slider box, values of all columns in colname will be changed, so I do set text for all columns in colname 
			)
		)
	)
);

Re : Créer un nombre différent de zones de texte en fonction d'une variable

Merci Jim, mais ce n'est pas ce dont j'ai besoin, pas besoin de remplacer (colname[1]) [1] par value

Ce dont j'ai besoin, c'est que lorsque la liste colname contient plus d'éléments, par exemple : 5, le script peut faire :

tb1 =

tb2 =

tb3=

tb4 =

tb5=

quand il a 10 éléments, alors faites tb1 ~ tb10

Re : Créer un nombre différent de zones de texte en fonction d'une variable

Merci Jarmo, c'est exactement ce dont j'ai besoin

Puis-je vous demander pourquoi vous préféreriez déplacer le script de Slider Box en dehors de la zone de curseur ?

Re : Créer un nombre différent de zones de texte en fonction d'une variable

Stockez les références à la liste, créez le « collecteur » pour les zones de texte en dehors de la nouvelle fenêtre et je déplacerais également le script pour Slider Box en dehors de la zone de curseur dans une fonction/expression distincte.

Est-ce ce dont vous avez besoin?

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

colnames = {"name", "height", "weight"}; //it's a list of column names from previous code, number of items is not fixed

min = 0;
max = 10;
Value = 0;

lub =  Lineup Box(N Col(1));
tbs = {};
For Each({colname}, colnames,
	text_to_add = Eval Insert("^colname^: ^dt[1, colname]^");
	lub << Append(tb = Text Box(text_to_add));
	Insert into(tbs, tb);
);

If(N Items(tbs) != N Items(colnames),
	Throw("!Fatal error");
);

update_tbs = Expr(
	For Each({colname, idx}, colnames,
		text_to_set = Eval Insert("^colname^: ^dt[1, colname]^");
		tbs[idx] << Set Text(text_to_set);
	);
);

nw = New Window( "parameter setting",
	 Panel Box( "parameter setting",
		lub,
		Valuetb = Text Box( "Value: " || Char( Value )),
		sb = Slider Box(
			min, max, Value,
			Valuetb << set text( "Value: " || Char( Value ));
			:age << set each value(Value);
			update_tbs;
		)
	);
);