251314_zh-TW

liliconcom

JMP 腳本：JMP 15 中的能力分析

大家好，

我們最近從 JMP 14 升級到 15。

完成能力分析後，我們的一個腳本目前顯示不同的結果。

在 JMP 14 中，我們得到以下結果：

在 JMP 15 中，完全相同的表達式突然顯示 PPx 值（注意 - 這是來自不同的分析，因此限制不同）：

我們用來產生圖表的程式碼：

Distribution(
	Uniform Scaling( 1 ),
	Stack( 1 ),
	Arrange in Rows( 6 ),
	Automatic Recalc( 1 ),
	Continuous Distribution(
		Column( Eval( Column( i ) ) ), // i = loopcounter
		Quantiles( 0 ),
		Horizontal Layout( 1 ),
		Histogram( 0 ),
		Vertical( 0 ),
		Axes on Left( 1 ),
		Outlier Box Plot( 0 ),
		Customize Summary Statistics(
			Std Err Mean( 0 ),
			Upper Mean Confidence Interval( 0 ),
			Lower Mean Confidence Interval( 0 ),
			Maximum( 1 )
		), 
		Capability Analysis(
			// Column # in Limits table doesn't match columns # in result table
			USL( Num( Eval( dtDistLimits:_USL[i - 1] ) ) ),
			LSL( Num( Eval( dtDistLimits:_LSL[i - 1] ) ) )
		)
	),
	SendToReport(
		Dispatch( {}, "Distributions", OutlineBox, {Set Title( "Distributions" )} ),
		Dispatch(
			{},
			"Mean(Result",
			OutlineBox,
			{Set Title(
				sComponentName || " Specification: (LSL " || sLslDisplayValue || ", USL " || sUslDisplayValue
				 || ")"
			)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Summary Statistics"},
			"",
			NumberColBox,
			{Set Format( 9, 3 )}
		),
		Dispatch( {"Distributions", "Mean(Result"}, "Capability Analysis", OutlineBox, {Set Title( "" )} ),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Specification",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Value",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Portion",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"% Actual",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"1",
			ScaleBox,
			{Min( Eval( iMinScale ) ), Max( Eval( iMaxScale ) ), Inc( 0.5 ), Minor Ticks( 5 )}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Lower CI",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Upper CI",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Portion",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		), 
								// THIS DISPATCH GENERATES ERRORS
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"Percent",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		), 
								// THIS DISPATCH GENERATES ERRORS
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"PPM",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"Sigma Quality",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		)
	)
); // Distribution

我可以做些什麼來再次獲得正確的（舊的）結果嗎？

謝謝你，

揚

回覆：JMP 腳本：JMP 15 中的能力分析

您可以使用PkK 功能標籤訊息關閉 Ppk 標籤。

任何一個

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );
obj = dt << Distribution( Column( :Weight ) );
obj << PpK Capability Labeling( 0 );
obj << Capability Analysis( LSL( 16 ), USL( 24 ), Target( 20 ) );

或者

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );
obj = dt << Distribution( Column( :Weight ),
	PpK Capability Labeling( 0 ),
	Capability Analysis( LSL( 16 ), USL( 24 ), Target( 20 ) )
 );

將現代能力分析的混亂歸咎於AAIG。

我最喜歡的名言：

相對較新的 Pp 和 Ppk 符號的引入以及在利益相關者沒有共識的情況下重新定義 Cp 和 Cpk 造成了相當大的混亂。根據我們的經驗，許多審核員和從業人員並不知道 AIAG 所稱的 Ppk 已在該行業中作為 Cpk 使用了大約 30 年。

http://www.sematech.org/docubase/document/Semiconductor_Industry_SPC_Practices.pdf

或者，換一種方式

過程表現指數d Pp 和Ppk 是倒退了一步。它們是對工程工作和管理工作的浪費——它們什麼也沒告訴你。

- DC蒙哥馬利

或者說得更強烈

通過品質標準或行業指南強制使用 Pp 和 Ppk 屬於“統計恐怖主義”

- 科茨和洛夫萊斯

幸運的是，我們有一個開關，可以將它們關閉:)