将表脚本嵌入到由嵌入表脚本生成的表中我有一个脚本添加了一些用于绘图的嵌入式表格脚本。 我现在尝试添加另一个表脚本，该脚本创建一个汇总表并在该新表中嵌入一个新的表脚本。
因此 dt 中的嵌入表运行良好，按预期打开 dtsum，但“辅助表脚本标题”未嵌入 dtsum 中。 如果我运行脚本的该部分 (CTL+R)，那么它就会嵌入到 dtsum。
请注意，我已经清理了脚本以隐藏一些公司 IP 内容。 您能看出我的格式/结构有问题吗？
dt << New Script(
"First level Table script title",
dtsum = dt << Summary(
// summary details
),
dtsum << New Script(
"Secondary table script title",
// graph builder details here
)
);
自动化和脚本编写回复：将表脚本嵌入到由嵌入表脚本生成的表中在创建摘要时，将表脚本添加到同一表脚本中的 dt_sum。 如果您只需将 , 替换为 ; 就足够了。
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << Delete scripts(dt << Get Table Script Names); // has many of these already
dt << New Script("Create Summary",
Names Default To Here(1);
dt_sum = Current Data Table() << Summary(
Group(:name),
Mean(:height),
Mean(:weight),
Freq("None"),
Weight("None"),
Link to original data table(0)
);
dt_sum << New Script("Plot",
Graph Builder(
Size(528, 458),
Show Control Panel(0),
Variables(X(:name), Y(:"Mean(height)"n), Y(:"Mean(weight)"n, Position(1))),
Elements(Bar(X, Y(1), Y(2), Legend(4)))
)
)
);回复：将表脚本嵌入到由嵌入表脚本生成的表中看起来你的最后一句话是正确的，我只需要将 , 替换为 ;
我认为我的格式很好，但我有一些比这更糟糕的东西，我很感谢您的快速响应！ 谢谢！
