717649_zh-TW

liliconcom

動態地將分佈圖加入表中

我有一個包含大約 180 列資料的表。

 

我想透過 JSL 中的 for 迴圈為每列動態新增分佈圖（到表中）（使用特定於每列的本機資料篩選器）。

 

這可能嗎？ 在我的嘗試中發生的情況是所有附加的圖都是 for 迴圈的最後一個值。 可能我缺少一些簡單的東西。

 

謝謝！

自動化和腳本編寫回覆：動態地將分佈圖加入表中

這是可能的。如果您可以附加腳本的清理版本，那麼提供協助會更容易、更快速。

回覆：動態地將分佈圖加入表中

我不確定你到底在尋找什麼。這是一個簡單的腳本，它使用本地資料過濾器來創建所有分佈。

Names Default To Here( 1 );

dt = 
// Open Data Table: Blood Pressure.jmp
// → Data Table( "Blood Pressure" )
Open( "$SAMPLE_DATA/Blood Pressure.jmp" );

ColNames = dt << get column names( string, numeric );

nw = New Window( "Distributions",
 H List Box(

  For Each( {Col}, ColNames,
   Eval(
    Eval Expr(
     Distribution(
      Continuous Distribution( Column( Eval( col ) ) ),
      Local Data Filter( Add Filter( columns( Eval( col )) ) )
     )
    )
   )
  )
 )
);

 

 

回覆：動態地將分佈圖加入表中

這是一個縮短的版本：

 

 

Clear Log();
Clear Globals();
dt = current data table ();

myTests = {:Name ("Cont_VDD"), :Name ("Cont_OUTP")};



for (i=1, i<= 2, i++,
 
 dt << Add Properties to Table(
 {New Script(
  "Distribution",
  Distribution(
   Stack( 1 ),
   Continuous Distribution(
    Column( myTests[i] ) ),
    Horizontal Layout( 1 ),
    Vertical( 0 ),
    Outlier Box Plot( 0 ),
    Process Capability( Use Column Property Specs )
   )
  )
 });
);

 

 

回覆：動態地將分佈圖加入表中

您的腳本沒有完全充實表腳本運行所需的 JSL。myTests 的參考需要解析為準確的列名稱，以便表腳本能夠正常運作。下面的 JSL 在將程式碼儲存到資料表之前強制對其進行擴充。我還添加了本地過濾器，並且還更改了程式碼以使腳本名稱成為列名稱

Names Default To Here( 1 );
Clear Log();
Clear Globals();

dt = 
// Open Data Table: Blood Pressure.jmp
// → Data Table( "Blood Pressure" )
Open( "$SAMPLE_DATA/Blood Pressure.jmp" );

myTests = dt << get column names( string, numeric );



For( i = 1, i <= N Items( myTests ), i++,
 Eval(
  Eval Expr(
   dt << Add Properties to Table(
    {New Script(
     expr(myTests[i]),
     Distribution(
      Stack( 1 ),
      Continuous Distribution( Column( Expr( myTests[i] ) ) ),
      Horizontal Layout( 1 ),
      Vertical( 0 ),
      Outlier Box Plot( 0 ),
      Process Capability( Use Column Property Specs ),
      Local Data Filter( Add Filter( columns( Expr( myTests[i] )) ) )
     )
    )}
   )
  )
 )
);

 

回覆：動態地將分佈圖加入表中

如果您在分發的啟動腳本中使用全域變量，那麼它將使用該變數中儲存的目前值。 您需要將其轉換為啟動腳本的文字值。

回覆：動態地將分佈圖加入表中

非常感謝！！！我自學了 JSL...並且一路上遇到了一些障礙...現在我清楚了 Eval 的使用，...再次感謝！

 

——馬特

回覆：動態地將分佈圖加入表中

此外，如果您只是尋找簡單的直方圖，從 JMP 15 開始，只需選擇資料表中的直方圖圖示即可在每列上方顯示直方圖