695928_es-ES

liliconcom

Creando límites de especificaciones

Hola,

Estoy intentando crear límites de especificaciones usando la interfaz jmp o jsl. Estoy intentando crear el límite de especificaciones para diferentes columnas sin USL o LSL. Por favor ayuda. agradecer.

Análisis y modelado de datos básicosIngeniería de Calidad y ProcesosRe: Crear límites de especificaciones

¿Has investigado el Administrador de límites?

Analizar=>Calidad y Procesos=>Gestor de Límites

Re: Crear límites de especificaciones

Hola Jim,

Lo he mirado, pero por lo que veo esta herramienta es para aceptar el límite y aplicarlo a la columna. Lo que estoy tratando de hacer es calcular simplemente un USL o LSL en función de una sigma y una media que proporciono. O si hay una herramienta en la que especifico cuál quiero que sea el sigma para esa columna y luego JMP genera los límites de especificación. ¿Has pasado por algo como esto? gracias jim.

Re: Crear límites de especificaciones

Los límites de especificación normalmente no son límites calculados.Se fijan en función de las especificaciones de diseño o de las limitaciones de la herramienta, etc.

 

Sin embargo, aquí hay un script simple que establecerá los límites de especificaciones para todas las columnas continuas en una tabla de datos usando límites 3 sigma.

Names Default To Here( 1 );
dt = Current Data Table();

colNames = dt << get column names( string, continuous );

For Each( {col}, colNames,
 theMean = Col Mean( As Column( dt, col ) );
 theSTD = Col Std Dev( As Column( dt, col ) );
 Eval(
  Substitute(
    Expr(
     Column( dt, col ) << set property(
      "Spec Limits",
      {LSL( _LSL_ ), Target( _Target_ ), USL( _USL_ ), Show Limits( 1 )}
     )
    ),
   Expr( _LSL_ ), theMean - 3 * theSTD,
   Expr( _Target_ ), theMean,
   Expr( _USL_ ), theMean + 3 * theSTD
  )
 );
);

Re: Crear límites de especificaciones

¡Ciertamente! Para crear límites de especificaciones en JMP usando JSL, abra su tabla de datos, elija la columna deseada y use la plataforma de distribución con la opción Límites de especificaciones para establecer sus límites.

Re: Creación de límites de especificaciones

¿Es posible configurar diferentes límites de especificación para diferentes pasos sin dividir todos los pasos en cada columna?

Re: Creación de límites de especificaciones

Actualmente, solo se permite un conjunto de límites de especificaciones por columna.

Sin embargo, al usar JSL, se pueden incorporar múltiples límites de especificación en un script que pueda recorrer una tabla de datos extrayendo cada subgrupo de a uno por vez, aplicando los límites de especificación para el subconjunto y luego ejecutando el análisis. A continuación, se muestra un ejemplo simple.

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

dtLimits = New Table( "Limits",
	New Column( "Group", character, values( {"F", "M"} ) ),
	New Column( "USL", values( {66, 70} ) ),
	New Column( "Target", values( {61, 64} ) ),
	New Column( "LSL", values( {52, 51} ) )
);

groups = Associative Array( dt:sex ) << get keys;

nw = New Window( "Distributions", hlb = H List Box() );

For Each( {level}, groups,
	dt << select where( :sex == level );
	dtSub = dt << subset( selected columns( 0 ), selecte rows( 1 ), output table( level ), invisible );
	theRow = (dtLimits << get rows where( :group == level ))[1];
	Eval(
		Eval Expr(
			dtSub:height << set property(
				"spec limits",
				{LSL( Expr( dtLimits:LSL[theRow] ) ), USL( Expr( dtLimits:USL[theRow] ) ),
				Target( Expr( dtLimits:Target[theRow] ) ), Show Limits( 1 )}
			)
		)
	);
	hlb << append(
		dis = dtSub << Distribution( Continuous Distribution( Column( :height ), Process Capability( 0 ) ) );
		Report( dis )[Outline Box( 2 )] << set title( "Height=" || level )
		;
	);	
);