695928_it-IT

liliconcom

Creazione dei limiti delle specifiche

CIAO,

Sto cercando di creare limiti di specifica utilizzando l'interfaccia jmp o jsl. Sto cercando di creare il limite delle specifiche per colonne diverse senza USL o LSL. Per favore aiuto. Grazie.

Analisi e modellazione dei dati di baseIngegneria della qualità e dei processiRe: Creazione dei limiti delle specifiche

Hai esaminato il Limits Manager?

Analizza=>Qualità e Processo=>Gestore Limiti

Re: Creazione dei limiti delle specifiche

Ciao Jim,

L'ho guardato, ma da quello che vedo questo strumento è accettare il limite e applicarlo alla colonna. Quello che sto cercando di fare è semplicemente calcolare un USL o un LSL basato su un sigma e una media che fornisco. Oppure se esiste uno strumento in cui specifico cosa voglio che sia il sigma per quella colonna e quindi JMP genera i limiti delle specifiche. Ti è capitato qualcosa del genere? grazie Jim.

Re: Creazione dei limiti delle specifiche

I limiti delle specifiche normalmente non sono limiti calcolati.Vengono impostati in base alle specifiche di progettazione o alle limitazioni dello strumento, ecc.

 

Tuttavia, ecco un semplice script che imposterà i limiti delle specifiche per tutte le colonne continue in una tabella dati utilizzando i limiti 3 sigma

Names Default To Here( 1 );
dt = Current Data Table();

colNames = dt << get column names( string, continuous );

For Each( {col}, colNames,
 theMean = Col Mean( As Column( dt, col ) );
 theSTD = Col Std Dev( As Column( dt, col ) );
 Eval(
  Substitute(
    Expr(
     Column( dt, col ) << set property(
      "Spec Limits",
      {LSL( _LSL_ ), Target( _Target_ ), USL( _USL_ ), Show Limits( 1 )}
     )
    ),
   Expr( _LSL_ ), theMean - 3 * theSTD,
   Expr( _Target_ ), theMean,
   Expr( _USL_ ), theMean + 3 * theSTD
  )
 );
);

Re: Creazione dei limiti delle specifiche

Certamente! Per creare limiti di specifica in JMP utilizzando JSL, apri la tabella dati, scegli la colonna desiderata e utilizza la piattaforma di distribuzione con l'opzione Limiti di specifica per impostare i tuoi limiti.

Re: Creazione limiti Spec

È possibile impostare limiti di specifiche diversi per fasi diverse senza suddividere tutte le fasi in ogni colonna?

Re: Creazione limiti Spec

Attualmente è consentito un solo set di limiti di specifiche per colonna.

Tuttavia, usando JSL, più limiti di specifica possono essere intrecciati in uno script che può scorrere una tabella dati estraendo ogni sottogruppo uno alla volta, applicando i limiti di specifica per il sottoinsieme e quindi eseguendo l'analisi. Ecco un semplice esempio.

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

dtLimits = New Table( "Limits",
	New Column( "Group", character, values( {"F", "M"} ) ),
	New Column( "USL", values( {66, 70} ) ),
	New Column( "Target", values( {61, 64} ) ),
	New Column( "LSL", values( {52, 51} ) )
);

groups = Associative Array( dt:sex ) << get keys;

nw = New Window( "Distributions", hlb = H List Box() );

For Each( {level}, groups,
	dt << select where( :sex == level );
	dtSub = dt << subset( selected columns( 0 ), selecte rows( 1 ), output table( level ), invisible );
	theRow = (dtLimits << get rows where( :group == level ))[1];
	Eval(
		Eval Expr(
			dtSub:height << set property(
				"spec limits",
				{LSL( Expr( dtLimits:LSL[theRow] ) ), USL( Expr( dtLimits:USL[theRow] ) ),
				Target( Expr( dtLimits:Target[theRow] ) ), Show Limits( 1 )}
			)
		)
	);
	hlb << append(
		dis = dtSub << Distribution( Continuous Distribution( Column( :height ), Process Capability( 0 ) ) );
		Report( dis )[Outline Box( 2 )] << set title( "Height=" || level )
		;
	);	
);