713667_fr-FR

liliconcom

Puis-je définir le titre du générateur de graphiques en fonction d'une variable d'une zone de liste H ?

J'ai une fenêtre de zone de liste H dans laquelle les utilisateurs peuvent saisir des paramètres, après quoi je ferai quelques calculs et fournirai un générateur de graphiques à l'utilisateur.

Ma question est la suivante : puis-je définir le titre du générateur de graphiques également en fonction des paramètres de la zone de liste H ?ci-dessous est l'exemple de code

Names Default To Here( 1 );
dt = current data table();
nw = New Window( "simulator",
 H List Box( Text Box( "   Input sample rate " ), sample rate = Number Edit Box() ), 
 H List Box( Text Box( "   Input threshold " ), threshold = Number Edit Box() ),
 Button Box( "OK",
    thesamplerate = sample rate << get;
 thethreshold = threshold << get;
    numthreshold = num(thethreshold);
    numtime = num(thetime);

    //Here are more code I already finished based on above variable

Graph Builder(
 Variables( X( :File Name ), Y( :greater ) ),
 Elements( Bar( X, Y, Legend( 4 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Sample rate =    Threshold = " )} //I want to have sample rate & threshold shown on title
  )
 )
)
))

 

 

Automatisation et scriptsRe : Puis-je définir le titre du générateur de graphiques en fonction d'une variable d'une zone de liste H ?

Voici la méthode que j'utilise habituellement :

Names Default To Here( 1 );
dt = Current Data Table();
nw = New Window( "simulator",
 H List Box( Text Box( "   Input sample rate " ), sample rate = Number Edit Box() ),
 H List Box( Text Box( "   Input threshold " ), threshold = Number Edit Box() ),
 Button Box( "OK",
  thesamplerate = sample rate << get;
  thethreshold = threshold << get;
  numthreshold = Num( thethreshold );
  numtime = Num( thetime );

    //Here are more code I already finished based on above variable

  gb = Graph Builder( Variables( X( :File Name ), Y( :greater ) ), Elements( Bar( X, Y, Legend( 4 ) ) ) );
  // Set the title
  Report( gb )[Outline Box( 1 ), Text Edit Box( 1 )] << set text( "Sample Rate=" || Char( thesamplerate ) );
  
 )
);

Re : Puis-je définir le titre du générateur de graphiques en fonction d'une variable d'une zone de liste H ?

Vous pouvez créer le titre en utilisant Eval Insert ou la concaténation de chaînes.

Voici une option

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("simulator",
 H List Box(Text Box("   Input sample rate "), sample rate = Number Edit Box()),
 H List Box(Text Box("   Input threshold "), threshold = Number Edit Box()),
 Button Box("OK",
  thesamplerate = sample rate << get;
  thethreshold = threshold << get;
  //numthreshold = Num(thethreshold);
  //numtime = Num(thetime);
  gb = dt << Graph Builder(
   Variables(X(:age), Y(:weight)),
   Elements(Bar(X, Y, Legend(4)))
  );
  Report(gb)[TextEditBox(1)] << Set Text(Eval Insert("Sample rate = ^thesamplerate^   Threshold = ^thethreshold^"));
 )
);

Vous devriez pouvoir également l'insérer directement dans le titre dans SendToReport. Ici, je construis également la variable de titre séparément, mais ce n'est pas nécessaire mais peut faciliter le débogage, etc.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("simulator",
 H List Box(Text Box("   Input sample rate "), sample rate = Number Edit Box()),
 H List Box(Text Box("   Input threshold "), threshold = Number Edit Box()),
 Button Box("OK",
  thesamplerate = sample rate << get;
  thethreshold = threshold << get;
  //numthreshold = Num(thethreshold);
  //numtime = Num(thetime);
  graph_title = Eval Insert("Sample rate = ^thesamplerate^   Threshold = ^thethreshold^");
  gb = dt << Graph Builder(
   Variables(X(:age), Y(:weight)),
   Elements(Bar(X, Y, Legend(4))),
   SendToReport(
    Dispatch(
     {},
     "graph title",
     TextEditBox,
     {Set Text(graph_title)} //I want to have sample rate & threshold shown on title
    )
   )
  );
 )
);

Re : Puis-je définir le titre du générateur de graphiques en fonction d'une variable d'une zone de liste H ?

Merci à vous deux pour votre réponse rapide