239840_zh-CN

liliconcom

获取相对预测方差值

你好，

我想制作三元图来显示三分量混合 DOE 的相对预测方差。

为此，我需要从预测方差剖面图中提取大量值（假设为 20,000 个），并使用这些值创建一个数据表。 该数据表将有 20,000 行和 4 列：X1、X2、X3 和相对预测方差。

也许另一种方法是使用列公式编辑器并实现相对预测方差公式，但我不熟悉公式编辑器中的矩阵函数。

多谢。

顺便说一句，这对于下一次 JMP 更新来说将是一个很好的功能:)

 

回复：获取相对预测方差值

精彩的！ 非常感谢马克

 

 

回复：获取相对预测方差值

该脚本演示了三个分量 X1、X2、X3 和二次 Scheffe 模型的方法。

 

Names Default to Here( 1 );

// make design
doe = DOE(
 Custom Design,
 {Add Response( Maximize, "Y", ., ., . ), Add Factor( Mixture, 0, 1, "X1", 0 ),
 Add Factor( Mixture, 0, 1, "X2", 0 ), Add Factor( Mixture, 0, 1, "X3", 0 ),
 Set Random Seed( 27513 ), Number of Starts( 10000 ), Add Term( {1, 1} ),
 Add Term( {2, 1} ), Add Term( {3, 1} ), Add Term( {1, 1}, {2, 1} ),
 Add Term( {1, 1}, {3, 1} ), Add Term( {2, 1}, {3, 1} ), Set Sample Size( 12 ),
 Simulate Responses( 0 ), Save X Matrix( 1 ), Make Design,
 Set Run Order( Randomize )}
);

// make design data table
doe dt = doe << Make Table;
doe << Close Window;

// get model matrix, X
model matrix expr = doe dt << Get Script( "Model Matrix" );
X = Arg( Arg( model matrix expr, 1 ), 2 );
inv x prime x = Inverse( X` * X );

// make expression for prediction variance
pv expr = Substitute(
 Expr(
  xi = Matrix( List( :X1, :X2, :X3, :X1*:X2, :X1*:X3, :X2*:X3 ) );
  xi` * iii * xi;
 ),
 Expr( iii ), inv x prime x
);

// add data column with prediction variance formula
Eval(
 Substitute(
  Expr(
   doe dt << New Column( "Prediction Variance", Numeric, Continuous,
    Formula( fff )
   );
  ),
  Expr( fff ), Name Expr( pv expr )
 )
);

// plot prediction variance
mp = doe dt << Mixture Profiler(
 Y( :Prediction Variance ),
 Mixture Profiler(
  1,
  Term Value(
   X1( 0.333333333333335, Lock( 0 ), Show( 1 ) ),
   X2( 0.333333333333336, Lock( 0 ), Show( 1 ) ),
   X3( 0.333333333333335, Lock( 0 ), Show( 1 ) )
  ),
  Contour Value(
   Prediction Variance(
    0.5,
    Min( 0 ),
    Max( 1 )
   )
  ),
  Top Factor( X1 ),
  Left Factor( X2 ),
  Right Factor( X3 )
 )
);
mp << Contour Grid( 0, 1, 0.1, :Prediction Variance );

回复：获取相对预测方差值

是的，你是对的，马克，谢谢。 事实上，我最初的想法是使用公式编辑器来计算

表达。

 

但正如我所说，我不熟悉公式编辑器中的矩阵函数，而且我没能做到......

 

回复：获取相对预测方差值

我知道预测方差概况和 FDS 图，不幸的是这两个平台无法在三元图中显示预测方差值（即以 X1、X2、X3 作为变量，以预测方差作为响应的三角形）。

回复：获取相对预测方差值

如果您想创建自己的可视化，可以使用线性回归的标准公式。 该公式在“帮助”>“书籍”>“实验设计”指南中提供。 请参阅有关统计详细信息的章节。 以下是相关信息：

 

 

右下角的结果是相对预测方差，它是预测方差刻画器和 FDS 图中绘制的数量。 如果您愿意，可以将此结果乘以实际响应方差和绝对结果。

回复：获取相对预测方差值

JMP 提供刻画器和设计分数图，用于任何设计（包括混合实验）的预期预测方差。 设计评估大纲中提供了这两种预测方差的可视化效果。 单击“制作设计”后会自动生成它们。

 

如果您已有设计，也可以选择 DOE > 设计诊断 > 评估设计并打开数据表，并将数据列添加到因子角色。 可以使用相同的两个可视化。

回复：获取相对预测方差值我想要做的是使用三元图将预测的相对方差值绘制为 X 的函数（不需要 Y 的值）。
谢谢回复：获取相对预测方差值

我对你想做什么有点困惑。

 

由于您有 DOE 数据并且正在查看分析器，因此您有一个模型。 您是否看过作为混合模型模型拟合一部分的混合分析器？ 您可以将等高线网格添加到混合刻画器中，该网格将根据您的模型给出三元图。

 

如果您仍想使用“图形”>“三元图”中的等高线图，请保存模型拟合中的预测公式。 在“三元图”对话框的等高线字段中指定预测公式。 这会给你平滑的轮廓。 除非我遗漏了某些内容，否则不需要创建包含数千行的数据表。