697226_zh-CN

liliconcom

如何通过jsl保存图片

嗨，JMPer，我想使用 jsl 只保存过程能力的直方图，而不保存任何 . 有什么办法可以实现吗？

 

 

自动化和脚本编写回复: 如何通过jsl保存图片

如果您只想要这些直方图而没有其他任何东西，那么从分发平台一一捕获它们很可能是最简单的

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

nw_collector = New Window("",
 vlb = V List Box()
);

cols = {"NPN1", "PNP1"};

For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];
 pic = lb << Get Picture;
 vlb << Append( // use outlinebox to add title
  OutlineBox("Process Capability for " || col_name, pic)
 );
 dist << Close Window; 
);

当您同时打开所有这些图像时，可以从 Process Capability 或分发中捕获这些图像，但以这种方式导航报告层更容易。

 

回复：如何通过jsl保存图片

最近，我发现将图像保存到数据表在某些用例中可能很有用。 这是一个修改版本，基于@jthi的例子。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

cols = {"NPN1", "PNP1"};
outputdt = New Table( "imgs",
 Add Rows( nitems(cols) ),
 New Column( "image", Expression, "None", Set Values( {} ) ),
);

i = 1;
For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];
 pic = lb << Get Picture;
 outputdt:image[i] = pic;
 i++;
 dist << Close Window; 
);

回复: 如何通过jsl保存图片

非常感谢。

但我还有一个问题，将图像保存到表格后，可以导出为excel文件吗？ 我尝试这样做，但没有显示为图片。

 

回复: 如何通过jsl保存图片

据我所知这是不可能的。 原因如下：

1) Excel 中的图像不是单元格数据。 它们是 OLE 对象，您可以将其视为图像是工作表的附件。 JMP数据表中的图像是单元格数据。 因此 Excel 和 JMP 以不同的方式查看图像。

2) Excel可能永远无法理解JMP中图像的含义。

回复：如何通过jsl保存图片

以下介绍如何将报告导出为 MS Word 文件。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

nw_collector = New Window("",
 vlb = V List Box()
);

cols = {"NPN1", "PNP1"};

For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];

 vlb << Append( // use outlinebox to add title
  OutlineBox("Process Capability for " || col_name, lb);
 );
 dist << Close Window; 
);

vlb << save msword("c:\TEMP\test.doc", native);

 

回复: 如何通过jsl保存图片

我认为除了 jsl 之外，要使图像表现出色还需要 powershell（或其他类似 python 的东西）。 您可以使用 JMP 执行 powershell 代码运行程序()