697226_zh-TW

liliconcom

如何透過jsl儲存圖片

嗨，JMPer，我想使用 jsl 只保存過程能力的直方圖，而不保存任何 . 有什麼辦法可以實現嗎？

 

 

自動化和腳本編寫回覆：如何透過jsl保存圖片

如果您只想要這些直方圖而不需要其他任何東西，那麼從分發平台一一捕獲它們很可能是最簡單的

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

nw_collector = New Window("",
 vlb = V List Box()
);

cols = {"NPN1", "PNP1"};

For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];
 pic = lb << Get Picture;
 vlb << Append( // use outlinebox to add title
  OutlineBox("Process Capability for " || col_name, pic)
 );
 dist << Close Window; 
);

當您同時開啟所有這些影像時，可以從 Process Capability 或分發中擷取這些影像，但以這種方式導航報告層更容易。

 

回覆: 如何透過jsl保存圖片

最近，我發現將圖像保存到資料表在某些用例中可能很有用。 這是一個修改版本，基於@jthi的例子。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

cols = {"NPN1", "PNP1"};
outputdt = New Table( "imgs",
 Add Rows( nitems(cols) ),
 New Column( "image", Expression, "None", Set Values( {} ) ),
);

i = 1;
For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];
 pic = lb << Get Picture;
 outputdt:image[i] = pic;
 i++;
 dist << Close Window; 
);

回覆: 如何透過jsl保存圖片

非常感謝。

但我還有一個問題，將圖像儲存到表格後，可以匯出為excel檔案嗎？ 我嘗試這樣做，但沒有顯示為圖片。

 

回覆: 如何透過jsl保存圖片

據我所知這是不可能的。 原因如下：

1) Excel 中的影像不是儲存格資料。 它們是 OLE 對象，您可以將其視為圖像是工作表的附件。 JMP資料表中的影像是儲存格資料。 因此 Excel 和 JMP 以不同的方式檢視影像。

2) Excel可能永遠無法理解JMP中影像的意義。

回覆: 如何透過jsl保存圖片

以下介紹如何將報告匯出為 MS Word 檔案。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

nw_collector = New Window("",
 vlb = V List Box()
);

cols = {"NPN1", "PNP1"};

For Each({col_name}, cols,
 dist = dt << Distribution(
  Stack(1),
  Continuous Distribution(
   Column(Eval(col_name)),
   Horizontal Layout(1),
   Vertical(0),
   Process Capability(Use Column Property Specs)
  )
 );

 lb = Report(dist)[OutlineBox(col_name || " Capability"), OutlineBox("Histogram"), ListBox(1)];

 vlb << Append( // use outlinebox to add title
  OutlineBox("Process Capability for " || col_name, lb);
 );
 dist << Close Window; 
);

vlb << save msword("c:\TEMP\test.doc", native);

 

回覆: 如何透過jsl保存圖片

我認為除了 jsl 之外，要讓影像表現出色還需要 powershell（或其他類似 python 的東西）。 您可以使用 JMP 執行 powershell 程式碼運行程序()