719588_de-DE

liliconcom

Wie füge ich eine Markierungslinie zum Oberflächenteil des grünen Bereichs hinzu und entferne die Blackbox-Linien oben und rechts?

Ich muss ein x zwischen 2 und 4 in einen schattierten Bereich zeichnen, bin aber auf einen Haken gestoßen, der Oberflächenteil fühlt sich nicht so an, als gäbe es dafür eine gute Möglichkeit, und ich muss die x-Koordinaten des Punktes finden, wo die beiden Geraden schneiden sich.

Und wie man die Black-Box-Linien oben und rechts entfernt.

names default to here(1);

new window("Ex",
	gb=graph box(
		framesize(300,300),
		x scale(-6,6),
		y scale(0,20),
		double buffer,
		pen color(3);
		y function(x*x,x);
		pen color(4);
		Vline(2,0,4);
		vline(4,0,16);
		yfunction(x-2,x,max(4),min(2));
		yfunction(x-2.5,x,max(4),min(2));
		yfunction(x-3,x,max(4),min(2));
		yfunction(x-3.5,x,max(4),min(2));
		yfunction(x,x,max(4),min(2));
		yfunction(x-0.5,x,max(4),min(2));
		yfunction(x-1,x,max(4),min(2));
		yfunction(x-1.5,x,max(4),min(2));
		yfunction(x+0.5,x,max(4),min(2));
		yfunction(x+1,x,max(4),min(2));
		yfunction(x+1.5,x,max(4),min(2));
	)
);

Mac OSBetreff: Wie füge ich eine Markierungslinie zum Oberflächenteil des grünen Bereichs hinzu und entferne die Blackbox-Linien oben und rechts?

Hallo @lehaofeng ,

Ich verstehe eigentlich nicht alles, was Sie fragen. Lassen Sie mich Ihnen bei den schwarzen Linien oben/rechts helfen (ich glaube, Sie fragen danach):

Klicken Sie einfach mit der rechten Maustaste in das Diagramm > Rand > deaktivieren Sie „Oben“ und „Rechts“.

Werde dir das geben:

Hoffe das hilft,

Florian

Betreff: Wie füge ich eine Markierungslinie zum Oberflächenteil des grünen Bereichs hinzu und entferne die Blackbox-Linien oben und rechts?

Vielen Dank! Ich hoffe, den im Diagramm unten gezeigten Effekt zu erzielen

Betreff: Wie füge ich eine Markierungslinie zum Oberflächenteil des grünen Bereichs hinzu und entferne die Blackbox-Linien oben und rechts?

Sie können stattdessen auch ein Polygon mit einem farbigen Füllmuster verwenden.

Names Default to Here( 1 );

// integration resolution
nSteps = 25;

// function range for AUC
xMin = 2;
xMax = 3;

// define function
fxn = Function( {x},
	Return( x:*x );
);

// define polygon along top
polyX = Index( xMin, xMax, 1/nSteps );
polyY = fxn( polyX );

// finish (close) polygon
polyX ||= Transpose( Matrix( Eval List( List( xMax, xMin, xMin) ) ) );
polyy ||= Transpose( Matrix( Eval List( List( 0, 0, 4 ) ) ) );

New Window( "AUC",
	Outline Box( "Plot",
		Graph Box(
			X Scale( -5, 5 ),
			Y Scale( 0, 25 ),
			Pen Color( "Black" );
			Y Function( fxn( x ), x );
			Fill Color( "Green" );
			Fill Pattern( "right slant light" );
			Polygon( polyX, polyY );
		)
	),
	Outline Box( "AUC",
		Table Box(
			String Col Box( "Method", { "Polygon", "Calculus" } ),
			Number Col Box( "Estimate", { Polygon Area( polyX, polyY ), 19/3 } )
		)
	)
);

Betreff: Wie füge ich eine Markierungslinie zum Oberflächenteil des grünen Bereichs hinzu und entferne die Blackbox-Linien oben und rechts?

Danke！Es funktioniert！