251314_de-DE

liliconcom

JMP-Skript: Fähigkeitsanalyse in JMP 15

Hallo allerseits,

Wir haben kürzlich ein Upgrade von JMP 14 auf 15 durchgeführt.

Eines unserer Skripte zeigt derzeit ein anderes Ergebnis, wenn eine Fähigkeitsanalyse durchgeführt wird.

In JMP 14 hatten wir folgendes Ergebnis:

In JMP 15 zeigt der exakt gleiche Ausdruck plötzlich die PPx-Werte an (Hinweis – dies stammt aus einer anderen Analyse, also andere Grenzwerte):

Der Code, den wir zum Generieren des Diagramms verwenden:

Distribution(
	Uniform Scaling( 1 ),
	Stack( 1 ),
	Arrange in Rows( 6 ),
	Automatic Recalc( 1 ),
	Continuous Distribution(
		Column( Eval( Column( i ) ) ), // i = loopcounter
		Quantiles( 0 ),
		Horizontal Layout( 1 ),
		Histogram( 0 ),
		Vertical( 0 ),
		Axes on Left( 1 ),
		Outlier Box Plot( 0 ),
		Customize Summary Statistics(
			Std Err Mean( 0 ),
			Upper Mean Confidence Interval( 0 ),
			Lower Mean Confidence Interval( 0 ),
			Maximum( 1 )
		), 
		Capability Analysis(
			// Column # in Limits table doesn't match columns # in result table
			USL( Num( Eval( dtDistLimits:_USL[i - 1] ) ) ),
			LSL( Num( Eval( dtDistLimits:_LSL[i - 1] ) ) )
		)
	),
	SendToReport(
		Dispatch( {}, "Distributions", OutlineBox, {Set Title( "Distributions" )} ),
		Dispatch(
			{},
			"Mean(Result",
			OutlineBox,
			{Set Title(
				sComponentName || " Specification: (LSL " || sLslDisplayValue || ", USL " || sUslDisplayValue
				 || ")"
			)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Summary Statistics"},
			"",
			NumberColBox,
			{Set Format( 9, 3 )}
		),
		Dispatch( {"Distributions", "Mean(Result"}, "Capability Analysis", OutlineBox, {Set Title( "" )} ),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Specification",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Value",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Portion",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"% Actual",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"1",
			ScaleBox,
			{Min( Eval( iMinScale ) ), Max( Eval( iMaxScale ) ), Inc( 0.5 ), Minor Ticks( 5 )}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Lower CI",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Upper CI",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Portion",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		), 
								// THIS DISPATCH GENERATES ERRORS
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"Percent",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		), 
								// THIS DISPATCH GENERATES ERRORS
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"PPM",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"Sigma Quality",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		)
	)
); // Distribution

Kann ich irgendetwas tun, um wieder die korrekten (alten) Ergebnisse zu erhalten?

Danke schön,

Jan

Betreff: JMP-Skript: Fähigkeitsanalyse in JMP 15

Sie können die Ppk-Kennzeichnung mithilfe der Meldung „PkK-Fähigkeitskennzeichnung“ deaktivieren.

Entweder

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );
obj = dt << Distribution( Column( :Weight ) );
obj << PpK Capability Labeling( 0 );
obj << Capability Analysis( LSL( 16 ), USL( 24 ), Target( 20 ) );

oder

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );
obj = dt << Distribution( Column( :Weight ),
	PpK Capability Labeling( 0 ),
	Capability Analysis( LSL( 16 ), USL( 24 ), Target( 20 ) )
 );

Geben Sie AAIG die Schuld für das Durcheinander, das die moderne Fähigkeitsanalyse mit sich bringt.

Meine Lieblingszitate:

Die relativ neue Einführung der Notationen Pp und Ppk und die Neudefinition von Cp und Cpk ohne Konsens der Beteiligten haben zu erheblicher Verwirrung geführt. Unserer Erfahrung nach ist vielen Prüfern und Praktikern nicht bewusst, dass das, was die AIAG Ppk nennt, seit etwa 30 Jahren als Cpk in der Industrie im Einsatz ist.

http://www.sematech.org/docubase/document/Semiconductor_Industry_SPC_Practices.pdf

Oder anders ausgedrückt

Die Prozessleistungsindizes Pp und Ppk sind ein Rückschritt. Sie sind eine Verschwendung von technischem Aufwand und Managementaufwand – sie sagen Ihnen nichts.

- DC Montgomery

Oder stärker ausgedrückt

Die durch Qualitätsstandards oder Branchenrichtlinien vorgeschriebene Verwendung von Pp und Ppk wird als „statistischer Terrorismus“ bezeichnet.

- Kotz und Lovelace

Zum Glück haben wir einen Schalter und können sie ausschalten