696688_de-DE

liliconcom

Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) in gruppierten Y-Diagrammen eine Referenzlinie nur in einer Y-Achsenvariablen hinzufügen?

In dem vom Skript unten generierten Diagramm möchte ich die Farbe der durch die roten Pfeile angezeigten Linien („die Trennlinien“) in Lila ändern. Außerdem möchte ich nur für die niedrigste Y-Achsenvariable (in diesem Fall PNP1) eine horizontale Referenzlinie hinzufügen.

Wie macht man das über JSL?

(Beachten Sie, dass in meinem tatsächlichen Fall die Y-Achsendaten im Gegensatz zu diesem Beispielfall nicht aus einer Spalte stammen.)

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
Graph Builder(
 Size( 960, 695 ),
 Variables(
  X( :SITE ),
  X( :lot_id, Position( 1 ) ),
  X( :wafer, Position( 1 ) ),
  Y( :NPN1 ),
  Y( :NPN2 ),
  Y( :PNP3 ),
  Y( :PNP1 )
 ),
 Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 44 ) ) ),
 Elements( Position( 1, 2 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 43 ) ) ),
 Elements( Position( 1, 3 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 38 ) ) ),
 Elements( Position( 1, 4 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 40 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "SITE",
   ScaleBox,
   {Label Row( 3, {Major Grid Line Color( 8 ), Show Major Grid( 1 )} )}
  )
 )
);

 

Automatisierung und SkripterstellungWindowsBetreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

schöne Idee, die vertikalen Linien und die Achsenbeschriftungen farblich zu verknüpfen
Leider sind die Linien so dünn, dass man das Merkmal kaum erkennen kann.
Wenn Sie das gleiche Gefühl haben, unterstützen Sie bitte diesen Wunsch:
Optimierte Grafikeinstellungen für hierarchische X-Kategorien – 2 Optionen

 

 

Alternativ könnten Sie die Site als X-Gruppe verwenden – höchstwahrscheinlich werden Sie jedoch auf das Problem mit den synchronisierten X-Achsenbeschriftungen stoßen.
Es besteht auch der Wunsch, dieses Problem zu beheben:
X-Gruppe: Beschränken Sie die Werte auf der Achse auf die jeweilige Gruppe

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << Graph Builder(
 Size( 841, 485 ),
 Show Control Panel( 0 ),
 Show Title( 0 ),
 Show X Axis Title( 0 ),
 Variables(
  X( :SITE ),
  X( :lot_id, Position( 1 ) ),
  X( :wafer, Position( 1 ) ),
  Y( :NPN1 ),
  Y( :NPN2 ),
  Y( :PNP3 ),
  Y( :PNP1 )
 ),
 Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 44 ) ) ),
 Elements( Position( 1, 2 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 43 ) ) ),
 Elements( Position( 1, 3 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 38 ) ) ),
 Elements( Position( 1, 4 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 40 ) ) ),
 SendToReport(
  Dispatch( {}, "SITE", ScaleBox,
   {Label Row(
    1,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    2,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    3,
    {Line Color( "Purple" ), Lower Frame( 1 ), Major Grid Line Color( "Purple" ),
    Row Title Side( "Start" ), Tick Mark Style( "Long Divider" )}
   )}
  ),
  Dispatch( {}, "PNP1", ScaleBox, {Add Ref Line( 300, "Solid", "Black", "", 5 )} ),
  Dispatch( {}, "Graph Builder", FrameBox( 4 ), {Reference Line Order( 3 )} )
 )
)

 

 

 

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Was meinst du mit

 

@Neo schrieb:

(Beachten Sie, dass in meinem tatsächlichen Fall die Y-Achsendaten im Gegensatz zu diesem Beispielfall nicht aus einer Spalte stammen.)

 

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

@hogi

>> (Beachten Sie, dass in meinem tatsächlichen Fall die Y-Achsendaten im Gegensatz zu diesem Beispielfall nicht aus einer Spalte stammen.)

In meinem tatsächlichen Fall stammen die Y-Achsen-Parameter aus der lokalen Datenfilterauswahl von Zeilenparametern

(Wenn es aus einer Spalte stammte, hätte ich in den Spezifikationen einen Grenzwert für die Referenzlinie festlegen können (nicht, dass ich das versucht hätte, aber ich erwarte, dass es funktioniert))

 

Mal sehen, ob ich einen Datensatz für die Demo zusammenstellen kann (ich komme wieder ).

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Hallo @Neo ,

 

Der Code, der @hogi gepostet wird Ihr Problem lösen, eine Referenzlinie für einen einzelnen Unterplot in Ihrem Diagrammersteller zu erhalten, aber wenn ich mir die Baumstruktur ansehe, sehe ich leider keine Möglichkeit, einen Befehl zu senden, der nur diese eine Zeile des x- ändern würde. Achse. In der Baumstruktur ist die gesamte x-Achse in einem einzigen AxisBox(1)-Element gruppiert, sie ist nicht unterteilt und verschachtelt, auch wenn sie im Graph Builder so angezeigt wird. Ich konnte in den Einstellungen auch nichts finden, was es erlaubt, verschachtelte Achsenlinien zu ändern.

 

Sie können jederzeit mit der rechten Maustaste auf eine Achse klicken, die Sie haben möchten, und dann eine Referenzlinie hinzufügen, dann auf den roten Hot-Button neben dem Diagrammersteller gehen und das Skript im Skriptfenster speichern, und Sie können sehen, wie das Skript durch geändert wird Ergänzung der Zeile.

 

Hoffe das hilft!,

DS

 

Bearbeiten: Es könnte sich lohnen, eine Anfrage zu stellen, um die Farben verschachtelter Achsen ändern zu können. Das sollte machbar sein und ich könnte mir vorstellen, dass viele Menschen davon profitieren könnten.

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Welche Zeile ist das Problem?

Im Moment gibt es im untersten Diagramm nur eine einzige horizontale Linie.

 

Wenn Sie Teile von Referenzlinien ausblenden müssen, können Sie die Tatsache nutzen, dass jeder Unterplot über eigene Anpassungseinstellungen verfügt, sodass Sie einige Rechtecke hinzufügen und diese vor der Referenzlinie platzieren können.

 

[Alternativ können Sie auch direkt das Anpassungsskript verwenden, um ein Liniensegment hinzuzufügen.]

 

 

 

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
dt << Graph Builder(
 Show Control Panel( 0 ),
 Show Title( 0 ),
 Show X Axis Title( 0 ),
 Variables(
  X( :SITE ),
  X( :lot_id, Position( 1 ) ),
  X( :wafer, Position( 1 ) ),
  Y( :NPN1 ),
  Y( :NPN2 ),
  Y( :PNP3 ),
  Y( :PNP1 )
 ),
 Elements( Position( 1, 1 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 44 ) ) ),
 Elements( Position( 1, 2 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 43 ) ) ),
 Elements( Position( 1, 3 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 38 ) ) ),
 Elements( Position( 1, 4 ), Points( X( 1 ), X( 2 ), X( 3 ), Y, Legend( 40 ) ) ),
 SendToReport(
  Dispatch( {}, "SITE", ScaleBox,
   {Add Ref Line( 714.422378299564, "Solid", "Red", "", 4 ),
   Label Row(
    1,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    2,
    {Lower Frame( 1 ), Row Title Side( "Start" ), Show Major Grid( 0 ),
    Tick Mark Style( "Long Divider" )}
   ), Label Row(
    3,
    {Line Color( "Purple" ), Line Width( 3 ), Lower Frame( 1 ),
    Major Grid Line Color( "Purple" ), Row Title Side( "Start" ),
    Tick Mark Style( "Long Divider" )}
   )}
  ),
  Dispatch( {}, "PNP3", ScaleBox, {Add Ref Line( 135, "Solid", "Red", "", 3 )} ),
  Dispatch( {}, "PNP1", ScaleBox, {Add Ref Line( 300, "Solid", "Black", "", 5 )} ),
  Dispatch( {}, "400", ScaleBox,
   {Legend Model( 38, Properties( 0, {Transparency( 0.5 )}, Item ID( "PNP3", 1 ) ) )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox,
   {Grid Line Order( 2 ), Reference Line Order( 1 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Fill Color( white );
    Rect( -10000, 10000, 10000, -10000, 1 );
   )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox( 2 ),
   {Grid Line Order( 2 ), Reference Line Order( 1 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Fill Color( white );
    Rect( -10000, 10000, 10000, -10000, 1 );
   )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox( 3 ),
   {Grid Line Order( 2 ), Reference Line Order( 1 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Fill Color( white );
    Rect( 290, 10000, 10000, -10000, 1 );
   )}
  ),
  Dispatch( {}, "Graph Builder", FrameBox( 4 ), {Reference Line Order( 3 )} )
 )
)

 

 

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

@hogi @SDF1 Im Anhang finden Sie eine vorbereitete Datentabelle (mit darin enthaltenem Plot-Skript), die meinen tatsächlichen Daten ähnelt. Ich möchte, dass eine Referenzlinie (unten rot) nur erscheint, wenn im lokalen Datenfilter Teststufe 3 ausgewählt ist.

(Y-Position der Referenzlinie ist vordefiniert)

 

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

@SDF1

Dadurch werden allen Nebenhandlungen Referenzlinien hinzugefügt, was nicht das ist, was ich möchte.

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Dies ist der einfache Fall, in dem die Diagramme aufgrund der Y-Gruppe in verschiedene FrameBoxes aufgeteilt werden. Anschließend können Sie über Anpassen einfach einzelne Referenzlinien hinzufügen.

 

Graph Builder(
 Y Group Edge( "Left" ),

 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) ),

 SendToReport(
  Dispatch(
   {},
   "Graph Builder",
   FrameBox( 3 ),
   {Add Graphics Script(
    2,
    Description( "" ),
    Pen Color( "red" );
    Pen Size( 3 );
    Y Function( 0.4, x );
   )}
  )
 )
)

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Hallo @Neo ,

 

Ich würde es so machen @hogi vorgeschlagen und verwenden Sie die Option „Anpassen“, wenn Sie mit der rechten Maustaste auf das gewünschte Diagramm klicken, auf das „+“ klicken, um ein neues Skript zu GB hinzuzufügen, und dann die JSL zum Hinzufügen einer Zeile eingeben.

 

 

Nun wäre es meiner Meinung nach eine größere Herausforderung, dies dynamisch auf den lokalen Datenfilter reagieren zu lassen. Wenn Sie diese Art von Funktionalität benötigen, würde ich stattdessen mein eigenes Berichtsfenster erstellen, in das der Graph Builder integriert ist, und dann möglicherweise Kontrollkästchen verwenden, um dem Benutzer die Möglichkeit zu geben, die Unterdiagramme mit Referenzlinien zu aktualisieren, wenn er die verschiedenen TestStage-Kontrollkästchen auswählt.

 

Ich habe auch eine Möglichkeit gefunden, die Farbe der verschachtelten Linien zu ändern. Ich weiß nicht, ob dies der „richtige“ Weg ist oder ob es sogar der schnellste Weg ist, aber wenn Sie mit der rechten Maustaste auf die verschachtelte Achse klicken und dann „Eigenschaften anzeigen“ auswählen, wenn Sie auf die verschachtelte Achse klicken und dann klicken Klicken Sie auf den roten Hot-Button neben AxisBox, wählen Sie „Achseneinstellungen kopieren“ aus, Sie können es dann in ein Skriptfenster einfügen und bearbeiten. Wählen Sie die gewünschte Achse aus und ändern Sie die Linienfarbe von „Keine“ in die gewünschte Farbe. Anschließend müssen Sie diesen bearbeiteten Code kopieren, zum roten Hot-Button zurückkehren, Achseneinstellungen einfügen auswählen und das Diagramm wird aktualisiert. Damit wird die Arbeit erledigt, aber ich bin mir nicht sicher, wie dies dynamisch erledigt werden kann.

 

Wenn Sie das entsprechende Skript in einem Skriptfenster speichern, können Sie die Befehle sehen, die Sie an den Graph Builder und die Label Row senden müssen, um das gewünschte Ergebnis zu erhalten.

Graph Builder(
 Size( 592, 526 ),
 Y Group Edge( "Left" ),
 Graph Spacing( 4 ),
 Variables(
  X( :TestStage ),
  X( :TestParameter, Position( 1 ) ),
  Y( :Median ),
  Group Y( :TestStage )
 ),
 Elements(
  Points( X( 1 ), X( 2 ), Y, Legend( 33 ) ),
  Smoother( X( 1 ), X( 2 ), Y, Legend( 34 ) )
 ),
 Local Data Filter(
  Conditional,
  Add Filter( columns( :TestStage ), Where( :TestStage == {1, 2, 3} ) )
 ),
 SendToReport(
  Dispatch(
   {},
   "TestStage",
   ScaleBox,
   {Label Row( 2, Line Color( "Purple" ) )}
  ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox( 3 ),
   {Add Graphics Script(
    2,
    Description( "" ),
    Pen Color( "red" );
    Pen Size( 3 );
    Y Function( 0.3, x );
   )}
  )
 )
);

Wenn Sie diese Informationen verwenden und mit der Datei Semiconductor Capability.jmp zu Ihrem ursprünglichen Beitrag zurückkehren, können Sie erreichen, was Sie ursprünglich verlangt haben: Die verschachtelte Achse ist lila, die vertikalen Gitterlinien sind lila und es gibt nur eine Referenzlinie für das unterste Diagramm. In diesem speziellen Fall funktioniert ein Doppelklick auf die Achse, zu der Sie die Referenzlinie hinzufügen möchten, da Sie in den Unterdiagrammen des Graph Builder verschiedene Spalten zeichnen. Für die Beispieldatentabelle, die Sie freigegeben haben, müssen Sie es umgekehrt mit „Anpassen“ und dem Hinzufügen einer Y-Funktion() machen.

Hier ist der JSL-Code, der das obige Diagramm generiert hat. Sie können sehen, wo Sie für Ihren speziellen Fall die entsprechenden Änderungen vornehmen müssen.

Names Default to Here(1);

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

dt<<GRAPH builder=""></GRAPH>

Hoffe das hilft!,

DS

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Sie könnten den Mittelwert aus den Werten selbst berechnen:

Graph Builder(
 Y Group Edge( "Left" ), 

 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) )
);

myFB = Current Report()[FrameBox( 3 )];
myFB << Add Graphics Script(
 2,
 Description( "" ),
<STRONG> mySeg = myFB << Find Seg( Marker Seg( 1 ) );
 value = Mean( mySeg << Get Y Values );</STRONG>
 Pen Color( "red" );
 Pen Size( 3 );
 Y Function( value, x );
);

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

@SDF1 Danke. Ich werde überprüfen, wie Sie es geschafft haben, die Farbe der verschachtelten Achse in Lila zu ändern. Mittlerweile habe ich verwendet @hogi Vorschlag und Make Filter Change Handler (), um die Position, an der JMP die Referenzlinie platziert, dynamisch zu ändern, wenn der Benutzer die Filterauswahl ändert. Zwei Probleme damit habe ich noch nicht gelöst.

1. Der Filteränderungshandler wird nicht ausgelöst, wenn das Diagramm zum ersten Mal gezeichnet wird, sondern erst, wenn die nächste Testphase ausgewählt wird.

2. Wenn der Filter geändert wird, verbleibt die frühere Referenzlinie auf einer anderen Teststufe. Ich verstehe den Grund dafür, konnte sie aber noch nicht entfernen.  

Names Default To Here (1);
clear log ();

gb = Graph Builder(
 Y Group Edge( "Left" ),
 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) ),
 Local Data Filter(
  Conditional,
  Add Filter( columns( :TestStage ), Where( :TestStage == {1} ) )
 )
);

ldf = Current Report()["Local Data Filter"] << get scriptable object;

getTestStage = Function( {this}, //print (this);
                          
                          testStateFiltered = Associative Array(:TestStage [ldf << get filtered rows]) << get keys; 
                                                    
                          gb << SendToReport(
                                
        Dispatch({},"Graph Builder", 
        FrameBox(N Items (testStateFiltered)), {Add Graphics Script( 2, Description( "" ), Pen Color( "red" ); Line Style ("dashed"); Pen Size( 0.25 );
           Y Function( 0.2, x );
          )}
         )        
        );      
                          show (N Items (testStateFiltered));  Print(testStateFiltered);
                          );
rs = ldf << Make Filter Change Handler( getTestStage() ); 

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Übrigens gibt es eine neue Funktion in Jmp17:
Fügen Sie dynamische Referenzlinien basierend auf Statistikwerten hinzu

Graph Builder(
 Y Group Edge( "Left" ),
 Summary Statistic( "Median" ),
 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements(
  Points( X, Y, Legend( 33 ) ),
  Smoother( X, Y, Legend( 34 ) ),
  Caption Box(
   X,
   Y,
<STRONG>   Summary Statistic( "Median" ),
   Location( "Axis Reference Line" )</STRONG>
  )
 ),
 Local Data Filter(
  Conditional,
  Add Filter( columns( :TestStage ), Where( :TestStage == 1 ) )
 )
)

 

 

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Hallo @Neo ,

 

Das ist eine sehr coole Idee @hogi hat in Bezug auf die Verwendung eines Filter Change Handlers. Daran hatte ich nicht gedacht. Ich habe Ihren obigen Code geändert, um die beiden Probleme zu beheben, die Sie hatten. Das Skript erstellt nun das erste Diagramm mit der Referenzlinie und aktualisiert dann jedes Diagramm entsprechend, auch wenn mehr als ein Datenfilter ausgewählt wird. Löst dies das Problem?

Names Default To Here( 1 );

dt = Current Data Table();

//this creates a string list of the column names
ColNamesList = dt << Get Column Names( "string" );

//This tests if the there exist a :Mean Column. If not, it runs a summary to generate this data, updates the main table with the means and then deletes a column and closes out the summary table.
If( Contains( ColNamesList, "Mean" ) == 0,
 dtMeans = dt << Summary(
  Group( :TestParameter ),
  Mean( :Median ),
  Freq( "None" ),
  Weight( "None" ),
  statistics column name format( "stat" ),
  Link to original data table( 0 ),
  output table name( "MeanStats" )
 );
 dt << Update( With( dtMeans ), Match Columns( :TestParameter = :TestParameter ) );

 dt << Delete Columns( :N Rows );

 Close( dtMeans, NoSave );
);

//this makes the original graph with the reference line of the first row in column :Mean
gb = dt << Graph Builder(
 Y Group Edge( "Left" ),
 Variables( X( :PartNumber ), Y( :Median ), Group Y( :TestStage ) ),
 Elements( Points( X, Y, Legend( 33 ) ), Smoother( X, Y, Legend( 34 ) ) ),
 Dispatch(
  {},
  "Graph Builder",
  FrameBox( N Items( testStateFiltered ) ),
  {Add Graphics Script(
   2,
   Description( "" ),
   Pen Color( "red" );
   Line Style( "dashed" );
   Pen Size( 0.25 );
   Y Function( Eval( :Mean[1] ), x );
  )}
 ),
 Local Data Filter( Conditional, Add Filter( columns( :TestStage ), Where( :TestStage == 1 ) ) )//no {} around the 1 here.
);

ldf = Current Report()["Local Data Filter"] << get scriptable object;

getTestStage = Function( {this}, //print (this);
                          
 testStateFiltered = Associative Array( :TestStage[ldf << get filtered rows] ) << get keys;
 
 //this finds which row to grab the mean from
 mrows = dt << Get Rows where( :TestStage == testStateFiltered[1] );
 
 //this defines the mean to Eval() in the Y Function()
 gbmean = :Mean[mrows[1]];
 
 If( N Items( testStateFiltered ) == 1, //only does this if only one data filter is selected
  gbreport = gb << Report; //makes a report reference for the graph builder
  fb = gbreport[GraphBuilderComponentBox( 17 )];//accesses the frame to remove the script from
  fb << Remove Graphics Script( 1 );//removes most recent script from the frame
 );
                                                    
 gb << SendToReport(
                                
  Dispatch(
   {},
   "Graph Builder",
   FrameBox( N Items( testStateFiltered ) ),
   {Add Graphics Script(
    2,
    Description( "" ),
    Pen Color( "red" );
    Line Style( "dashed" );
    Pen Size( 0.25 );
    Y Function( Eval( GBMean ), x );
   )}
  )
 );
 Show( N Items( testStateFiltered ) );
 Print( testStateFiltered );
);

rs = ldf << Make Filter Change Handler( getTestStage() );

Hoffe das hilft!,

DS

 

  

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

Beim ersten Mal kannst du laufen getTestStage(1) manuell.
Bitte beachten Sie, dass es beim Datenfilter 1-3 FrameBoxes im GraphBuilder gibt (meistens nur 1?). Entweder Sie legen also fest, an welche FB die Nachricht gesendet werden soll – oder Sie wählen einfach eine TestStage aus und senden den Befehl immer an Framebox 1.

Betreff: Wie kann ich (1) die Standardfarbe in AxisBox ändern und (2) eine Referenzlinie in nur einer Y-Achsenvariablen in gruppierten Y-Diagrammen hinzufügen?

@SDF1 @hogi

Die von mir geteilte Datentabelle wurde schnell als Beispiel zusammengestellt. Ich hätte erwähnen sollen, dass ich LSL/USL oder eine andere Zahl in dieser Tabelle nicht zum Generieren der Referenzlinie verwenden kann.

 

Wie auch immer, das Folgende hat bei mir funktioniert.

• Berufung getTestStage(1) vor dem Make Filter Change Handler-Aufruf.
• Hinzufügen von RemoveGraphicsScript (N) mit entsprechenden Handles innerhalb der getTestStage-Funktion, wobei N die FrameBox-Nummer ist, die aus der zuletzt ausgewählten TestStage-Framebox-Nummer erhalten wird, die generiert wird, wenn der TestStage-Filter geändert wird.

Ich werde mich jetzt damit zufrieden geben. Es gibt jedoch noch ein Problem. Wenn ich eine Testphase, dann eine zweite und dann eine dritte auswähle, funktioniert alles wie erwartet, aber wenn ich von drei Auswahlen zurück zu einer gehe, funktioniert mein Skript nicht wie erwartet.

Bei Gelegenheit werde ich einen repräsentativen Datensatz mit dem Skript zur Erläuterung des Problems veröffentlichen.