696688_ko-KR

liliconcom

(1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

아래 스크립트로 생성된 차트에서 빨간색 화살표("구분선")로 표시된 선의 색상을 보라색으로 변경하고 싶습니다. 또한 가장 낮은 y축 변수(이 경우 PNP1)에 대해서만 수평 기준선을 추가하고 싶습니다.

JSL을 통해 이를 수행하는 방법은 무엇입니까?

(실제 사례에서는 y축 데이터가 이 예제 사례와 달리 열에서 나온 것이 아닙니다.)

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
Graph Builder(
 Size( 960, 695 ),
 Variables(
  X( :SITE ),
  X( :lot_id, Position( 1 ) ),
  X( :wafer, Position( 1 ) ),
  Y( :NPN1 ),
  Y( :NPN2 ),
  Y( :PNP3 ),
  Y( :PNP1 )
 ),
 Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 44 ) ) ),
 Elements( Position( 1, 2 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 43 ) ) ),
 Elements( Position( 1, 3 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 38 ) ) ),
 Elements( Position( 1, 4 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 40 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "SITE",
   ScaleBox,
   {Label Row( 3, {Major Grid Line Color( 8 ), Show Major Grid( 1 )} )}
  )
 )
);

 

자동화 및 스크립팅윈도우Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

색상을 통해 수직선과 축 레이블을 연결하는 좋은 아이디어
아쉽게도 선이 너무 얇아서 특징을 알아차리기 어렵습니다.
여러분도 같은 마음이시라면 이 소원을 응원해 주세요.
계층적 X 카테고리에 최적화된 그래픽 설정 - 2가지 옵션

 

 

또는 사이트를 X 그룹으로 사용할 수도 있지만 동기화된 X 축 레이블에 문제가 발생할 가능성이 높습니다.
이 문제를 해결하려는 희망 사항도 있습니다.
X 그룹: 축의 값을 해당 그룹으로 제한합니다.

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << Graph Builder(
 Size( 841, 485 ),
 Show Control Panel( 0 ),
 Show Title( 0 ),
 Show X Axis Title( 0 ),
 Variables(
  X( :SITE ),
  X( :lot_id, Position( 1 ) ),
  X( :wafer, Position( 1 ) ),
  Y( :NPN1 ),
  Y( :NPN2 ),
  Y( :PNP3 ),
  Y( :PNP1 )
 ),
 Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 44 ) ) ),
 Elements( Position( 1, 2 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 43 ) ) ),
 Elements( Position( 1, 3 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 38 ) ) ),
 Elements( Position( 1, 4 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 40 ) ) ),
 SendToReport(
  Dispatch( {}, "SITE", ScaleBox,
   {Label Row(
    1,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    2,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    3,
    {Line Color( "Purple" ), Lower Frame( 1 ), Major Grid Line Color( "Purple" ),
    Row Title Side( "Start" ), Tick Mark Style( "Long Divider" )}
   )}
  ),
  Dispatch( {}, "PNP1", ScaleBox, {Add Ref Line( 300, "Solid", "Black", "", 5 )} ),
  Dispatch( {}, "Graph Builder", FrameBox( 4 ), {Reference Line Order( 3 )} )
 )
)

 

 

 

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

무슨 뜻이야?

 

@네오 썼다:

(실제 사례에서는 y축 데이터가 이 예제 사례와 달리 열에서 나온 것이 아닙니다.)

 

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

@호기

>> (실제 사례에서는 y축 데이터가 이 예제 사례와 달리 열에서 나온 것이 아닙니다.)

실제 사례에서는 y축 매개변수가 행 매개변수의 로컬 데이터 필터 선택에서 나옵니다.

(열에서 나온 것이라면 참조선에 대한 사양에 제한이 설정되어 있을 수 있습니다. (이것을 시도한 것은 아니지만 작동할 것으로 예상합니다.)

 

데모용 데이터 세트를 만들 수 있는지 살펴보겠습니다(다시 돌아올게요 ).

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

안녕 @네오 ,

 

그 코드는 @호기 게시된 내용은 그래프 빌더 내에서 단일 하위 플롯에 대한 참조선을 얻는 문제를 해결할 것입니다. 하지만 안타깝게도 트리 구조를 살펴보면 x- 중심선. 트리 구조에서는 전체 x축이 단일 AxisBox(1) 요소로 그룹화되어 있으며, 그래프 빌더에서는 그렇게 표시되지만 분할되거나 중첩되지 않습니다. 또한 중첩된 축 선을 수정할 수 있는 기본 설정 내에서 아무것도 찾을 수 없습니다.

 

언제든지 원하는 축을 마우스 오른쪽 버튼으로 클릭하고 참조선을 추가한 다음 그래프 빌더 옆에 있는 빨간색 핫 버튼으로 이동하여 스크립트를 스크립팅 창에 저장하면 스크립트가 어떻게 수정되는지 확인할 수 있습니다. 라인 추가.

 

도움이 되었기를 바랍니다!,

DS

 

편집: 중첩된 축의 색상을 변경할 수 있도록 요청을 제출하는 것이 좋습니다. 이는 실행 가능해야 하며 많은 사람들이 혜택을 누릴 수 있다고 생각합니다.

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

어느 라인이 문제인가요?

현재 가장 낮은 플롯에는 단 하나의 수평선만 있습니다.

 

참조선의 일부를 숨겨야 하는 경우 모든 하위 플롯에 고유한 사용자 정의 설정이 있다는 사실을 활용하여 일부 직사각형을 추가하고 참조선 앞에 배치할 수 있습니다.

 

[또는 사용자 정의 스크립트를 직접 사용하여 선분을 추가할 수도 있습니다.]

 

 

 

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << Graph Builder(
 Show Control Panel( 0 ),
 Show Title( 0 ),
 Show X Axis Title( 0 ),
 Variables(
  X( :SITE ),
  X( :lot_id, Position( 1 ) ),
  X( :wafer, Position( 1 ) ),
  Y( :NPN1 ),
  Y( :NPN2 ),
  Y( :PNP3 ),
  Y( :PNP1 )
 ),
 Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 44 ) ) ),
 Elements( Position( 1, 2 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 43 ) ) ),
 Elements( Position( 1, 3 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 38 ) ) ),
 Elements( Position( 1, 4 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 40 ) ) ),
 SendToReport(
  Dispatch( {}, "SITE", ScaleBox,
   {Add Ref Line( 714.422378299564, "Solid", "Red", "", 4 ),
   Label Row(
    1,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    2,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    3,
    {Line Color( "Purple" ), Line Width( 3 ), Lower Frame( 1 ),
    Major Grid Line Color( "Purple" ), Row Title Side( "Start" ),
    Tick Mark Style( "Long Divider" )}
   )}
  ),
  Dispatch( {}, "PNP3", ScaleBox, {Add Ref Line( 135, "Solid", "Red", "", 3 )} ),
  Dispatch( {}, "PNP1", ScaleBox, {Add Ref Line( 300, "Solid", "Black", "", 5 )} ),
  Dispatch( {}, "400", ScaleBox,
   {Legend Model( 38, Properties( 0, {Transparency( 0.5 )}, Item ID( "PNP3", 1 ) ) )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox,
   {Grid Line Order( 2 ), Reference Line Order( 1 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Fill Color( white );
    Rect( -10000, 10000, 10000, -10000, 1 );
   )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox( 2 ),
   {Grid Line Order( 2 ), Reference Line Order( 1 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Fill Color( white );
    Rect( -10000, 10000, 10000, -10000, 1 );
   )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox( 3 ),
   {Grid Line Order( 2 ), Reference Line Order( 1 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Fill Color( white );
    Rect( 290, 10000, 10000, -10000, 1 );
   )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox( 4 ), {Reference Line Order( 3 )} )
 )
)

 

 

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

@호기 @SDF1 첨부된 데이터 테이블은 실제 데이터와 유사하게 구성된 데이터 테이블(내부에 플롯 스크립트 포함)입니다. 로컬 데이터 필터에서 테스트 3단계를 선택한 경우에만 참조선(아래 빨간색)이 나타나도록 하고 싶습니다.

(기준선 y 위치는 미리 정의되어 있습니다)

 

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

@SDF1

이렇게 하면 내가 원하는 것이 아닌 모든 하위 플롯에 참조선이 추가됩니다.

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

이는 Y 그룹으로 인해 그래프가 서로 다른 FrameBox로 분할되는 쉬운 경우입니다. 그런 다음 사용자 정의를 통해 개별 참조선을 추가할 수 있습니다.

 

Graph Builder(
 Y Group Edge( "Left" ),

 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) ),

 SendToReport(
  Dispatch(
   {},
   "Graph Builder",
   FrameBox( 3 ),
   {Add Graphics Script(
    2,
    Description( "" ),
    Pen Color( "red" );
    Pen Size( 3 );
    Y Function( 0.4, x );
   )}
  )
 )
)

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

안녕 @네오 ,

 

나는 다음과 같이 할 것이다 @호기 관심 있는 그래프를 마우스 오른쪽 버튼으로 클릭하고 "+"를 클릭하여 GB에 새 스크립트를 추가한 다음 줄에 추가하기 위해 JSL을 입력할 때 사용자 정의 옵션을 제안하고 사용합니다.

 

 

이제 이것이 로컬 데이터 필터에 동적으로 응답하도록 하는 것이 더 어려울 것이라고 생각합니다. 그러한 종류의 기능이 필요한 경우 대신 그래프 빌더가 내장된 자체 보고서 창을 생성한 다음 확인란을 사용하여 사용자가 다른 TestStage 확인란을 선택할 때 참조선으로 하위 도표를 업데이트할 수 있는 옵션을 제공할 수 있습니다.

 

중첩된 선 색상을 변경하는 방법도 알아냈습니다. 이것이 "올바른" 방법인지, 아니면 가장 빠른 방법인지는 모르겠지만, 중첩 축을 마우스 오른쪽 버튼으로 클릭한 다음 속성 표시를 선택하고, 중첩 축을 클릭한 다음 AxisBox 옆에 있는 빨간색 핫 버튼을 클릭하고 축 설정 복사를 선택한 다음 스크립팅 창에 붙여넣고 편집할 수 있습니다. 관심 있는 축을 선택하고 선 색상을 "없음"에서 원하는 색상으로 변경합니다. 그런 다음 이 편집된 코드를 복사하고 빨간색 핫 버튼으로 돌아가서 축 설정 붙여넣기를 선택하면 그래프가 업데이트됩니다. 이렇게 하면 작업이 완료되지만 이 작업을 어떻게 동적으로 수행할 수 있는지 잘 모르겠습니다.

 

해당 스크립트를 스크립팅 창에 저장하면 원하는 결과를 얻기 위해 그래프 빌더 및 레이블 행을 보내는 데 필요한 명령을 볼 수 있습니다.

Graph Builder(
 Size( 592, 526 ),
 Y Group Edge( "Left" ),
 Graph Spacing( 4 ),
 Variables(
  X( :TestStage ),
  X( :TestParameter, Position( 1 ) ),
  Y( :Median ),
  Group Y( :TestStage )
 ),
 Elements(
  Points( X( 1 ), X( 2 ), Y, Legend( 33 ) ),
  Smoother( X( 1 ), X( 2 ), Y, Legend( 34 ) )
 ),
 Local Data Filter(
  Conditional,
  Add Filter( columns( :TestStage ), Where( :TestStage == {1, 2, 3} ) )
 ),
 SendToReport(
  Dispatch(
   {},
   "TestStage",
   ScaleBox,
   {Label Row( 2, Line Color( "Purple" ) )}
  ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox( 3 ),
   {Add Graphics Script(
    2,
    Description( "" ),
    Pen Color( "red" );
    Pen Size( 3 );
    Y Function( 0.3, x );
   )}
  )
 )
);

이 정보를 사용하고 Semiconductor Capability.jmp 파일을 사용하여 원래 게시물로 돌아오면 원래 요청했던 것을 얻을 수 있습니다. 중첩된 축은 보라색이고 수직 격자선은 보라색이며 다음에 대한 참조선만 있습니다. 맨 아래 그래프. 이 특별한 경우에는 그래프 빌더의 하위 도표에 서로 다른 열을 표시하기 때문에 참조선을 추가하려는 축을 두 번 클릭하면 작동합니다. 공유한 예제 데이터 테이블의 경우 사용자 정의를 사용하여 다른 방식으로 수행하고 Y 함수()를 추가해야 합니다.

위의 그래프를 생성한 JSL 코드는 다음과 같습니다. 특정 사례에 대해 적절하게 편집해야 하는 위치를 확인할 수 있습니다.

Names Default to Here(1);

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

dt<<GRAPH builder=""></GRAPH>

도움이 되었기를 바랍니다!,

DS

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

값 자체에서 평균을 계산할 수 있습니다.

Graph Builder(
 Y Group Edge( "Left" ), 

 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) )
);

myFB = Current Report()[FrameBox( 3 )];
myFB << Add Graphics Script(
 2,
 Description( "" ),
<STRONG> mySeg = myFB << Find Seg( Marker Seg( 1 ) );
 value = Mean( mySeg << Get Y Values );</STRONG>
 Pen Color( "red" );
 Pen Size( 3 );
 Y Function( value, x );
);

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

@SDF1 감사해요. 중첩된 축의 색상을 어떻게 보라색으로 변경했는지 확인해 보겠습니다. 그러는 동안 나는 @호기 제안 및 필터 변경 처리기 만들기()를 사용하여 사용자가 필터 선택을 변경할 때 JMP가 참조선을 배치하는 위치를 동적으로 변경합니다. 아직 두 가지 문제를 해결하지 못했습니다.

1. 필터 변경 핸들러는 차트가 처음으로 플롯될 때 트리거되지 않고 다음 TestStage가 선택될 때만 트리거됩니다.

2. 필터가 변경되면 이전 참조선이 다른 테스트 단계에 남아 있는데, 그 이유를 이해하지만 아직 제거할 수는 없습니다.  

Names Default To Here (1);
clear log ();

gb = Graph Builder(
 Y Group Edge( "Left" ),
 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) ),
 Local Data Filter(
  Conditional,
  Add Filter( columns( :TestStage ), Where( :TestStage == {1} ) )
 )
);

ldf = Current Report()["Local Data Filter"] << get scriptable object;

getTestStage = Function( {this}, //print (this);
                          
                          testStateFiltered = Associative Array(:TestStage [ldf << get filtered rows]) << get keys; 
                                                    
                          gb << SendToReport(
                                
        Dispatch({},"Graph Builder", 
        FrameBox(N Items (testStateFiltered)), {Add Graphics Script( 2, Description( "" ), Pen Color( "red" ); Line Style ("dashed"); Pen Size( 0.25 );
           Y Function( 0.2, x );
          )}
         )        
        );      
                          show (N Items (testStateFiltered));  Print(testStateFiltered);
                          );
rs = ldf << Make Filter Change Handler( getTestStage() ); 

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

그런데 Jmp17에는 새로운 기능이 있습니다:
통계 값을 기반으로 동적 참조선 추가

Graph Builder(
 Y Group Edge( "Left" ),
 Summary Statistic( "Median" ),
 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements(
  Points( X, Y, Legend( 33 ) ),
  Smoother( X, Y, Legend( 34 ) ),
  Caption Box(
   X,
   Y,
<STRONG>   Summary Statistic( "Median" ),
   Location( "Axis Reference Line" )</STRONG>
  )
 ),
 Local Data Filter(
  Conditional,
  Add Filter( columns( :TestStage ), Where( :TestStage == 1 ) )
 )
)

 

 

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

안녕 @네오 ,

 

그거 참 좋은 아이디어네요 @호기 필터 변경 핸들러 사용에 관한 것입니다. 나는 그것을 생각하지 못했습니다. 발생한 두 가지 문제를 해결하기 위해 위 코드를 수정했습니다. 이제 스크립트는 참조선이 있는 첫 번째 그래프를 생성한 다음, 둘 이상의 데이터 필터를 선택하는 경우에도 이에 따라 각 그래프를 업데이트합니다. 문제가 해결되었나요?

Names Default To Here( 1 );

dt = Current Data Table();

//this creates a string list of the column names
ColNamesList = dt << Get Column Names( "string" );

//This tests if the there exist a :Mean Column. If not, it runs a summary to generate this data, updates the main table with the means and then deletes a column and closes out the summary table.
If( Contains( ColNamesList, "Mean" ) == 0,
 dtMeans = dt << Summary(
  Group( :TestParameter ),
  Mean( :Median ),
  Freq( "None" ),
  Weight( "None" ),
  statistics column name format( "stat" ),
  Link to original data table( 0 ),
  output table name( "MeanStats" )
 );
 dt << Update( With( dtMeans ), Match Columns( :TestParameter = :TestParameter ) );

 dt << Delete Columns( :N Rows );

 Close( dtMeans, NoSave );
);

//this makes the original graph with the reference line of the first row in column :Mean
gb = dt << Graph Builder(
 Y Group Edge( "Left" ),
 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) ),
 Dispatch(
  {},
  "Graph Builder",
  FrameBox( N Items( testStateFiltered ) ),
  {Add Graphics Script(
   2,
   Description( "" ),
   Pen Color( "red" );
   Line Style( "dashed" );
   Pen Size( 0.25 );
   Y Function( Eval( :Mean[1] ), x );
  )}
 ),
 Local Data Filter( Conditional, Add Filter( columns( :TestStage ), Where( :TestStage == 1 ) ) )//no {} around the 1 here.
);

ldf = Current Report()["Local Data Filter"] << get scriptable object;

getTestStage = Function( {this}, //print (this);
                          
 testStateFiltered = Associative Array( :TestStage[ldf << get filtered rows] ) << get keys;
 
 //this finds which row to grab the mean from
 mrows = dt << Get Rows where( :TestStage == testStateFiltered[1] );
 
 //this defines the mean to Eval() in the Y Function()
 gbmean = :Mean[mrows[1]];
 
 If( N Items( testStateFiltered ) == 1, //only does this if only one data filter is selected
  gbreport = gb << Report; //makes a report reference for the graph builder
  fb = gbreport[GraphBuilderComponentBox( 17 )];//accesses the frame to remove the script from
  fb << Remove Graphics Script( 1 );//removes most recent script from the frame
 );
                                                    
 gb << SendToReport(
                                
  Dispatch(
   {},
   "Graph Builder",
   FrameBox( N Items( testStateFiltered ) ),
   {Add Graphics Script(
    2,
    Description( "" ),
    Pen Color( "red" );
    Line Style( "dashed" );
    Pen Size( 0.25 );
    Y Function( Eval( GBMean ), x );
   )}
  )
 );
 Show( N Items( testStateFiltered ) );
 Print( testStateFiltered );
);

rs = ldf << Make Filter Change Handler( getTestStage() );

도움이 되었기를 바랍니다!,

DS

 

  

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

처음에는 달릴 수 있어요 getTestStage(1) 수동으로.
데이터 필터를 사용하면 GraphBuilder에 1-3개의 FrameBox가 있다는 점에 유의하십시오(대부분의 경우 1개?). 따라서 메시지를 보낼 FB를 결정하거나 TestStage 하나를 선택하고 항상 명령을 프레임박스 1로 보냅니다.

Re: (1) AxisBox의 기본 색상을 변경하고 (2) 그룹화된 Y 플롯에서 하나의 Y축 변수에만 참조선을 추가하는 방법은 무엇입니까?

@SDF1 @호기

제가 공유한 데이터 테이블은 예시로 빠르게 정리한 것입니다. 참조선을 생성하기 위해 이 표에 있는 LSL/USL 또는 다른 숫자를 사용할 수 없다는 점을 언급했어야 했습니다.

 

어쨌든 다음은 나에게 효과적이었습니다.

• 부름 필터 변경 핸들러 호출 전 getTestStage(1).
• getTestStage 함수 내에 적절한 핸들이 있는 RemoveGraphicsScript(N)를 추가합니다. 여기서 N은 TestStage 필터가 변경될 때 생성된 마지막으로 선택한 TestStage 프레임박스 번호에서 얻은 FrameBox 번호입니다.

이제 이것으로 만족하겠습니다. 그러나 한 가지 남은 문제가 있습니다. 하나의 TestStage를 선택한 다음 두 번째, 세 번째를 선택하면 모든 것이 예상대로 작동하지만 3개 선택 항목에서 다시 하나로 돌아가면 스크립트가 예상대로 작동하지 않습니다.

기회가 되면 문제를 설명하는 스크립트와 함께 대표 데이터 세트를 게시하겠습니다.