697226_it-IT

liliconcom

Come salvare un'immagine con jsl

Ciao, JMPer, voglio utilizzare jsl per salvare solo i grafici dell'istogramma di Process Capability senza alcun file . C'è un modo per raggiungerlo?

 

 

Automazione e scriptingRe: Come salvare un'immagine in jsl

Se desideri solo quegli istogrammi e nient'altro, molto probabilmente è più semplice catturarli uno per uno dalla piattaforma di distribuzione

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

nw_collector = New Window("",
 vlb = V List Box()
);

cols = {"NPN1", "PNP1"};

For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];
 pic = lb << Get Picture;
 vlb << Append( // use outlinebox to add title
  OutlineBox("Process Capability for " || col_name, pic)
 );
 dist << Close Window; 
);

Tali immagini possono essere acquisite da Process Capability o dalla distribuzione quando sono tutte aperte contemporaneamente, ma in questo modo è più semplice navigare nel livello del report.

 

Re: Come salvare un'immagine in jsl

Di recente ho scoperto che salvare le immagini in una tabella dati può essere utile in alcuni casi d'uso. Ecco una versione modificata che lo fa, basata su @jthi è l'esempio.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

cols = {"NPN1", "PNP1"};
outputdt = New Table( "imgs",
 Add Rows( nitems(cols) ),
 New Column( "image", Expression, "None", Set Values( {} ) ),
);

i = 1;
For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];
 pic = lb << Get Picture;
 outputdt:image[i] = pic;
 i++;
 dist << Close Window; 
);

Re: Come salvare un'immagine in jsl

Grazie mille.

Ma avevo un'altra domanda: dopo aver salvato l'immagine nella tabella, è possibile esportarla come file Excel? Ho provato a farlo, non è stato mostrato come immagine.

 

Re: Come salvare un'immagine in jsl

Ciò non è possibile, per quanto ne so. Ecco i motivi:

1) Le immagini in Excel non sono dati di cella. Sono oggetti OLE, che puoi pensare che le immagini siano allegati al foglio. Le immagini nella tabella dati JMP sono dati di cella. Quindi Excel e JMP vedono le immagini in modo diverso.

2) Excel probabilmente non capirà mai il significato delle immagini in JMP.

Re: Come salvare un'immagine in jsl

Ecco come esportare il report come file MS Word.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

nw_collector = New Window("",
 vlb = V List Box()
);

cols = {"NPN1", "PNP1"};

For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];

 vlb << Append( // use outlinebox to add title
  OutlineBox("Process Capability for " || col_name, lb);
 );
 dist << Close Window; 
);

vlb << save msword("c:\TEMP\test.doc", native);

 

Re: Come salvare un'immagine in jsl

Penso che far sì che le immagini eccellano richiederà PowerShell (o qualcos'altro come Python) oltre a JSL. È possibile eseguire il codice PowerShell da JMP utilizzando Eseguire il programma()