703805_de-DE

liliconcom

Benennen Sie die Namen der Untergruppenspalten aus der Übersichtstabelle um

Hallo zusammen,

Ich brauche Hilfe bei meinem Skript. Ich habe ein Skript, das wie folgt eine Übersichtstabelle aus der Rohdatentabelle erstellt.

Data Table( "DVIRCR_SumTable" ) << Summary(
 Group( :prodgroup3, :subapp ),
 Max( :rcr% ),
 Subgroup( :date_ ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 )
);
 
//rename N Rows column to Lot Count
:Name( "N Rows" ) << Set Name( "Lot Count" );
******

 

Jetzt muss ich die Untergruppenspalte automatisch umbenennen. Das Datum ändert sich täglich.

Ich möchte vom aktuellen Format – rcr%(:date_) zum Format – :date_ wechseln

Letztendlich möchte ich kein rcr%-Wort vor dem Datum.

 

Automatisierung und SkripterstellungBetreff: Benennen Sie die Namen der Untergruppenspalten aus der Übersichtstabelle um

Hier ist eine Änderung an Ihrem Skript.Die erste Änderung besteht darin, der Übersichtstabelle einen Namen zu geben

Output Table( "My Summary" )

Die zweite Änderung durchläuft alle Spalten in der neuen Tabelle und ändert alle Spalten, deren Name mit „rcr%“ beginnt, und ändert den Namen.

// Create a list of all of the column
colNames = Data Table( "My Summary" ) << get column names( string );

// Loop through all of the names, and when "rcr%," is found in the 
// start of the column name, change the name to the column name 
// starting from the 7th character in the name
For Each( {col}, colNames,
 If( Contains( col, "rcr%," ) == 1,
  Column( col ) << set name( Substr( col, 7 ) )
 )
);

Hier ist das komplette Skript

Names Default to Here( 1 );
Data Table( "DVIRCR_SumTable" ) << Summary(
 Group( :prodgroup3, :subapp ),
 Max( :rcr% ),
 Subgroup( :date_ ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 ),
 Output Table( "My Summary" )
);
 
//rename N Rows column to Lot Count
:Name( "N Rows" ) << Set Name( "Lot Count" );

// Create a list of all of the column
colNames = Data Table( "My Summary" ) << get column names( string );

// Loop through all of the names, and when "rcr%," is found in the 
// start of the column name, change the name to the column name 
// starting from the 7th character in the name
For Each( {col}, colNames,
 If( Contains( col, "rcr%," ) == 1,
  Column( col ) << set name( Substr( col, 7 ) )
 )
);

Bitte geben Sie außerdem Ihre JSL in Diskussionen ein, indem Sie die verwenden Symbol, das die JSL in einem Format anzeigt, das für die Community-Mitglieder einfacher zu lesen und das Problem zu verstehen ist.