713667_de-DE

liliconcom

Kann ich den Titel des Diagrammerstellers basierend auf einer Variablen aus einem H-Listenfeld festlegen?

Ich habe ein H-Listenfeldfenster, in das Benutzer Parameter eingeben können. Anschließend werde ich einige Berechnungen durchführen und dem Benutzer einen Diagrammersteller zur Verfügung stellen

Meine Frage ist: Kann ich den Titel des Graph Builder auch basierend auf den Parametern aus dem H-Listenfeld festlegen?Unten finden Sie den Beispielcode

Names Default To Here( 1 );
dt = current data table();
nw = New Window( "simulator",
 H List Box( Text Box( "   Input sample rate " ), sample rate = Number Edit Box() ), 
 H List Box( Text Box( "   Input threshold " ), threshold = Number Edit Box() ),
 Button Box( "OK",
    thesamplerate = sample rate << get;
 thethreshold = threshold << get;
    numthreshold = num(thethreshold);
    numtime = num(thetime);

    //Here are more code I already finished based on above variable

Graph Builder(
 Variables( X( :File Name ), Y( :greater ) ),
 Elements( Bar( X, Y, Legend( 4 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Sample rate =    Threshold = " )} //I want to have sample rate & threshold shown on title
  )
 )
)
))

 

 

Automatisierung und SkripterstellungBetreff: Kann ich den Titel des Diagrammerstellers basierend auf einer Variablen aus einem H-Listenfeld festlegen?

Hier ist die Methode, die ich normalerweise verwende:

Names Default To Here( 1 );
dt = Current Data Table();
nw = New Window( "simulator",
 H List Box( Text Box( "   Input sample rate " ), sample rate = Number Edit Box() ),
 H List Box( Text Box( "   Input threshold " ), threshold = Number Edit Box() ),
 Button Box( "OK",
  thesamplerate = sample rate << get;
  thethreshold = threshold << get;
  numthreshold = Num( thethreshold );
  numtime = Num( thetime );

    //Here are more code I already finished based on above variable

  gb = Graph Builder( Variables( X( :File Name ), Y( :greater ) ), Elements( Bar( X, Y, Legend( 4 ) ) ) );
  // Set the title
  Report( gb )[Outline Box( 1 ), Text Edit Box( 1 )] << set text( "Sample Rate=" || Char( thesamplerate ) );
  
 )
);

Betreff: Kann ich den Titel des Diagrammerstellers basierend auf einer Variablen aus einem H-Listenfeld festlegen?

Sie können den Titel mithilfe von Eval Insert oder String-Verkettung erstellen.

Hier ist eine Option

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("simulator",
 H List Box(Text Box("   Input sample rate "), sample rate = Number Edit Box()),
 H List Box(Text Box("   Input threshold "), threshold = Number Edit Box()),
 Button Box("OK",
  thesamplerate = sample rate << get;
  thethreshold = threshold << get;
  //numthreshold = Num(thethreshold);
  //numtime = Num(thetime);
  gb = dt << Graph Builder(
   Variables(X(:age), Y(:weight)),
   Elements(Bar(X, Y, Legend(4)))
  );
  Report(gb)[TextEditBox(1)] << Set Text(Eval Insert("Sample rate = ^thesamplerate^   Threshold = ^thethreshold^"));
 )
);

Sie sollten es auch direkt in den Titel in SendToReport einfügen können. Hier erstelle ich auch die Titelvariable separat, aber das ist nicht notwendig, kann aber das Debuggen usw. erleichtern

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("simulator",
 H List Box(Text Box("   Input sample rate "), sample rate = Number Edit Box()),
 H List Box(Text Box("   Input threshold "), threshold = Number Edit Box()),
 Button Box("OK",
  thesamplerate = sample rate << get;
  thethreshold = threshold << get;
  //numthreshold = Num(thethreshold);
  //numtime = Num(thetime);
  graph_title = Eval Insert("Sample rate = ^thesamplerate^   Threshold = ^thethreshold^");
  gb = dt << Graph Builder(
   Variables(X(:age), Y(:weight)),
   Elements(Bar(X, Y, Legend(4))),
   SendToReport(
    Dispatch(
     {},
     "graph title",
     TextEditBox,
     {Set Text(graph_title)} //I want to have sample rate & threshold shown on title
    )
   )
  );
 )
);

Betreff: Kann ich den Titel des Diagrammerstellers basierend auf einer Variablen aus einem H-Listenfeld festlegen?

Vielen Dank euch beiden für eure prompte Antwort