710876_de-DE

liliconcom

Standardisierte Gruppenspaltenattribute

Hallo. Ich bin neu in JSL-Skripten.

Über das Skript-Hilfemenü kann ich Spaltenattribute umwandeln, aber wie mache ich das für alle Spalten in der Gruppe?

Es ist zu umständlich, alle 20 Spalten einzeln zu schreiben, und ich habe viele gruppierte Spalten.

Ich weiß, dass es einfach ist, Standardattribute ohne Skripterstellung zu verwenden, aber ich habe es mit verknüpften Tabellen zu tun, die häufig aktualisiert werden, und es ist nicht produktiv, dies ständig zu tun.

 

dt << Transform Column( "A");
dt:A << Datentyp (Numerisch);
dt:A << Modellierungstyp( "Kontinuierlich" );

 

Ich habe versucht, „Spalte“ in „Spaltengruppe“ zu ändern, es scheint jedoch nicht zu funktionieren.

Automatisierung und SkripterstellungBetreff: Standardisierte Gruppenspaltenattribute

Ich glaube, das wird tun, was Sie brauchen:

Names Default To Here( 1 );
dt = Current Data Table();
colNames = dt << get column group( "the group's name" );

For Each( {col}, 
 colNames, Column( dt, col ) << Data Type( Numeric ) << Modeling Type( Continuous ) 
);

Bitte nutzen Sie die bei der Eingabe von JSL.Dies erleichtert den Lesern die Untersuchung der JSL

 

Betreff: Standardisierte Gruppenspaltenattribute

Sie können Standardisierungsattribute als Ausgangspunkt verwenden und das erstellte Skript nach Bedarf ändern.

Ich habe Spalten wie diese und möchte Höhe und Stärke in Spalten vom Typ „Zeichen“ ändern

Durch die Standardisierung von Attributen erhalte ich ein Skript wie dieses (aus dem erweiterten Protokoll).

// Standardize column attributes
Local({old dt = Current Data Table()},
 Current Data Table(Data Table("Big Class"));
 For Each({col, index}, {:height, :weight},
  col << Data Type(Character) << Set Modeling Type("Nominal")
 );
 Current Data Table(old dt);
);

Nächster Suchskriptindex für Spaltengruppe (oder etwas Ähnliches)

nach einer kleinen Änderung (ich ändere Datentyp und Modellierungstyp wieder in numerisch)

// Standardize column attributes
Local({old dt = Current Data Table()},
 Current Data Table(Data Table("Big Class"));
 For Each({col, index}, old dt << get column group("height etc."),
  col << Data Type(Numeric) << Set Modeling Type("Continuous")
 );
 Current Data Table(old dt);
);

Wenn Sie den Namen der Spaltengruppe nicht kennen, kehren Sie zum Skriptindex zurück

 

 

Betreff: Standardisierte Gruppenspaltenattribute

Danke schön!

Wie erhalte ich das erweiterte Protokoll? Ist es in JMP 16 verfügbar? Ich habe noch kein Upgrade durchgeführt

Betreff: Standardisierte Gruppenspaltenattribute

Danke Das nächste Mal werde ich verwenden

 

Ich habe das Skript ausprobiert, aber stattdessen wurde diese Warnung angezeigt. Was soll ich tun?

 

Betreff: Standardisierte Gruppenspaltenattribute

Ja, es wurde in JMP16 hinzugefügt und seitdem ist jede Version in der Lage, mehr Aktionen zu erfassen (und JMP17 verfügt über einen Workflow-Builder).

Betreff: Standardisierte Gruppenspaltenattribute

Dieses Skript verwendet auch For Each, das ebenfalls in JMP16 hinzugefügt wurde. Sie müssten es in eine For-Schleife umwandeln, die etwa so aussehen würde

Local({old dt = Current Data Table()},
 Current Data Table(Data Table("Big Class"));
 collist = old dt << get column group("height etc.");
 For(i = 1, i <= N Items(collist), i++,
  col = collist[i];
  col << Data Type(Numeric) << Set Modeling Type("Nominal");
 );
 Current Data Table(old dt);
);

Je nachdem, wo das Skript ausgeführt wird, könnte es (zumindest meiner Meinung nach) auch etwas bereinigt werden, etwa so

Names Default To Here(1);

dt = Current Data Table(); 
// dt = Open(); // use this if possible

collist = dt << get column group("height etc.");
For(i = 1, i <= N Items(collist), i++,
 col = collist[i];
 col << Data Type(Numeric) << Set Modeling Type("Continuous");
);