36971_es-ES

liliconcom

Guardar animación JMP

Hola, soy bastante nuevo en JMP y tengo una pregunta: ¿Es posible guardar la animación?

Por ejemplo, si ajusto Y por X en alguna tabla y luego uso la animación de filtro de datos. ¿Sería posible guardar la animación/clip?

¡Gracias!

  

Re: Guardar animación JMP

¡Muchas gracias!:)

Re: Guardar animación JMP

Puede encontrar otro ejemplo de cómo guardar un GIF animado con un filtro de datos aquí: Guarde una animación de filtro de datos como un GIF animado .

 

 

Re: Guardar animación JMP

Si está utilizando JMP 13 en Windows, puede utilizar la nueva funcionalidad JSL para crear GIF animados para guardar su animación de filtro de datos.

A continuación se muestra un ejemplo que creará un generador de gráficos con un filtro de datos local y se guardará y abrirá un GIF animado. Para más información, consulte @JohnPonte 's publicación sobre GIF animados usando Bubble Plot . Tomé prestado mucho código de su ejemplo de huracanes en el siguiente script. En teoría, esto puede funcionar en una ventana actual que tenga abierta si ejecuta todo comenzando con la línea "report = Current Report()".

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
gb = dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :age ),
   Where( :age == 12 ),
   Display( :age, Size( 202, 114 ), List Display )
  )
 )
);

report = Current Report();

ldf_listBox = report[ListBoxBox(1)];

numLevels = NItems(ldf_ListBox << Get ITems);

// Create a new image, same size as the graph we are going to capture
graphFrame = report[FrameBox(1)] << getPicture();
{w, h} = graphFrame << getSize();
img = newImage(w, h);

for(i=1,i<=numLevels,i++,
 
 // deselect old selection
 selectedItems = ldf_listBox << Get Selected Indices;
 for(k=1,k<=nitems(selectedItems),k++,
  ldf_listBox << set selected(selectedItems[k],0);
 );
 
 // set the next item selected
 ldf_listBox << set selected(i);
 
 wait(0); // wait for the display to update
 // Capture frame for current graph and save to animated image
 graphFrame = report[FrameBox(1)] << getPicture();
 {r, g, b} = graphFrame << getPixels("rgb");
 img << addFrame();
 img << setFrameDuration(1000);  // Time between frames, in ms
 img << setPixels("rgb", {r, g, b}); 
 wait(0.5); // for demonstration purposes
);

// Remove inital blank frame
img << removeFrame(0);

// Write out animated image
img << saveImage ("$temp\animated.gif", gif);

// open the gif
open("$temp\animated.gif");

Editado para agregar el archivo GIF resultante:Resulting animated gif Gif animado resultante