695928_ko-KR

liliconcom

사양 한도 만들기

안녕,

jmp 인터페이스나 jsl을 사용하여 사양 제한을 만들려고 합니다. USL 또는 LSL이 없는 다양한 열에 대한 사양 제한을 만들려고 합니다. 도와주세요. 감사하다.

기본 데이터 분석 및 모델링품질 및 프로세스 엔지니어링Re: 사양 제한 생성

Limits Manager를 살펴보셨나요?

분석=>품질 및 프로세스=>한계 관리자

Re: 사양 제한 생성

안녕하세요 짐,

살펴봤지만 이 도구는 한계를 수용하고 이를 열에 적용하는 것으로 보입니다. 제가 하려는 것은 시그마와 제가 제공하는 평균을 기반으로 USL 또는 LSL을 계산하는 것입니다. 또는 해당 열에 대한 시그마를 지정하는 도구가 있는 경우 JMP가 사양 한계를 생성합니다. 이런 일을 겪어 본 적이 있나요? 고마워요 짐.

Re: 사양 제한 생성

사양 한계는 일반적으로 계산된 한계가 아닙니다.이는 설계 사양이나 도구 제한 사항 등에 따라 설정됩니다.

 

그러나 다음은 3 시그마 제한을 사용하여 데이터 테이블의 모든 연속 열에 대한 사양 제한을 설정하는 간단한 스크립트입니다.

Names Default To Here( 1 );
dt = Current Data Table();

colNames = dt << get column names( string, continuous );

For Each( {col}, colNames,
 theMean = Col Mean( As Column( dt, col ) );
 theSTD = Col Std Dev( As Column( dt, col ) );
 Eval(
  Substitute(
    Expr(
     Column( dt, col ) << set property(
      "Spec Limits",
      {LSL( _LSL_ ), Target( _Target_ ), USL( _USL_ ), Show Limits( 1 )}
     )
    ),
   Expr( _LSL_ ), theMean - 3 * theSTD,
   Expr( _Target_ ), theMean,
   Expr( _USL_ ), theMean + 3 * theSTD
  )
 );
);

Re: 사양 제한 생성

틀림없이! JSL을 사용하여 JMP에서 사양 제한을 만들려면 데이터 테이블을 열고 원하는 열을 선택한 다음 Spec Limits 옵션이 있는 배포 플랫폼을 사용하여 제한을 설정하세요.

Re: 사양 제한 생성

모든 단계를 각 열로 분할하지 않고도 각 단계에 대해 다른 사양 제한을 ​​설정하는 것이 가능할까요?

Re: 사양 제한 생성

현재는 열당 하나의 사양 제한 세트만 허용됩니다.

하지만 JSL을 사용하면 여러 사양 한계를 스크립트에 짜넣어 데이터 테이블을 반복하면서 각 하위 그룹을 하나씩 꺼내 하위 집합에 대한 사양 한계를 적용한 다음 분석을 실행할 수 있습니다. 간단한 예는 다음과 같습니다.

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

dtLimits = New Table( "Limits",
	New Column( "Group", character, values( {"F", "M"} ) ),
	New Column( "USL", values( {66, 70} ) ),
	New Column( "Target", values( {61, 64} ) ),
	New Column( "LSL", values( {52, 51} ) )
);

groups = Associative Array( dt:sex ) << get keys;

nw = New Window( "Distributions", hlb = H List Box() );

For Each( {level}, groups,
	dt << select where( :sex == level );
	dtSub = dt << subset( selected columns( 0 ), selecte rows( 1 ), output table( level ), invisible );
	theRow = (dtLimits << get rows where( :group == level ))[1];
	Eval(
		Eval Expr(
			dtSub:height << set property(
				"spec limits",
				{LSL( Expr( dtLimits:LSL[theRow] ) ), USL( Expr( dtLimits:USL[theRow] ) ),
				Target( Expr( dtLimits:Target[theRow] ) ), Show Limits( 1 )}
			)
		)
	);
	hlb << append(
		dis = dtSub << Distribution( Continuous Distribution( Column( :height ), Process Capability( 0 ) ) );
		Report( dis )[Outline Box( 2 )] << set title( "Height=" || level )
		;
	);	
);