251314_ja-JP

liliconcom

JMP スクリプト: JMP 15 の能力分析

やあみんな、

最近、JMP 14 から 15 にアップグレードしました。

現在、スクリプトの 1 つでは、能力分析が行われると異なる結果が表示されます。

JMP 14 では次の結果が得られました。

JMP 15 では、まったく同じ式で突然 PPx 値が表示されます (注 - これは別の分析によるものであるため、制限が異なります)。

チャートの生成に使用するコードは次のとおりです。

Distribution(
	Uniform Scaling( 1 ),
	Stack( 1 ),
	Arrange in Rows( 6 ),
	Automatic Recalc( 1 ),
	Continuous Distribution(
		Column( Eval( Column( i ) ) ), // i = loopcounter
		Quantiles( 0 ),
		Horizontal Layout( 1 ),
		Histogram( 0 ),
		Vertical( 0 ),
		Axes on Left( 1 ),
		Outlier Box Plot( 0 ),
		Customize Summary Statistics(
			Std Err Mean( 0 ),
			Upper Mean Confidence Interval( 0 ),
			Lower Mean Confidence Interval( 0 ),
			Maximum( 1 )
		), 
		Capability Analysis(
			// Column # in Limits table doesn't match columns # in result table
			USL( Num( Eval( dtDistLimits:_USL[i - 1] ) ) ),
			LSL( Num( Eval( dtDistLimits:_LSL[i - 1] ) ) )
		)
	),
	SendToReport(
		Dispatch( {}, "Distributions", OutlineBox, {Set Title( "Distributions" )} ),
		Dispatch(
			{},
			"Mean(Result",
			OutlineBox,
			{Set Title(
				sComponentName || " Specification: (LSL " || sLslDisplayValue || ", USL " || sUslDisplayValue
				 || ")"
			)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Summary Statistics"},
			"",
			NumberColBox,
			{Set Format( 9, 3 )}
		),
		Dispatch( {"Distributions", "Mean(Result"}, "Capability Analysis", OutlineBox, {Set Title( "" )} ),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Specification",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Value",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"Portion",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis"},
			"% Actual",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"1",
			ScaleBox,
			{Min( Eval( iMinScale ) ), Max( Eval( iMaxScale ) ), Inc( 0.5 ), Minor Ticks( 5 )}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Lower CI",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Upper CI",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(Result", "Capability Analysis", "Long Term Sigma"},
			"Portion",
			StringColBox,
			{Name( "Hide/Unhide" )(1)}
		), 
								// THIS DISPATCH GENERATES ERRORS
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"Percent",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		), 
								// THIS DISPATCH GENERATES ERRORS
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"PPM",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		),
		Dispatch(
			{"Distributions", "Mean(RESULT", "Capability Analysis", "Long Term Sigma"},
			"Sigma Quality",
			NumberColBox,
			{Name( "Hide/Unhide" )(1)}
		)
	)
); // Distribution

正しい（古い）結果を再び取得するために何かできることはありますか？

ありがとう、

1月

Re: JMP スクリプト: JMP 15 の能力分析

PkK Capability Labelingメッセージを使用して、Ppk ラベリングをオフにできます。

どちらか

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );
obj = dt << Distribution( Column( :Weight ) );
obj << PpK Capability Labeling( 0 );
obj << Capability Analysis( LSL( 16 ), USL( 24 ), Target( 20 ) );

または

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );
obj = dt << Distribution( Column( :Weight ),
	PpK Capability Labeling( 0 ),
	Capability Analysis( LSL( 16 ), USL( 24 ), Target( 20 ) )
 );

現代の能力分析の混乱はAAIGのせいだ。

私のお気に入りの引用:

Pp および Ppk という表記法の比較的新しい導入と、利害関係者の合意がない Cp および Cpk の再定義は、かなりの混乱を引き起こしました。私たちの経験では、多くの監査人や実務家は、AIAG が Ppk と呼んでいるものが Cpk として業界で約 30 年間使用されてきたことを知りません。

http://www.sematech.org/docubase/document/Semiconductor_Industry_SPC_Practices.pdf

あるいは、別の言い方をすると、

プロセスパフォーマンス指標 Pp および Ppk は一歩後退しています。それらはエンジニアリングの労力と管理の労力の無駄であり、何も教えてくれません。

- DCモンゴメリー

あるいは、もっと強く言えば、

品質基準や業界ガイドラインを通じて Pp および Ppk の使用を義務付けることは「統計的テロリズム」である

- コッツとラブレス

幸いなことに、私たちはスイッチを持っているので、それらをオフにすることができます:)