561547_es-ES

liliconcom

Necesitas ayuda. Obtuve algún error al crear un archivo HTML interactivo

Estoy escribiendo un script para crear un archivo HTML (interactivo) agregando una función de filtro de datos en los gráficos, pero recibí un error en el siguiente código durante la llamada a la función guardar HTML interactivo()

Gracias por ayudar en esto.

El mensaje de error se encuentra debajo de la imagen adjunta.

Aquí está mi código.

Names Default To Here( 1 );
dt = Open( "C:\myJSL\BigClass.csv");
app=New Window( "Shared Local Filter Batman",
	Data Filter Context Box(
		H List Box(
			Current Data Table() <<
			Data Filter( Local ),
			Platform(
				Current Data Table(),
					Bivariate( Y( :height ), X( :weight ) )
			),
			Platform(
				Current Data Table(),
				Distribution(
					Continuous Distribution(
					Column( :height ),
					Horizontal Layout( 1 ),
					Vertical( 0 )
			)
			)
			)
		)
	)
);

box = app << Run;
Show Properties( box );
Show( box );
/*create HTML */
(box << get windows)[app] << save Interactive HTML( "C:\myJSL\myiHTML.htm" );

/* Open HTML file in Chrome */
Web( "file:///C:/myJSL/myiHTML.htm", Chrome);

Organización de contenidosExploración y visualización de datosLa personalización en masaCompartir y comunicar resultadosRe: Necesito ayuda. Obtuve algún error al crear un archivo HTML interactivo

Hola John, @John_Powell_JMP Muchas gracias por ayudarme a descubrir en qué me equivoco en mi código. ¡Ahora funciona bien! y así puedo modificar el código adecuado para mis tareas reales para el siguiente paso.

De todos modos, también gracias por los consejos que debo seguir.

Re: Necesito ayuda. Obtuve algún error al crear un archivo HTML interactivo

Hola @cpbatman ,

Agregó las líneas Modo y Agregar filtro a la función Cuadro contextual de filtro de datos en lugar de la función Filtro de datos. También agregó un cuadro de lista H adicional que duplica el primero.

Así es como debería verse con algunos cambios menores en el nombre del archivo para que funcione en mi computadora:

Names Default To Here(1);
/* using sample data table */
dt = Open("$SAMPLE_DATA/Big Class.jmp"); // C:\myJSL\BigClass.csv");
app = New Window("Shared Local Filter Batman",
		
	Data Filter Context Box( 
		
		H List Box(
			Current Data Table() << Data Filter(Local,
				/** added code to handle data filter **/
				Mode( Include( 0 ) ),
				Add Filter( columns( :height ), Display( :height, N Items( 6 ) ) )
				/** end of added code **/
			),
			Platform(Current Data Table(), Bivariate(Y(:height), X(:weight))),
			Platform(
				Current Data Table(),
				Distribution(Continuous Distribution(Column(:height), Horizontal Layout(1), Vertical(0)))
			)
		)
		
		/** removed duplicate H List Box code **
		,
		
		H List Box(
			Current Data Table() << Data Filter(Local),
			Platform(Current Data Table(), Bivariate(Y(:height), X(:weight))),
			Platform(
				Current Data Table(),
				Distribution(Continuous Distribution(Column(:height), Horizontal Layout(1), Vertical(0)))
			)
		)
		** end of removed code **/
	)
	
);

/* exported file location changed */ 
app << save Interactive HTML("$DOWNLOADS\myiHTML.htm");
Web("$DOWNLOADS/myiHTML.htm", Chrome); // open with default browser

Dado que es nuevo en las secuencias de comandos JSL, aquí hay un par de consejos que le ayudarán:

1. Haga clic derecho en el editor JSL y seleccione 'Mostrar números de línea' para ayudar a encontrar las líneas mencionadas en el registro incrustado (el siguiente script).

2. Para saber qué parámetros puede pasar a una función, coloque el cursor sobre el nombre de la función y aparecerá una sugerencia. Para obtener más información sobre la función, haga clic derecho en la función y seleccione 'Índice de secuencias de comandos de ayuda'.

~Juan

Re: Necesito ayuda. Obtuve algún error al crear un archivo HTML interactivo

Hola John, @John_Powell_JMP, muchas gracias por pronosticar que mi próximo número lo veré.

Ahora tengo el problema que me dijiste jajaja ^^"

De todos modos, intenté agregar el código que sugirió (en la zona de comentarios agregué el código para manejar el filtro de datos ), pero obtuve un error como en la imagen adjunta. ¿Podrías ayudarme por favor? Perdón por mi interrupción, soy bastante nuevo en JSL.

Names Default To Here(1);
dt = Open("C:\myJSL\BigClass.csv");
app = New Window("Shared Local Filter Batman",
		
		Data Filter Context Box( 
		
<FONT color="#FF0000">/** código agregado para manejar el filtro de datos **/ Local, Modo( Include( 0 ) ), Agregar filtro( columnas( :height ), Display( :height, N Items( 6 ) ) ); /** fin del código agregado **/</FONT>
		
		H List Box(
			Current Data Table() << Data Filter(Local),
			Platform(Current Data Table(), Bivariate(Y(:height), X(:weight))),
			Platform(
				Current Data Table(),
				Distribution(Continuous Distribution(Column(:height), Horizontal Layout(1), Vertical(0)))
			)
		),
		
		H List Box(
			Current Data Table() << Data Filter(Local),
			Platform(Current Data Table(), Bivariate(Y(:height), X(:weight))),
			Platform(
				Current Data Table(),
				Distribution(Continuous Distribution(Column(:height), Horizontal Layout(1), Vertical(0)))
			)
		)
		
	)
	
);

app << save Interactive HTML("C:\myJSL\myiHTML.htm");

Web("file:///C:/myJSL/myiHTML.htm", Chrome); // open with default browser

Aquí está mi mensaje de error.

Re: Necesito ayuda. Obtuve algún error al crear un archivo HTML interactivo

Muchas gracias @jthi

Funcionó bien después de que hice lo que sugeriste.

Re: Necesito ayuda. Obtuve algún error al crear un archivo HTML interactivo

Hola @cpbatman ,

No pude evitar notar que el filtro de datos local en su secuencia de comandos no define una columna para filtrar.

También noté que tienes habilitado el modo de inclusión en el filtro de datos local.

El filtro de datos local no funcionará en HTML interactivo a menos que se agregue una columna de filtro antes de guardar y el modo de inclusión esté deshabilitado.

Aquí hay un código de secuencia de comandos de filtro de datos local que deshabilitará el modo de inclusión y filtrará en la columna de edad:

Data Filter(Local, 
    Mode( Include( 0 ) ),
    Add Filter( columns( :age ), Display( :age, N Items( 6 ) ) )
)

Si combina esto con la solución de Jarmo, su filtro debería funcionar en JMP y en HTML interactivo.

Tenga en cuenta que el comportamiento con el modo Incluir deshabilitado será diferente que cuando está habilitado, ya que el filtro solo mostrará/ocultará filas. Siempre se incluirán todas las filas. Mientras que los puntos en el gráfico bivariado y los valores atípicos en el diagrama de caja responderán al modo Mostrar del filtro de datos local, el histograma y el diagrama de caja no lo harán.

Tenga en cuenta que al publicar en JMP Live o JMP Public, que también utilizan HTML interactivo, no es necesario desactivar el modo de inclusión.

Espero que encuentres esto útil.

~Juan

Re: Necesito ayuda. Obtuve algún error al crear un archivo HTML interactivo

Estoy usando JMP16.

Hice ligeras modificaciones a tu guión. La variable de cuadro no es necesaria cuando se usa Nueva ventana de esta manera (¿no está seguro de cuándo sería necesaria, aplicación/panel?) y puede simplemente guardar la aplicación (nueva ventana) como html interactivo.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
app = New Window("Shared Local Filter Batman",
	Data Filter Context Box(
		H List Box(
			Current Data Table() << Data Filter(Local),
			Platform(Current Data Table(), Bivariate(Y(:height), X(:weight))),
			Platform(
				Current Data Table(),
				Distribution(Continuous Distribution(Column(:height), Horizontal Layout(1), Vertical(0)))
			)
		)
	)
);

// box = app << Run; 
// Show Properties(box);
// Show(box);
/*create HTML */
app << save Interactive HTML("$DOWNLOADS\myiHTML.html");

Web("$DOWNLOADS\myiHTML.html"); // open with default browser