719588_fr-FR

liliconcom

Comment ajouter une ligne de marqueur à la partie superficielle de la zone verte et supprimer les lignes de boîte noire en haut et sur le côté droit ?

J'ai besoin de dessiner un x entre 2 et 4 sur une zone ombrée, mais j'ai rencontré un problème, la partie de surface ne donne pas l'impression qu'il existe un bon moyen de le faire, et je dois trouver les coordonnées x du point où les deux lignes se croisent.

Et comment se débarrasser des lignes de boîte noire en haut et à droite.

names default to here(1);

new window("Ex",
	gb=graph box(
		framesize(300,300),
		x scale(-6,6),
		y scale(0,20),
		double buffer,
		pen color(3);
		y function(x*x,x);
		pen color(4);
		Vline(2,0,4);
		vline(4,0,16);
		yfunction(x-2,x,max(4),min(2));
		yfunction(x-2.5,x,max(4),min(2));
		yfunction(x-3,x,max(4),min(2));
		yfunction(x-3.5,x,max(4),min(2));
		yfunction(x,x,max(4),min(2));
		yfunction(x-0.5,x,max(4),min(2));
		yfunction(x-1,x,max(4),min(2));
		yfunction(x-1.5,x,max(4),min(2));
		yfunction(x+0.5,x,max(4),min(2));
		yfunction(x+1,x,max(4),min(2));
		yfunction(x+1.5,x,max(4),min(2));
	)
);

macOSRe : Comment ajouter une ligne de marqueur à la partie superficielle de la zone verte et supprimer les lignes de boîte noire en haut et sur le côté droit ?

Salut @lehaofeng ,

En fait, je ne comprends pas tout ce que vous demandez. Alors laissez-moi vous aider avec (je pense que vous posez des questions sur) les lignes noires en haut/à droite :

Faites simplement un clic droit dans le graphique > Bordure > désélectionnez « Haut » et « Droite ».

Je te donnerai ceci :

J'espère que cela t'aides,

Florian

Re : Comment ajouter une ligne de marqueur à la partie superficielle de la zone verte et supprimer les lignes de boîte noire en haut et sur le côté droit ?

Merci！ J'espère obtenir l'effet indiqué dans le schéma ci-dessous

Re : Comment ajouter une ligne de marqueur à la partie superficielle de la zone verte et supprimer les lignes de boîte noire en haut et sur le côté droit ?

Vous pouvez plutôt utiliser un polygone avec un motif de remplissage coloré.

Names Default to Here( 1 );

// integration resolution
nSteps = 25;

// function range for AUC
xMin = 2;
xMax = 3;

// define function
fxn = Function( {x},
	Return( x:*x );
);

// define polygon along top
polyX = Index( xMin, xMax, 1/nSteps );
polyY = fxn( polyX );

// finish (close) polygon
polyX ||= Transpose( Matrix( Eval List( List( xMax, xMin, xMin) ) ) );
polyy ||= Transpose( Matrix( Eval List( List( 0, 0, 4 ) ) ) );

New Window( "AUC",
	Outline Box( "Plot",
		Graph Box(
			X Scale( -5, 5 ),
			Y Scale( 0, 25 ),
			Pen Color( "Black" );
			Y Function( fxn( x ), x );
			Fill Color( "Green" );
			Fill Pattern( "right slant light" );
			Polygon( polyX, polyY );
		)
	),
	Outline Box( "AUC",
		Table Box(
			String Col Box( "Method", { "Polygon", "Calculus" } ),
			Number Col Box( "Estimate", { Polygon Area( polyX, polyY ), 19/3 } )
		)
	)
);

Re : Comment ajouter une ligne de marqueur à la partie superficielle de la zone verte et supprimer les lignes de boîte noire en haut et sur le côté droit ?

Merci！Ça marche！