239840_de-DE

liliconcom

Erhalten Sie relative Vorhersagevarianzwerte

Hallo,

Ich möchte ternäre Diagramme erstellen, die die relative Vorhersagevarianz von 3-Komponenten-Mischungs-DOEs zeigen.

Dazu müsste ich eine große Anzahl von Werten (sagen wir 20.000) aus dem Diagramm „Vorhersage-Varianzprofil“ extrahieren und mit diesen Werten eine Datentabelle erstellen. Diese Datentabelle hätte 20.000 Zeilen und 4 Spalten: X1, X2, X3 und die relative Vorhersagevarianz.

Eine andere Möglichkeit, dies zu tun, wäre vielleicht, den Spaltenformel-Editor zu verwenden und die Formel für die relative Vorhersagevarianz zu implementieren, aber ich bin mit Matrixfunktionen im Formeleditor nicht vertraut.

Vielen Dank.

Das wäre übrigens eine nette Funktion für die nächsten JMP-Updates

 

Betreff: Relative Vorhersagevarianzwerte abrufen

Wunderbar! Vielen Dank Mark

 

 

Betreff: Relative Vorhersagevarianzwerte abrufen

Dieses Skript veranschaulicht einen Ansatz für drei Komponenten, X1, X2, X3 und das quadratische Scheffe-Modell.

 

Names Default to Here( 1 );

// make design
doe = DOE(
 Custom Design,
 {Add Response( Maximize, "Y", ., ., . ), Add Factor( Mixture, 0, 1, "X1", 0 ),
 Add Factor( Mixture, 0, 1, "X2", 0 ), Add Factor( Mixture, 0, 1, "X3", 0 ),
 Set Random Seed( 27513 ), Number of Starts( 10000 ), Add Term( {1, 1} ),
 Add Term( {2, 1} ), Add Term( {3, 1} ), Add Term( {1, 1}, {2, 1} ),
 Add Term( {1, 1}, {3, 1} ), Add Term( {2, 1}, {3, 1} ), Set Sample Size( 12 ),
 Simulate Responses( 0 ), Save X Matrix( 1 ), Make Design,
 Set Run Order( Randomize )}
);

// make design data table
doe dt = doe << Make Table;
doe << Close Window;

// get model matrix, X
model matrix expr = doe dt << Get Script( "Model Matrix" );
X = Arg( Arg( model matrix expr, 1 ), 2 );
inv x prime x = Inverse( X` * X );

// make expression for prediction variance
pv expr = Substitute(
 Expr(
  xi = Matrix( List( :X1, :X2, :X3, :X1*:X2, :X1*:X3, :X2*:X3 ) );
  xi` * iii * xi;
 ),
 Expr( iii ), inv x prime x
);

// add data column with prediction variance formula
Eval(
 Substitute(
  Expr(
   doe dt << New Column( "Prediction Variance", Numeric, Continuous,
    Formula( fff )
   );
  ),
  Expr( fff ), Name Expr( pv expr )
 )
);

// plot prediction variance
mp = doe dt << Mixture Profiler(
 Y( :Prediction Variance ),
 Mixture Profiler(
  1,
  Term Value(
   X1( 0.333333333333335, Lock( 0 ), Show( 1 ) ),
   X2( 0.333333333333336, Lock( 0 ), Show( 1 ) ),
   X3( 0.333333333333335, Lock( 0 ), Show( 1 ) )
  ),
  Contour Value(
   Prediction Variance(
    0.5,
    Min( 0 ),
    Max( 1 )
   )
  ),
  Top Factor( X1 ),
  Left Factor( X2 ),
  Right Factor( X3 )
 )
);
mp << Contour Grid( 0, 1, 0.1, :Prediction Variance );

Betreff: Relative Vorhersagevarianzwerte abrufen

Ja, du hast recht, Mark, danke. Tatsächlich bestand meine ursprüngliche Idee darin, den Formeleditor zur Berechnung zu verwenden

Ausdruck.

 

Aber wie gesagt, ich kenne mich mit Matrixfunktionen im Formeleditor nicht aus und habe es auch nicht hinbekommen...

 

Betreff: Relative Vorhersagevarianzwerte abrufen

Ich kenne das Vorhersage-Varianzprofil und das FDS-Diagramm, leider können diese beiden Plattformen keine Vorhersage-Varianzwerte in einem ternären Diagramm anzeigen (dh ein Dreieck mit X1, X2, X3 als Variablen und Vorhersage-Varianz als Antwort).

Betreff: Relative Vorhersagevarianzwerte abrufen

Sie können die Standardformel für die lineare Regression verwenden, wenn Sie Ihre eigene Visualisierung erstellen möchten. Die Formel finden Sie im Leitfaden „Hilfe“ > „Bücher“ > „Design of Experiments“. Siehe das Kapitel über statistische Details. Hier die relevanten Informationen:

 

 

Das Ergebnis unten rechts ist die relative Vorhersagevarianz, also die im Prediction Variance Profiler und im FDS Plot dargestellte Größe. Multiplizieren Sie dieses Ergebnis mit der tatsächlichen Antwortvarianz, um das absolute Ergebnis zu erhalten, wenn Sie möchten.

Betreff: Relative Vorhersagevarianzwerte abrufen

JMP bietet einen Profiler und das Bruchteil-des-Design-Diagramm für die Vorhersagevarianz, die bei jedem Design, einschließlich eines Mischungsexperiments, erwartet wird. Diese beiden Visualisierungen der Vorhersagevarianz sind in der Entwurfsbewertungsübersicht verfügbar. Sie werden automatisch erstellt, nachdem Sie auf „Design erstellen“ geklickt haben.

 

Wenn Sie bereits über ein Design verfügen, können Sie alternativ „DOE“ > „Designdiagnose“ > „Design bewerten“ bei geöffneter Datentabelle auswählen und der Faktorrolle Datenspalten hinzufügen. Es stehen die gleichen zwei Visualisierungen zur Verfügung.

Betreff: Relative Vorhersagevarianzwerte abrufenWas ich tun möchte, ist, die Werte der relativen Varianz der Vorhersage als Funktion der X-Werte mithilfe eines ternären Diagramms darzustellen (dafür sind keine Y-Werte erforderlich).
DankeBetreff: Relative Vorhersagevarianzwerte abrufen

Ich bin ein wenig verwirrt darüber, was Sie tun möchten.

 

Da Sie über DOE-Daten verfügen und einen Profiler verwenden, verfügen Sie über ein Modell. Haben Sie sich den Mischungsprofiler angesehen, der Teil der Modellanpassung eines Mischungsmodells ist? Sie können dem Mischungsprofiler ein Konturgitter hinzufügen, das ein ternäres Diagramm basierend auf Ihrem Modell erstellt.

 

Wenn Sie weiterhin die Konturdiagramme aus Diagramm > Ternärdiagramm verwenden möchten, speichern Sie Ihre Vorhersageformel aus der Modellanpassung. Geben Sie die Vorhersageformel im Konturfeld des Dialogfelds „Ternary Plot“ an. Dadurch erhalten Sie glatte Konturen. Es besteht keine Notwendigkeit, eine Datentabelle mit Tausenden von Zeilen zu erstellen, es sei denn, mir fehlt etwas.